[[20211130014050]] 『二択の条件を二つ入れる関数』(モアナ) >>BOT

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『二択の条件を二つ入れる関数』(モアナ)

C3のセルに、下記の二つの条件を満たすような関数を入れたいです。

一つ目の条件は、A1のセルがAだったらアを返し、Bだったらイを返す、です。
=IF(A1=A, "ア","イ")

二つ目の条件は、B1のセルがCだったらウを返し、Dだったらエを返す、です。
=IF(B1=C, "ウ","エ")

でもこの二つの条件を同時に一つのセルに入れる方法が分かりません。

つまり、
=IF(A1=A, "ア","イ") + =IF(B1=C, "ウ","エ") を成り立たせるには、どんな関数にしたらいいのでしょうか。教えていただけませんでしょうか。

< 使用 Excel:Excel2016、使用 OS:Windows10 >


>=IF(A1=A, "ア","イ") + =IF(B1=C, "ウ","エ") を成り立たせるには、どんな関数にしたらいいのでしょうか

この意味がよく解りません。
違う場合は?
言葉でなく、どんなふうに表示されればいいんですか?
違う場合なども含めて、例を掲げてください。

(疑心) 2021/11/30(火) 02:30


=IF(A1="A", "ア",if(A1="B","イ",""))
=IF(B1="C", "ウ",if(B1="D","エ",""))

(疑心) 2021/11/30(火) 02:35

優先順位を考えてません(A1の内容優先)

=IF(A1="A", "ア",IF(A1="B","イ",IF(B1="C", "ウ",IF(B1="D","エ",""))))


(疑心) 2021/11/30(火) 02:40


わかりずらくてすみません。優先順位はないです。

一つ目の条件が、支払月で、翌月か翌々月。
二つ目の条件が、支払日で、10か末日。

この二つの情報を、A1とB1に、各々プルダウンで入れるようになっています。(翌月、末日などの文言は顧客指定のため変えられません。)

一つ書き忘れたのが、元となる日付があって、それを元に、これらの二つの選択肢を条件に、C3に日付を算出したいのです。

元となる日付がD4に入っているとします。2021年10月10日。A1の支払い月が翌々月で、B1の支払日が末日なら、2021年12月31日を算出する計算式をC3に入れたいのです。(当然、支払月が翌月で、支払日が10日の時もあります。)

宜しくお願い致します。

(モアナ) 2021/11/30(火) 03:08


 条件は最初から説明した方がよいと思います
 =IF(B1=10,EOMONTH(D4,IF(A1="翌月",0,1))+10,EOMONTH(D4,IF(A1="翌月",1,2)))
(どん) 2021/11/30(火) 04:49

こんな感じ表を初めから作っておくとか、
後は、Vlookupなどで参照したらどうですかね?

        翌月           翌々月
10      2021/11/10     2021/12/10
末日    2021/11/30     2021/12/31

翌月10
=DATE(YEAR(D1),MONTH(D1)+1,10)

翌月末日
=DATE(YEAR(D1),MONTH(D1)+2,0)

翌々月10
=DATE(YEAR(D1),MONTH(D1)+2,10)

翌々月末日
=DATE(YEAR(D1),MONTH(D1)+3,0)

因みに該当日が祝祭日の場合とかは考慮してません。
(疑心) 2021/11/30(火) 10:21


こっちの方がわかりやすいですかね?

翌月末日(2ヵ月後の1日から1引いた日)
=DATE(YEAR(D1),MONTH(D1)+2,1)-1

翌々月末日(3ヵ月後の1日から1引いた日)
=DATE(YEAR(D1),MONTH(D1)+3,1)-1
(疑心) 2021/11/30(火) 10:42


[[20211129174419]]『複雑な条件での日付の算出』(かせ)
類似質問があるので併せてご参考に。
(きまぐれおじさん) 2021/11/30(火) 10:52

 =IF(COUNTA(A1:B1)=2,SUM(EOMONTH(D4,SUM((A1="翌々月"),(B1="末日"))),B1),"")

(きまぐれおじさん) 2021/11/30(火) 11:16


 もしかして ↓ 同じ人?
[[20211129174419]]『複雑な条件での日付の算出』(かせ)

 違うのなら、ちょっと確認

 支払日が「10」だったら、D4の日付が月初(2021/10/1)だろうが月末(2021/10/31)だろうが
 支払月が「翌月」なら 2021/11/10?

 だとしたら・・・

 =EOMONTH(D4,LEN(A1)-1-(B1=10))+N(B1)
 表示形式「日付」

 以上
(笑) 2021/11/30(火) 11:27

最初からしっかりと条件を書かずにすみませんでした。
どん様、ありがとうございました!まさにこれです!

 =IF(B1=10,EOMONTH(D4,IF(A1="翌月",0,1))+10,EOMONTH(D4,IF(A1="翌月",1,2)))

EOMONTHの中にIFを入れるという発想がありませんでした!感動です。

本当にありがとうございました。

他の方もお時間を割いてくださり、ありがとうございました。
ちなみに、同一人物ではないですが、同じテストをやってる可能性はあります。私はそちらの問題は自分でなんとかなったんですが、参考にしようにも、Nの使い方がまったく分からなかったです。

ありがとうございました。

(モアナ) 2021/11/30(火) 17:44


コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.