[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『条件に当てはまるものをカウントしたい』(ガス抜き)
セル3行分(OFFSET($L$19:$L$327,,{0,1,2}に値が入っているときのみ
下記の条件3つを満たすものをカウントしたいです。
=SUM(COUNTIFS(OFFSET($L$19:$L$327,,{0,1,2}),"<>",$B$19:$B$327,"A 見込み (予測・決定)",$I$19:$I$327,"11オリジナル教材",$G$19:$G$327,"継続"))
上記の関数だと(OFFSET($L$19:$L$327,,{0,1,2}に値が入っている個数も計上してしまいます。
if文を使っても試みたのですがspilエラーが出てしまいます。
分かりにくい質問で申し訳ありませんが、ご確認お願い致します。
< 使用 Excel:unknown、使用 OS:Windows10 >
>if文を使っても試みたのですがspilエラーが出てしまいます。 この式って提示可能でしょうか? あとそのエラーが出るということは365とかですかね? (.:*.ゆ ゅ) 2022/06/24(金) 15:57
=IF(OFFSET($L$19:$L$327,,{0,1,2})<>"",SUM(COUNTIFS($B$19:$B$327,"A 見込み (予測・決定)",$I$19:$I$327,"11オリジナル教材",$G$19:$G$327,"継続")),"")
(ガス抜き) 2022/06/24(金) 16:19
スピルエラーに消されていますが、そもそもそのoffsetの使い方は#VALUE!になるはずです。 あんまりよくわかってないのですが、 =IF(CONCAT($L$19:$N$327)<>"",SUM(COUNTIFS($B$19:$B$327,"A 見込み (予測・決定)",$I$19:$I$327,"11オリジナル教材",$G$19:$G$327,"継続")),"") で良かったりしませんか? (.:*.ゆ ゅ) 2022/06/24(金) 16:38
>(OFFSET($L$19:$L$327,,{0,1,2}に値が入っているときのみ >(OFFSET($L$19:$L$327,,{0,1,2}に値が入っている個数も計上
いまいち目的が不明確です。
SUM(COUNTIFS(略)) ってのも相まって余計混乱中...
=SUMPRODUCT( (($L$19:$L$327<>"")+($M$19:$M$327<>"")+($N$19:$N$327<>"")) *($B$19:$B$327="A 見込み (予測・決定)") *($I$19:$I$327="11オリジナル教材") *($G$19:$G$327="継続") )
的なものをCOUNTIFSで表現したいって事でしょうか?
(白茶) 2022/06/24(金) 16:56
>セル3行分(OFFSET($L$19:$L$327,,{0,1,2}に値が入っているときのみ
「3列」分では?
やりたいことは L列、M列、N列のどれか 1つにでも値が入っていて、かつ B列、G列、I列が条件を満たすものの個数ということ?
とりあえず・・・
1)A案 ※O列を作業列に O19 =IF(COUNTA(L19:N19),1,"") 下コピー
=COUNTIFS(B19:B327,"A 見込み (予測・決定)",I19:I327,"11オリジナル教材",G19:G327,"継続",O19:O327,1)
2)B案 =SUM((MMULT(N(L19:N327<>""),{1;1;1})>0)*(B19:B327="A 見込み (予測・決定)")*(I19:I327="11オリジナル教材")*(G19:G327="継続"))
以上、参考まで (笑) 2022/06/24(金) 17:13
商材 確度 新規/継続 1月 2月 3月
A 見込 継続 20 40
A 見込 継続 20 30 40
A 見込 継続 40
(ガス抜き) 2022/06/24(金) 17:21
で、回答を試した結果はどうなったんですか? 例示の場合、どっちの方法でも「3」になると思いますけど?
一つだけ言っておくと、作業列の式は対象が数値なら COUNTA ではなく COUNT にしてください。
以上 (笑) 2022/06/24(金) 18:49
B案では欲しい件数が出てきました。
MMULT関数初めて知りました、難しすぎて困惑しております。
A案は作業列を作れないのでまだ試していません。
ご助言ありがとうございます。
(ガス抜き) 2022/06/24(金) 19:13
なんで作業列が使えないのか知りませんけど 3列(3か月)だけなら ↓ な感じでも
=SUM(SIGN((L19:L327<>"")+(M19:M327<>"")+(N19:N327<>""))*(B19:B327="A")*(G19:G327="見込")*(I19:I327="継続"))
以上、参考まで (笑) 2022/06/25(土) 11:19
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.