[[20221216105152]]　『閾値以上で累計リセット』（エビアン）　ページの最後に飛ぶ

『閾値以上で累計リセット』（エビアン）

以下の表のC,D列を関数で作成したいです。
「C4」「D4」に入力するだけで下にスピルする関数を教えてください。

【仕様】

 (1)[B1セル]:閾値（手入力、変数）
 (2)C列：売上金額を累計。但し[B1セル]の金額（含む）以上になれば、次の日時からリセットして再計算。
 (3)D列：累計リセット毎のグループ番号

【現在表】

      　A           B         C          D
  1   閾値       10,000                        
  2                                            
  3   日時     売上金額  リセット累計  グループ
  4   12月1日    10,000                        
  5   12月2日     1,000                        
  6   12月3日     3,000                        
  7   12月4日     4,000                        
  8   12月5日    11,000                        
  9   12月6日     6,000                        
 10   12月7日     2,000                        
 11   12月8日     8,000                        
 12   12月9日    12,000

【完成表】

      　A           B         C          D
  1   閾値       10,000                   
  2                                            
  3   日時     売上金額  リセット累計  グループ
  4   12月1日    10,000        10,000         1
  5   12月2日     1,000         1,000         2
  6   12月3日     3,000         4,000         2
  7   12月4日     4,000         8,000         2
  8   12月5日    11,000        19,000         2
  9   12月6日     6,000         6,000         3
 10   12月7日     2,000         8,000         3
 11   12月8日     8,000        16,000         3
 12   12月9日    12,000        12,000         4

＜使用 Excel：Microsoft365、使用 OS：Windows10 ＞

 グループだけ。
 また、現在365で試せないためうまくいかない場合はすまない。

 最大20行目まで入力するとして。
 D4セルに
 =IF(A4:A20="","",COUNTIF(INDIRECT("C3:C"&ROW(3:19)),">="&B$1)+1)
 または
 =IF(A4:A20="","",COUNTIF(INDIRECT("C3:C"&SEQUENCE(17,,3),">="&B$1)+1)
 ではどうだろうか？
（ねむねむ） 2022/12/16(金) 11:42:22

ねむねむ様、すごいです。スピルしました。
両方共、結果も期待通りです。
2つ目の式だけ、INDIRECTの閉じカッコを追加しました。
感謝です。ありがとうございました。

累計はSCAN関数でいけると思うのですが、実力不足で..
（エビアン） 2022/12/16(金) 12:14:07

 >累計はSCAN関数
 =SCAN(0,B4:B12,LAMBDA(累計,値,IF(累計<B1,累計+値,値)))
（´・ω・`） 2022/12/16(金) 13:27:14

（´・ω・`）様、できました。

「SCAN関数で、できそうだ」、までは調べられたのですが、
自分で組めるかと言われれば、？？？でした。

こういう風に使うのですね。勉強になりました。
どうも、ありがとうございました。
（エビアン） 2022/12/16(金) 14:06:02

コメント返信：

[ 一覧(最新更新順) ]

[[20221216105152]] 『閾値以上で累計リセット』（エビアン） ページの最後に飛ぶ

[[20221216105152]]　『閾値以上で累計リセット』（エビアン）　ページの最後に飛ぶ