[[20220411210116]]　『IF関数とVLOOKUP関数について（空白セルの場合そａx（川本）　ページの最後に飛ぶ

『IF関数とVLOOKUP関数について（空白セルの場合そのまま空白にしたい）』（川本）

お世話になります。
御教授お願い致したく投稿させて頂きます。
下記、Ａ列に数値が入力されており、Ｘさんが、１１、１７，１９の札にて
２００、１４９、１７０と数値が又記載されております。
Ａ列をＦ列にコピペし、並び替えにて１１～３５までを順序良く配列し、
下段にあります様にＸ、Ｙ、Ｚに該当する数値をＶＬＯＯＫＵＰ関数で
各々に振り分けするのですが、値の無いところが０になります。
０を出さずにしたいのですが。

	－Ａ－	－Ｂ－	－Ｃ－	－D－
１		X	Y	Z
２	11	200		
３	13		180	
４	15			150
５	17	149		
６	19	170		
７	21		200	
８	23		210	
９	25			221
１０	27			180
１１	22			176
１２	30		265	
１３	26	220		
１４	12		240	
１５	18		270	
１６	24	210		
１７	28	230		
１８	16			210
１９	20			240
２０	29			230
２１	14		240	
２２	31			250
２３	33	185		
２４	35	170		
２５	32		265

下記がＶＬＯＯＫＵＰ関数での配置
関数は、Ｇ２セルに=VLOOKUP(F2,$A$2:$D$25,2,FALSE)
Ｈ２セルに=VLOOKUP(F2,$A$2:$D$25,3,FALSE)とし
後はしてにコピーしております。

	－Ｆ－	－Ｇ－	－Ｈ－	－Ｉ－
１		X	Y	Z
２	11	200	0	0
３	12	0	240	0
４	13	0	180	0
５	14	0	240	0
６	15	0	0	150
７	16	0	0	210
８	17	149	0	0
９	18	0	270	0
１０	19	170	0	0
１１	20	0	0	240
１２	21	0	200	0
１３	22	0	0	176
１４	23	0	210	0
１５	24	210	0	0
１６	25	0	0	221
１７	26	220	0	0
１８	27	0	0	180
１９	28	230	0	0
２０	29	0	0	230
２１	30	0	265	0
２２	31	0	0	250
２３	32	0	265	0
２４	33	185	0	0
２５	35	170	0	0

宜しくお願い致します。

＜使用 Excel：Excel2013、使用 OS：Windows10 ＞

 このへんを参考にどうぞ

 https://office-hack.com/excel/vlookup-blank/
（VLOOKUP） 2022/04/11(月) 21:34

 ＞Ａ列をＦ列にコピペし、並び替えにて１１～３５までを順序良く配列
 F列だけを並べ替えるのではなく
 A1:D25をコピーして貼り付け
 F1:I25を選択して、データタブの並べ替え
 F列を昇順に並べ替えれば希望通りの結果になりますけど、それではダメなんですか？

 ■数式
 数式でということなら
 表示形式で「0」を非表示にするか
 ※数式を入れたセルの表示形式～ユーザー定義を　#　とか　#,###　とか
 ※B2:D25に「0」があったらそれも非表示になる

 または、数式を ↓ に変更
 G2 =IFERROR((VLOOKUP($F2,$A$2:$D$25,COLUMN(B2),FALSE)&"")*1,"")
 右・下コピー
 COLUMN(B2)はB2セルの値を参照しているわけではないので、表の位置を変更することがあっても
 必ず「B列のセル番地」にすること

 または
 G2 =IFERROR((INDEX(B$2:B$25,MATCH($F2,$A$2:$A$25,0))&"")*1,"")
 右・下コピー

 以上
（笑） 2022/04/11(月) 22:03　追記 22:14

 念のために言っておくと
 =VLOOKUP(F2,$A$2:$D$25,2,FALSE)&""
 のように　&""　をつけるだけでも「0」は表示されなくなりますが
 これでは数値ではなく「文字列」になってしまいます。

 　↓ なら数値のまま
 =IFERROR((VLOOKUP($F2,$A$2:$D$25,COLUMN(B2),FALSE)&"")*1,"")
 ※列番号を COLUMN(B2) にしたのは、列ごとに数式を変更せずに済むように
 　そこをG列は「2」、H列は「3」、I列は「4」にしても同じこと
 ※INDEX～MATCH の方がいいかも

 ■ついでに･･･
 F列も数式で

 F2 =SMALL($A$2:$A$25,ROW(A1))
 下コピー
 ※このROW(A1)もA1セルの値を参照しているわけではないので変更しないように

 以上、参考まで
（笑） 2022/04/11(月) 22:43　追記 23:40

VLOOＫUP様、笑様大変ありがとうございました。

笑様ＳＭＡＬＬ関数も含めて詳細にご教授頂き感謝です。
出来るだけコピペ無しで行きたかった為、本当助かりました。
もう１点御教授願いたく、表を散布図グラフで作成時に、０にて非表示の所も
グラフ上点になってしまい、山谷のようなグラフになります。
＃Ｎ／Ａで回避出来ると、ネットで調べたのですが、“”部に挿入しても上手く行きません。
表に＃Ｎ／Ａと出るのは諦める？しかないのですがグラフだけでも綺麗にしたい為
御教授お願い出来ればと。
宜しくお願い致します。
（川本） 2022/04/12(火) 09:59

 #N/A にするんだったら

 G2 =IFERROR((INDEX(B$2:B$25,MATCH($F2,$A$2:$A$25,0))&"")*1,NA())
                                                           ~~~~~
 #N/A を見えなくしたいんだったら条件付き書式でできます。

 G2:I25を選択して、条件付き書式
 ルールの種類：指定の値を含むセルだけを書式設定
 ルールの内容：一番左のボックスから「エラー」を選択

 書式で文字色を白にする

 以上
（笑） 2022/04/12(火) 13:06

笑様

解りやすく詳細に説明して頂きありがとうございました。
希望通りに行きました。

（川本） 2022/04/12(火) 14:54

コメント返信：

[ 一覧(最新更新順) ]

[[20220411210116]] 『IF関数とVLOOKUP関数について（空白セルの場合そａx（川本） ページの最後に飛ぶ

[[20220411210116]]　『IF関数とVLOOKUP関数について（空白セルの場合そａx（川本）　ページの最後に飛ぶ