[[20220606153505]]　『条件を満たす式を作りたいです』（50の悩み）　ページの最後に飛ぶ

『条件を満たす式を作りたいです』（50の悩み）

申し訳ございませんがご教授お願い致します。

sheet1の表より最悪値を文字文章で現したく、

sheet1

    A       B      C     D      E     F       G        H         I
1   品種    入荷   出荷   潰れ   キズ   未熟    腐れ     運送時間  不良品合計                       
2   あまおう  48    48     0     0     0        0        3         0                     
3   とちおとめ 50   48     0     1     1        0        5         2                      
4   紅ほっぺ   50   48    0      1    1         0       6          2

sheet2

         A                   B                
1     あまおう         不良なし,運送時間3
2     とちおとめ      キズ1,未熟1,運送時間5
3     紅ほっぺ          キズ1,未熟1,運送時間6

sheet2では、sheet1の表結果からsheet2 B列に不良状態と運送時間を文字文章に変換できる式を作りたい。

sheet3

sheet3では下記両者式が成立する式を作りたい。

•最悪値(不良品合計が多く、運送時間が長い)をsheet2 B列の結果から
文字文章を引っ張ってくる式を作りたい

•sheet1で不良品合計が多く又入荷数が多いものを抽出したい
(2条件が成立する式を作りたい)

検索順は
1:不良品合計
2:入荷最大値

但し、不良品合計が『0』及び全数値が同じ値にで合った場合は
入荷最大の品種を返す。
不良品合計も入庫最大値も3品種同じ値であれば、品種欄の一番先頭の品種あまおうを返す。
もし2品種が同じ値にで合った場合は
該当する行の最初の品種を返す。
（sheet1では返したいのはとちおとめになります）

複雑で申し訳御座いません(_ _)

＜使用 Excel：Office365、使用 OS：Windows10 ＞

 Sheet1とSheet2の A列は同じ順番に並んでるんですか？

 だとしたら  ↓ な感じでできませんか？

 Sheet2
 B1 =IF(A1="","",IF(Sheet1!I2=0,"不良なし",TEXTJOIN(",",TRUE,IF(Sheet1!D2:G2>0,Sheet1!$D$1:$G$1&Sheet1!D2:G2,"")))&",運送時間"&Sheet1!H2)
 下コピー

 Sheet3 はやりたいことが理解できません。

 以上、参考まで
（笑） 2022/06/06(月) 16:54

有難う御座います。
Sheet1とSheet2の A列は同じ順番に並んでいます。

sheet2の式誠に有難う御座います。
出来ました。

sheet3の式に関しましては
まずワースト値(不良品合計が多く、運送時間が長い)をsheet1から選んで
それに該当する値sheet2から引っ張ってきたいです
(作成したjoint分を抽出)

（50の悩み） 2022/06/06(月) 17:08

 ＞sheet1で不良品合計が多く又入荷数が多いものを抽出したい

 こっちの方だけ

 =INDEX(FILTER(Sheet1!A2:A10,Sheet1!I2:I10*10^9+Sheet1!B2:B10=MAX(Sheet1!I2:I10*10^9+Sheet1!B2:B10)),1)

 こういうこと？

 もう一つの方は条件がわかりません。

 以上、参考まで
（笑） 2022/06/06(月) 23:49

誠に有難う御座います。

解けました。

尚、下の表の場合ですが、入荷数が3品種共に50で出荷が50より多かった場合ですが、出荷数が多く不具合合計も多い物を抽出は可能でしょうか?(_ _)
(正解は紅ほっぺにしたい)

sheet1

    A       B      C     D      E     F       G        H         I
1   品種    入荷   出荷   潰れ   キズ   未熟    腐れ     運送時間  不良品合計                       
2   あまおう  50    48     0     0     0        0        3         0                     
3   とちおとめ 50   48     0     1     1        0        5         2                      
4   紅ほっぺ   50   55     0      1    1        0        6         2

（50の悩み） 2022/06/07(火) 12:12

 ＞=INDEX(FILTER(Sheet1!A2:A10,Sheet1!I2:I10*10^9+Sheet1!B2:B10=MAX(Sheet1!I2:I10*10^9+Sheet1!B2:B10)),1)

 まず、上の式を ↓ に差し替えてください（結果は同じ）
 =LET(x,Sheet1!I2:I10*10^9+Sheet1!B2:B10,INDEX(FILTER(Sheet1!A2:A10,MAX(x)=x),1))

 ＞出荷数が多く不具合合計も多い物を抽出
 これは条件の追加？
 不良品合計も入荷数も同じなら、出荷数の多いものを表示ということ？

 =LET(x,Sheet1!I2:I10*10^10+Sheet1!B2:B10*10^5+Sheet1!C2:C10,INDEX(FILTER(Sheet1!A2:A10,MAX(x)=x,""),1))

 よくわかってないのでテキトーです。

 以上
