[[20220129130537]]　『月の合計データを取得したい。』（う～）　ページの最後に飛ぶ

『月の合計データを取得したい。』（う～）

データシートに、毎日その日の売上データを下記のように登録します。
その登録したデータを集計シートにて、
前月分の売上,支払、今月分の売上,支払を取得したいです。

自分なりに考え、使おうと考えた数式は
「=SUMIFS(C2:C366,TEXT(A2:A366,"yyyymm"),TEXT(DATE(YEAR(
TODAY()),MONTH(TODAY()),1)),B2:B366,"売上")」
です。

やってみたのですが、TEXT(A2:A366,"yyyymm")を入れると「この数式には問題があります。」のダイアログが返されうまくいきません。

何か別方法で実現できますでしょうか？

○登録データ一例
A,B,C
2022/1/29,売上,100
2022/1/29,支払,300
…

＜使用 Excel：Office365、使用 OS：Windows10 ＞

 こうじゃないですか？

 =SUMIFS(C$2:C$366,A$2:A$366,">"&EOMONTH(TODAY(),-1),A$2:A$366,"<="&EOMONTH(TODAY(),0),B$2:B$366,"売上")

（半平太） 2022/01/29(土) 14:58

 同じシートでいいのなら･･･

 今月分の売上
 =SUMPRODUCT((TEXT(A2:A366,"yyyymm")=TEXT(TODAY(),"yyyymm"))*(B2:B366="売上"),C2:C366)

 前月分の売上
 =SUMPRODUCT((TEXT(A2:A366,"yyyymm")=TEXT(EDATE(TODAY(),-1),"yyyymm"))*(B2:B366="売上"),C2:C366)

 こんな感じでも

 以上、参考まで
（笑） 2022/01/29(土) 15:29

 集計表を ↓ のようにすれば

	E		F	G
1			売上	支払
2	2021年12月			
3	2022年1月

 E2 =TEXT(EDATE(TODAY(),-1),"yyyy年m月")
 E3 =TEXT(TODAY(),"yyyy年m月")

 F2 =SUMPRODUCT((TEXT($A$2:$A$366,"yyyy年m月")=$E2)*($B$2:$B$366=F$1),$C$2:$C$366)
 右・下コピー

 参考まで
（笑） 2022/01/29(土) 15:39

掲載されている物には、一部間違いもありますが、
その場合は違うエラーが返ってくるはずなので、
正しく書かれているとしています。

Office365であれば、
=SUMIFS($C$2:$C$10,I2#,TEXT(DATE(YEAR(TODAY()),MONTH(TODAY()),1),"yyyymm"),$B$2:$B$10,"売上")
でもできると思います。

詳しくは、
・SPILL
・こぼれた範囲演算子
について調べてみて下さい。
（ヘンリー） 2022/01/29(土) 15:42

↑すみません。検証不足でした。
上記では出来ないようです。
（ヘンリー） 2022/01/29(土) 15:45

 放置の公算大ですけど･･･
 集計表が ↓ で SUMIFS なら

	E		F	G
1			売上	支払
2	2021年12月			
3	2022年1月

 E2 =EOMONTH(TODAY(),-2)+1
 E3 =EOMONTH(TODAY(),-1)+1
 表示形式～ユーザー定義　yyyy"年"m"月"

 F2 =SUMIFS($C:$C,$A:$A,">="&$E2,$A:$A,"<"&EDATE($E2,1),$B:$B,F$1)
 右・下コピー

 以上、参考まで
（笑） 2022/01/30(日) 13:14

コメントいただきありがとうございます。
時間が無くて試せておりませんが、のちのち試してみようと思います。
元々の背景が現在、[日付、登録データ、登録データに対する計算データ、日付に対する年月]で
分けておりました。（上の例は合計20列ぐらいあります。）
そして、データを新たに登録（セルの値入力）した際に、自動計算が2-3秒と結構かかったため、
なにか軽くする方法はないかと、考えてた結果、日付に対する年月の列を削除し、日付から年月を取ろうとした次第です。
（う〜） 2022/01/30(日) 23:10

コメント返信：

[ 一覧(最新更新順) ]

[[20220129130537]] 『月の合計データを取得したい。』（う～） ページの最後に飛ぶ

[[20220129130537]]　『月の合計データを取得したい。』（う～）　ページの最後に飛ぶ