[[20230203101432]]　『スクロールする際、数値が変わったタイミングでス』（famnak）　ページの最後に飛ぶ

『スクロールする際、数値が変わったタイミングでストップする機能があるか知りたい』（famnak）

スクロールする際、数値が変わったタイミングでストップする機能があるか知りたいです。

Ctrl+shift+↓を使用すると空白セルと入力セルの境界までジャンプしますが、同じようなコマンドはないでしょうか。

たとえば

１
１
２
３

の並びの行があったとして、現在一番上の１を選択していたとします。
この時Ctrl+shift+↓を使用すると３に飛びます。
これを２で止まるようにしたいのですが、そんな方法ありますか。

教えてくれると嬉しいです。

＜使用 Excel：Microsoft365、使用 OS：Windows10 ＞

 例えば右クリックするとそんな感じになるマクロとかどうっすか？
    Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
        Dim r As Range
        For Each r In Range(Target, Target.End(xlDown))
            If Target.Value <> r.Value Then
                r.Activate
                Cancel = True
                Exit Sub
            End If
        Next r
    End Sub
 エラー処理してないので、実際に動かしてみ実用できそうなら、もう少し肉付けします。
（稲葉） 2023/02/03(金) 10:26:54

 衝突しましたがそのままアップします。

 無いと思います。
 Onkeyメソッドでショートカットキーに
 マクロを割り付ける、ということなら
 可能かもしれませんが。
（MK） 2023/02/03(金) 10:29:14

 Ctrl + 方向キー は、アクティブセル領域の最終セルまで移動 で、
 これに Shiftキーも同時に押すことで、領域の選択になるんです

 言葉の説明ではジャンプですけど、やっていることは
 Ctrl+shift+↓ で領域を選択なので、ほんとにやりたいのはどっちなんでしょう

 ちなみに 、Ctrl+shift+↓ したあと Ctrl+G 押してセル選択で、アクティブ列との相違
  Ctrl+shift+↓  Ctrl+G  Alt+S Alt+M Enter  とかどうでしょう

 私は、左手キーボード、右手マウス　でやってます
（´・ω・`） 2023/02/03(金) 10:39:54

Onkeyメソッドを使ったサンプルを書いておきます。
設定方法などはネット検索してみてください。

'ThisWorkbookﾓｼﾞｭｰﾙ

Private Sub Workbook_Open()

 Application.OnKey "^y", "douti" 'Ctrl+y
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)

 Application.OnKey "^y"
End Sub

'標準モジュール

Sub douti()

 Dim kai As Range
 Dim shu As Range
 Dim c As Range
  Set kai = ActiveCell
  If kai.Value = "" Then
     Set kai = Nothing
     Exit Sub
  End If
  Set shu = kai.End(xlDown)
  For Each c In Range(kai.Offset(1), shu)
   If c.Value <> c.Offset(-1).Value Then
      c.Select
      Exit For
   ElseIf c = shu Then
      c.Select
   End If
  Next c
  Set kai = Nothing
  Set shu = Nothing
End Sub
（MK） 2023/02/03(金) 11:12:15

１
１
２
３
がA列にあるとし、
A1？の最初の位置でなんからのマクロを実行し、
アクティブセルの値をA2以降から検索して
異なっていればそこをアクティブにして停止。

みたいなマクロを組めばどうでしょう？
（初心者） 2023/02/03(金) 11:15:20

ありがとうございます。
mkさんのマクロでやりたいことができました。
救っていただき感謝しかない！
（famnak） 2023/02/03(金) 11:35:23

 解決済みのようですが、私の書いた作業をマクロの記録して、ちょと修正したものがこちらです

 Sub sample()
    Range(Selection, Selection.End(xlDown)).ColumnDifferences(ActiveCell).Cells(1, 1).Select
 End Sub
（´・ω・`） 2023/02/03(金) 11:47:16

 ColumnDifferencesというのがあるのですね。
 勉強になります。

 Onkeyメソッドを紹介しましたが、右クリックメニュー
 に追加する、という方法もあります。
 参考まで。

https://excel-excellent-technics.com/excel-vba-addrightclickmenu-8675
（MK） 2023/02/03(金) 11:53:26

コメント返信：

[ 一覧(最新更新順) ]

[[20230203101432]] 『スクロールする際、数値が変わったタイミングでス』（famnak） ページの最後に飛ぶ

[[20230203101432]]　『スクロールする際、数値が変わったタイミングでス』（famnak）　ページの最後に飛ぶ