[[20220421220211]]　『unique、filter、count、leftの組み合わせ？』（ぐるくん）　ページの最後に飛ぶ

『unique、filter、count、leftの組み合わせ？』（ぐるくん）

関数で悩んでいます。
A列に下記のようなリストがあります。
重複を除いた数を求めるには、
＝COUNTA(UNIQUE(FILTER(A:A,A:A<>"")))-1 で出来ました。
やりたい事は、先頭の数字が22のものだけで重複を除いた数を求めたいです。
結果は3と求めたいです？
LEFT関数と組み合わせれば良いのかと思いますが、うまくいきません。
ご教授頂けますと嬉しいです！

      コード
 1    22いちご
 2
 3
 4   23りんご
 5   22いちご、
 6
 7   25いちご
 8
 9   22メロン
 10
 11  26いちご
 12  22桃

＜使用 Excel：Office365、使用 OS：Windows10 ＞

 =COUNTA(UNIQUE(FILTER(A:A,LEFT(A:A,2)="22")))

 こういうこと？

 以上
（笑） 2022/04/21(木) 23:14

笑様
ありがとうございます。
ここに組み合わせればいいのですね！
家のPCがOffice365でない為、明日確認してみます。

（ぐるくん） 2022/04/21(木) 23:22

 COUNTA関数はエラー値もカウントするので
条件を満たすデータが無いと1になります
(FILTER関数が#CALC!を返す)
その辺の対応不要ですか？
範囲は列全体(A:A)にせずに実際の範囲にした方がよいですよ
（どん） 2022/04/22(金) 03:24

どん様
ありがとうございます。
エラー値もカウントするのでという事は、IFERRORでエラーだったら""とする…
ではダメという事でしょうか。
どのように対応すれば良いでしょうか？
また、範囲は常に動くので、可変にしたく、A:Aにしてます。
（ぐるくん） 2022/04/22(金) 05:43

 >可変にしたく、A:Aにしてます。
範囲をテーブルにして構造化参照すると、
自動で範囲が拡張されます
COUNTIFでカウントしてIFで分岐する
=IF(COUNTIF(テーブル1[列1],"22*"),COUNTA(UNIQUE(FILTER(テーブル1[列1],LEFT(テーブル1[列1],2)="22"))),0)
（どん） 2022/04/22(金) 06:17

 22で始まるコードが 1つもない場合があるんですか？

 =SUM(N(UNIQUE(FILTER(A:A,LEFT(A:A,2)="22",""))<>""))

 これでどうなりますか？
（笑） 2022/04/22(金) 09:00

どん様、笑様
ありがとうございました。
どちらの方法でも出来ました。大変勉強になりました。
（ぐるくん） 2022/04/22(金) 19:26

コメント返信：

[ 一覧(最新更新順) ]

[[20220421220211]] 『unique、filter、count、leftの組み合わせ？』（ぐるくん） ページの最後に飛ぶ

[[20220421220211]]　『unique、filter、count、leftの組み合わせ？』（ぐるくん）　ページの最後に飛ぶ