[[20220319165542]]　『前年に対しての曜日スライド』（ポンタ）　ページの最後に飛ぶ

『前年に対しての曜日スライド』（ポンタ）

手動で行えば質問する内容ではないのですが
関数や式などがあれば簡単に行えるので知識ありましたら
よろしくお願いします。
例えば2022年３月１日は火曜から始まります
そして2023年３月１日は水曜で始まります。
売上なのですが曜日を合わせたいのですが
2023年３月１日は水曜から始まるので2022年3月2日の
水曜の売上を比較してそのまま31日まで行くと木曜で終わり
2022年3月１日分は2023年３月1日に入力します
こんな曜日を合わせる良い方法ご存じでしたら知識を教えてください。
このやり方でなくてもかまいませんのでよろしくお願いします。

＜使用 Excel：Excel2007、使用 OS：WindowsVista ＞

 A1セルに月初日を入力 
 B1セル =EDATE(A1,-12)-1+MATCH(WEEKDAY(A1),WEEKDAY(EDATE(A1,-12)+{0;1;2;3;4;5;7}),0)

 A2セル =IF(A1="","",IF(DAY(A1+1)=1,"",A1+1))
 B2セル =IF(A2="","",IF(DAY(B1+1)=1,EOMONTH(B1,-1)+1,B1+1))

 2行目の数式を下にコピー

（半平太） 2022/03/19(土) 20:13

半平太様
回答ありがとうございます
この式でもともと売上額が入力されてるセルを
どのように求めるのでしょうか？
入力してみたのですが？
詳しく書きます
F4から下にF34に前年売上が入力されてます
H4から下にH34に日付が入力されてます
結果を出したいセルがJ4から下にJ34に曜日スライドした売上を出したいです
この説明でわかるでしょうか？
よろしくお願いします

（ポンタ） 2022/03/19(土) 21:04

 H4セルにどんな日付が入っているんですか？

 2022年3月1日それとも2023年3月1日　？

（半平太） 2022/03/19(土) 21:28

2023年３月1日です
２日目からは半平太様の言われた関数
=IF(A1="","",IF(DAY(A1+1)=1,"",A1+1))
が入力して31日まで出ています
よろしくお願いします
（ポンタ） 2022/03/19(土) 21:34

当然A1の所もHに変更しています
（ポンタ） 2022/03/19(土) 21:36

 前年(2022年3月1日)の日付はどこにもないのでしょうか？

 前年売上だけが単独でF4:F34にあるだけなんですか？

（半平太） 2022/03/19(土) 21:52

前年の売上はF4:F34に単独であります
前年(2022年3月1日)の日付は
A4:A34にあります
よろしくお願いします

（ポンタ） 2022/03/19(土) 22:25

 J4セル =IF(H4="","",INDEX(F$4:F$34,MOD(MATCH(WEEKDAY(H$4),WEEKDAY(EDATE($H$4,-12)+{0;1;2;3;4;5;7}),0)+ROW()-5,DAY(MAX(H$31:H$34)))+1))
 下にコピーでどうですか？

 2月で、一方が29日迄あることは考えておりません。

（半平太） 2022/03/19(土) 22:50

半平太様ありがとうございます。
出来ております。ありがとうございます
２月を考慮しないとどうなってしまうのでしょうか？
２月には28日29日がありますが対応は難しいのでしょうか？

（ポンタ） 2022/03/19(土) 23:17

 片一方が1日分足りないですよね？
 その時はどうなるべきなのかこちらでは分からないです。

 (1)前年が29日で当年が28日の場合と
 (2)前年が28日で当年が29日の場合について説明してください。

（半平太） 2022/03/20(日) 00:01

確かに足りなくなりますね
よくやっていたのは
前年が29日で当年が28日の時は足りない1日分を28日分に均等
に振り分けしてました。
前年が28日で当年が29日の場合は１日分足りないままやってました。
こんな感じなのですがこんな都合よく出来ませんよね？
（ポンタ） 2022/03/20(日) 00:32

 ＞前年が29日で当年が28日の時は足りない1日分を28日分に均等
 ＞に振り分けしてました。 
 １．ちょっと分からないです。
 　　J31セルはどうなればいいんですか？

 行  ______A______  _B_    ____F____  _G_  ______H______  _I_  ______J______
  3  前年                  前年売上        本年                スライド売上 
  4   2024/2/1(木)               101        2025/2/1(土)                 103
  5   2024/2/2(金)               102        2025/2/2(日)                 104
  6   2024/2/3(土)               103        2025/2/3(月)                 105

 29  2024/2/26(月)               126       2025/2/26(水)                 128
 30  2024/2/27(火)               127       2025/2/27(木)                 101
 31  2024/2/28(水)               128       2025/2/28(金)                 115.5   ←(102+129)÷2　と言うことですか？
 32  2024/2/29(木)               129

 ＞前年が28日で当年が29日の場合は１日分足りないままやってました。 
 ２．こっちは、単にJ32セルは空白で良いって事ですね？

（半平太） 2022/03/20(日) 10:21

回答ありがとうございます
28日29日の時は足りないままやります
前年29日本年28にちの時は上の表ですと129なので129➗28日で
46071円を1日から28日振り分けその29日の129分が振り分けて
ゼロになるようにしておりました。
こんな感じです
よろしくお願いします
（ポンタ） 2022/03/20(日) 13:45

 J4セル =IF(OR(A4="",H4=""),"",INDEX(F$4:F$34,MOD(MATCH(WEEKDAY(H$4),INDEX(WEEKDAY(A$4:A$10),0),0)+ROW()-5,DAY(EOMONTH(A$4,0)))+1)+IF(DAY(EOMONTH(A$4,0))-DAY(EOMONTH(H$4,0))=1,F$32/28,0))

 下にコピーでどうですか？

（半平太） 2022/03/20(日) 15:15

半平太様ありがとうございます。
思ってる通りです。しかもこんな長い式で凄いですね！
感謝致します。
今回大変お世話になりました。ありがとうございました。
（ポンタ） 2022/03/20(日) 22:33

コメント返信：

[ 一覧(最新更新順) ]

[[20220319165542]] 『前年に対しての曜日スライド』（ポンタ） ページの最後に飛ぶ

[[20220319165542]]　『前年に対しての曜日スライド』（ポンタ）　ページの最後に飛ぶ