（笑） 2022/06/07(火) 16:32

何度もすみません
条件の追加となります。
不良品合計も入荷数も同じなら、出荷数の多いものを表示ということになります。

不良品合計も入荷数も出荷数も同じなら、エラーになる事はありますでしょうか?

単純に出荷数を加算すればいいんですかね？
INDEX(FILTER(Sheet1!A2:A10,Sheet1!I2:I10*10^9+Sheet1!B2:B10+Sheet1!c2:ｃ10=MAX(Sheet1!I2:I10*10^9+Sheet1!B2:B10*+Sheet1!c2:c10)),1)

式の内容についてですが
INDEX(FILTER(Sheet1!A2:A10,Sheet1!I2:I10*10^9+Sheet1!B2:B10=MAX(Sheet1!I2:I10*10^9+Sheet1!B2:B10)),1)

＊10^9の乗算の意味を教えて頂きたく(_ _)
（50の悩み） 2022/06/07(火) 16:51

 ＞単純に出荷数を加算すればいいんですかね？
 それではダメでしょう。

 　　↓ はどうなったんですか？
 ＞=LET(x,Sheet1!I2:I10*10^10+Sheet1!B2:B10*10^5+Sheet1!C2:C10,INDEX(FILTER(Sheet1!A2:A10,MAX(x)=x,""),1))

 以上、確認だけ
（笑） 2022/06/07(火) 17:07

下記の式で回答出来ました。(_ _)
=LET(x,Sheet1!I2:I10*10^10+Sheet1!B2:B10*10^5+Sheet1!C2:C10,INDEX(FILTER(Sheet1!A2:A10,MAX(x)=x,""),1))

（50の悩み） 2022/06/07(火) 17:24

何回も申し訳ございませんです

LET式ですが
範囲A2:A10の条件で
抽出がどうしてもA4紅ほっぺになってしまいます。
A2:A4範囲でしたら正解回答が出ます。
（50の悩み） 2022/06/08(水) 12:15

 どんな場合でも「紅ほっぺ」になるってこと？

 5行目に何が入力されている時にそうなるのか
 2022/06/07(火) 12:12　の表に5行目を追加して、再現する具体例を提示してください。

 以上
（笑） 2022/06/08(水) 14:49

すみません
全表の数値とは若干異なありますがこちらになります
LET式ではとちおとめを返しました。
正解を 5行目のとよのかにしたく(_ _)

       A    B     C     D      E     F       G        H    I
1    品種   入荷   出荷   潰れ   キズ   未熟    腐れ   運送時間  不良品合計                       
2   あまおう  50    48     0     0     0        0        3         0                     
3   とちおとめ 50   48     0     1     1        0        5         2                      
4   紅ほっぺ   50   55     0      1    1        0        6         2
5   とよのか   50   120    0     1    1        0         2         2

（50の悩み） 2022/06/08(水) 15:54

 ＞LET式では とちおとめを返しました。

 実際に入力した式をコピーして提示してください。
 ※掲示板の式をコピーするのではなく

 以上
（笑） 2022/06/08(水) 16:37

度々申し訳ございません。
入力した式は以下になります(_ _)

=LET(x,Sheet1!I2:I5*10^10+Sheet1!B2:B5*10^5+Sheet1!C2:C5,INDEX(FILTER(Sheet1!A2:A5,MAX(x)=x,""),1))

私の勘違いでございました。
2022/06/08(水) 16:37の表では
とよなかを返しております。

入荷数出庫数不良品がゼロの状況になりますと
A2のあまおう(上段のセル)を返すようになるんですね。

理解出来ました。

（50の悩み） 2022/06/09(木) 12:35

(笑)様
度々申し訳御座いません
2022/06/08(水) 15:54の表の項目と条件が増えた場合ですが
下表のように

       A    B     C     D      E     F       G        H    I            J
1    品種   入荷   出荷   潰れ   キズ   未熟    腐れ   運送時間  不良品合計   仕入額                       
2   あまおう  50    48     0     0     0        0        3         0    50                  
3   とちおとめ 50   48     0     1     1        0        5         2    50                  
4   紅ほっぺ   50   55     0      1    1        0        6         2    50
5   とよのか   50   120    0     1    1        0         2         2    45
6   ゆめのか   60   60     0     0    0        0         3         0    45
7   ｽｶｲﾍﾞﾘｰ    70   60     1     0    0        1         1         2    45

