[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『車輌の車検、点検を自動表示させる表を作りたい』(お正月)
お尋ねいたします。
車輌の車検、点検を自動表示させる表を作りたいと考えています。
以下のように、C7:C9までを手入力します。
C10はC7:C9までの情報をもとに関数で算出したいです。
その際、C8で2を選択した場合は、初回車検は3年後、その後は2年後として算出させたいです。1を選択の場合は毎年車検となります。
これらをもとに、C11:C22のセルに「車検」、「3ヶ月点検」又は「6ヶ月点検」又は「12ヶ月点検」と表示させたいというものです。
その際、C10の車検日とB列の日付は合致しないので、年月で判断させて、表示させたいです。
なお、B11:B22には月を算出させています。以下のようになります。
B2=西暦(「2021」数字で入力)
C7=初年度登録日(「2021/11/29」のように入力)
C8=車検サイクル(1か2をリストから選択)
C9=点検サイクル(3か6か12をリストから選択
C10=車検日
B11=DATE(B2,4,1) 表示は「4月」
:
B22=DATE(B2+1,3,1) 表示は「3月」
よろしくお願いいたします。
< 使用 Excel:Excel2019、使用 OS:Windows10 >
点検の方だけ。 C11セルに =IF(EOMONTH(C$7,C$9-1)<B11,IF(MOD(MONTH(B11)-MONTH(C$7),C$9),"",C$9&"ヶ月点検"),"") ではどうだろうか? (ねむねむ) 2021/11/29(月) 14:04
C11=IF(DATE(YEAR($C$10),MONTH($C$10),1)=$B11,"車検",IF(EOMONTH(C$7,C$9-1)<B11,IF(MOD(MONTH(B11)-MONTH(C$7),C$9),"",C$9&"ヶ月点検"),""))
ただ、C10の車検日、特に初回の車検なのか2回目以降なのかを関数で判断させることは可能でしょうか?
よろしくお願いいたします。
(お正月) 2021/11/29(月) 16:34
例えば、、、
B2=2024
C7=2021/11/30
C8=2
C10=2024/11/30
B2=2025
C7=2021/11/30
C8=2
C10=2026/11/30
C10=IF(C8=1,DATE(B2,MONTH(C7),DAY(C7)),IF(AND(C8=2,B2-YEAR(C7)<3),DATE(YEAR(C7)+3,MONTH(C7),DAY(C7)),IF(AND(C8=2,B2-YEAR(C7)>=3),DATE(YEAR(C7)+2,MONTH(C7),DAY(C7)),"")))
(お正月) 2021/11/30(火) 07:18
=DATE(IF(C8<2,B2,IF(SUM(YEAR(C7),3)>=B2,SUM(YEAR(C7),3),SUM(B2,ISEVEN(B2-YEAR(C7))))),MONTH(C7),DAY(C7))
C8=1の場合、登録年中は登録日のままになります。
(きまぐれおじさん) 2021/11/30(火) 13:45
<きまぐれおじさんからご提示いただいた数式による結果>
B2=2022
C7=2015/3/26
C8=1
C10=2022/3/26
<私が求める結果>
B2=2022
C7=2015/3/26
C8=1
C10=2023/3/26
(お正月) 2021/11/30(火) 14:19
C10=2025/3/26 ←このように算出したい
(お正月) 2021/11/30(火) 14:24
もう少しと思われるのであれば、お正月さんにとって簡単なのでしょうから是非チャレンジしてみてください。 単純な話、C7の月が3以下であれば年に+1するだけなので。 ifの条件が1つ増えるだけですよ。 (.:*.ゆ ゅ) 2021/11/30(火) 14:41
=EDATE(C7,12*(IF(C8<2,B2,IF(YEAR(C7)+3>=B2,YEAR(C7)+3,B2+ISEVEN(B2-YEAR(C7)+(MONTH(C7)<4)))-YEAR(C7)+(MONTH(C7)<4))))
うるう年の2/29を2/28にする場合の別案(いちおう4月年度対応)です。
(きまぐれおじさん) 2021/11/30(火) 15:33
B2=2022
C7=2020/5/28
C8=1
C10=4042/5/26
(お正月) 2021/11/30(火) 16:09
=EDATE(C7,12*(IF(C8<2,B2,IF(YEAR(C7)+3>=B2,YEAR(C7)+3,B2+ISEVEN(B2-YEAR(C7)+(MONTH(C7)<4))))-YEAR(C7)+(MONTH(C7)<4)))
括弧が1つずれていましたね。すみません。
(きまぐれおじさん) 2021/11/30(火) 16:25
B2=2016
C7=2017/2/24
C8=2
C10=2021/2/24
(お正月) 2021/12/01(水) 07:01
=IF(B2<YEAR(C7)-(MONTH(C7)<4),"",EDATE(C7,12*(IF(C8<2,B2,IF(YEAR(C7)+3>=B2,3+YEAR(C7)-(MONTH(C7)<4),B2+ISEVEN(B2-YEAR(C7)+(MONTH(C7)<4))))-YEAR(C7)+(MONTH(C7)<4))))
おはようございます。
ご指摘のエラーの是正、また、
B2に初年度登録前の年度を記入したときに日付を記入しないようにしました。
(きまぐれおじさん) 2021/12/01(水) 08:34
=IF(B2<YEAR(C7)-(MONTH(C7)<4),"",EDATE(C7,12*(MAX(CEILING(DATEDIF(C7,MAX(C7,DATE(B2,4,0)),"Y"),2)+1,3))))
数式を見直しました
(きまぐれおじさん) 2021/12/01(水) 11:46
=IF(B2<YEAR(C7)-(MONTH(C7)<4),"",EDATE(C7,12*(IF(C8<2,B2-YEAR(C7)+(MONTH(C7)<4),MAX(CEILING(DATEDIF(C7,MAX(C7,DATE(B2,4,0)),"Y"),2)+1,3)))))
失礼、C8<2の場合のパターンが抜け落ちました。
(きまぐれおじさん) 2021/12/01(水) 11:50
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.