[[20211212211736]]　『INDIRECTでB1に、最終列の１行目のセルの値を表示』（jahakas）　ページの最後に飛ぶ

『INDIRECTでB1に、最終列の１行目のセルの値を表示させたい』（jahakas）

　INDIRECTを使って、セルB1に、最終列の１行目のセルの値を表示させたいので
すが、どう書けば良いんでしょうか？
　B列から最終列まで、データは詰まっていますが、データ（列）数は、変動し
ます。

＜使用 Excel：unknown、使用 OS：unknown ＞

 =LOOKUP(1,0/(1:1<>""),1:1)
 ではどうだろうか？
（ねむねむ） 2021/12/12(日) 22:41

 おっとINDIRECT関数を使ってか。
 =INDIRECT(ADDRESS(1,COUNTA(C1:Z1)+2))
 ではどうだろうか？
 上記式ではZ1セルまでを見ている。
（ねむねむ） 2021/12/12(日) 22:49

 ＞B列から最終列まで、データは詰まっています
 C列からでしょ？

 ＞データ（列）数は、変動します。
 最大で「Z列」までだとして

 1）データが文字列で、かつ数式で空白にしていないのなら
　　=INDEX(C1:Z1,COUNTA(C1:Z1))　　← 数値・文字列混在でもオッケー
　　または
　　=LOOKUP("ー",C1:Z1)
　
  　数式で空白にしているのなら
　　=LOOKUP(1,0/(C1:Z1<>""),C1:Z1)　
　　または
　　=LOOKUP(1,0/LEN(C1:Z1),C1:Z1)
　　※数値・文字列どちらでもオッケー

 2）データが数値なら
　　=INDEX(C1:Z1,COUNT(C1:Z1))
　　または
　　=LOOKUP(10^9,C1:Z1)
　
 INDIRECTは使ってませんけど･･･

 ところで、Excelのバージョンは？

 以上
（笑） 2021/12/13(月) 00:27

 追加
 データが文字列で、かつ数式で空白にしている場合

 =INDEX(C1:Z1,COUNTIF(C1:Z1,"?*"))

 以上
（笑） 2021/12/13(月) 08:37

　ありがとうございます。上手く行きました。
　INDIRECT以外でもできることが分かり、勉強になりました。
（jahakas） 2021/12/13(月) 09:43

コメント返信：

[ 一覧(最新更新順) ]

[[20211212211736]] 『INDIRECTでB1に、最終列の１行目のセルの値を表示』（jahakas） ページの最後に飛ぶ

[[20211212211736]]　『INDIRECTでB1に、最終列の１行目のセルの値を表示』（jahakas）　ページの最後に飛ぶ