表にJ列に仕入額が入った場合なんですが、
全条件 (2022/06/07(火) 16:32)+仕入額が安い物を表示させたいです。m(__)m
この表の抽出結果は A5 とよのかとなります

ご教授お願い申し上げます
（50の悩み） 2022/06/09(木) 21:18

大変申し訳ございません
どなたか 2022/06/09(木) 21:18を解いて頂く事は出来ませんでしょうか(_ _)
LET関数+MINIFSは出来なさそうだったので、
ご教授宜しくお願い致します。(_ _)
（50の悩み） 2022/06/22(水) 11:43

 ＞1   品種     入荷   出荷   潰れ  キズ 未熟  腐れ  運送時間  不良品合計   仕入額  
 ＞5   とよのか   50   120    0     1    1      0        2         2         45
 ＞7   ｽｶｲﾍﾞﾘｰ    70    60    1     0    0      1        1         2         45

 ＞この表の抽出結果は A5 とよのかとなります

 検索順は、ですよね？
 　　　　　　↓
 　1:不良品最多
 　2:入荷値最多　←
 　3:仕入額最少

 「ｽｶｲﾍﾞﾘｰ」の方が「とちおとめ」より入荷数が多いですけど、優先条件は正しいですか？

（半平太） 2022/06/22(水) 13:20

半平太様
有難う御座います。
今回の検索順ですが

 　1:仕入額最少
   2:不良品最多
   3:入庫最大又は 出庫最大
     (この表で仕入れ最低額群内でスカイベリーの入庫70が多いですが
      この状況では出庫最大のとよのかを返すようにしたいです)

となります。

複数条件の状況で申し訳ございません

（50の悩み） 2022/06/22(水) 17:22

 ＞   3:入庫最大又は 出庫最大
 ＞     (この表で仕入れ最低額群内でスカイベリーの入庫70が多いですが
 ＞      この状況では出庫最大のとよのかを返すようにしたいです)

 「又は」、「この状況では」なんて曖昧です。

  どう言う理屈で優先順位が決まるのか、誰でも分かる様にご説明ください。

（半平太） 2022/06/22(水) 17:40

申し訳ございませんでした。
優先順位は

   1:仕入額最少
   2:不良品最多
   3:出庫最大
  となります

（50の悩み） 2022/06/22(水) 18:06

 ＞優先順位は
 ＞   1:仕入額最少
 ＞   2:不良品最多
 ＞   3:出庫最大

 入荷は無関係になったんですね？（ただし、運送時間最大は残るんでしょうね)

 Sheet3のA1セル =INDEX(SORT(Sheet1!A2:J10,{10,9,3,8},{1,-1,-1,-1}),1,1)

（半平太） 2022/06/22(水) 20:11

半平太様
有難う御座います。

運送時間は除外で考えています。

入庫に関しては、含めますと複雑化に
なる可能性がありましたので、、、、
ただし、先行2022/06/07(火) 16:32でもご教授して頂いた
不良品合計も入荷数も同じなら、出荷数の多いものを表示も
条件として入れたいと思って下ります(_ _)

（50の悩み） 2022/06/22(水) 21:18

 また、入荷数が何かに関係するんですか？

 取り留めない感じで、よく分からないです。

 仕様を整理するのはこちらの守備範囲ではないので、私は降ります。

（半平太） 2022/06/22(水) 21:32

半平太様
複雑化してしまい大変失礼致しました。
申し訳ございません(_ _)
（50の悩み） 2022/06/22(水) 22:02

度々申し訳ございません
2022/06/07(火) 17:07のご教授で式を採用し答えを返す事が出来まして、データをセーブして再度シートを開くと式エラーが表示させるようになってしまいます。
エラーは[=#VALUE!］となりなす
Excel設定の問題でしょうか?

（50の悩み） 2022/06/28(火) 10:30

エラー解消出来ました。
マクロ有効にしないといけないのでした。(_ _)
（50の悩み） 2022/06/28(火) 10:55

コメント返信：

[ 一覧(最新更新順) ]

[[20220606153505]] 『条件を満たす式を作りたいです』（50の悩み） ページの最後に飛ぶ

[[20220606153505]]　『条件を満たす式を作りたいです』（50の悩み）　ページの最後に飛ぶ