[[20230211135016]]　『sumif関数を横方向にもspillしたい』（ユーリ）　ページの最後に飛ぶ

『sumif関数を横方向にもspillしたい』（ユーリ）

初めて質問させていただきます。
下記[計算元]から各月の担当ごと合計額を[計算後]のように算出したいです。
「１月の担当者ごと合計額」であればsumif関数で簡単にspillできたのですが、
２月、３月もspillして１つの関数で完結できる方法が無いかと思い、試行錯誤しています。

最近spillをようやく覚えたので活用したいなと思いまして…。
実現可能でしたら教えていただきたいです。

[計算元]
担当　1月　　2月　　3月
A　　　3　　　4　　　3
B　　　2　　　1　　　2
A　　　4　　　5　　　3
B　　　1　　　3　　　2
B　　　5　　　2　　　1

[計算後]
担当　1月　　2月　　3月
A　　　7　　　9　　　6
B　　　8　　　6　　　5

＜使用 Excel：Microsoft365、使用 OS：Windows10 ＞

 表を下のように変更すれば、
 F2 =SUMIFS(C2:C16,A2:A16,E2:E3,B2:B16,F1:H1)
 これで左右にスピルします。
 元表で左右にスピルさせる式はわかりませんでした。識者の方をお待ちください。

     |[A] |[B]|[C] |[D]|[E] |[F]|[G]|[H]
 [1] |担当|月 |人数|   |担当|1月|2月|3月
 [2] |A   |1月|   3|   |A   |  7|  9|  6
 [3] |B   |1月|   2|   |B   |  8|  6|  5
 [4] |A   |1月|   4|   |    |   |   |   
 [5] |B   |1月|   1|   |    |   |   |   
 [6] |B   |1月|   5|   |    |   |   |   
 [7] |A   |2月|   4|   |    |   |   |   
 [8] |B   |2月|   1|   |    |   |   |   
 [9] |A   |2月|   5|   |    |   |   |   
 [10]|B   |2月|   3|   |    |   |   |   
 [11]|B   |2月|   2|   |    |   |   |   
 [12]|A   |3月|   3|   |    |   |   |   
 [13]|B   |3月|   2|   |    |   |   |   
 [14]|A   |3月|   3|   |    |   |   |   
 [15]|B   |3月|   2|   |    |   |   |   
 [16]|B   |3月|   1|   |    |   |   |   
（フォーキー） 2023/02/11(土) 14:53:48

 >左右
 右と下、でした。すみません。
（フォーキー） 2023/02/11(土) 14:57:52

 3か月分なら、一応 ↓ でできなくはない
 B11 =SUMIF(A2:A6,A11:A12,OFFSET(B2:B6,0,{0,1,2}))

 実際は12か月分なら
 B11 =SUMIF(A2:A6,A11:A12,OFFSET(B2:B6,0,SEQUENCE(1,12,0)))

 以上、参考まで
（笑） 2023/02/11(土) 22:43:13

＞フォーキーさま
なるほど。。ありがとうございます！
元表の作り方を工夫することで容易にスピルできるようになるんですね。
数式が非常にシンプルでわかりやすいです。

＞笑さま
ありがとうございます。
いただいた数式で横方向にもスピルできました！
実は表示する月数を動的に変更することにも対応させたいと思っていまして、
その点もいただいた例のSEQUENCE関数内を少し変更することで実現できました。
=SUMIF(A2:A6,A9:A10,OFFSET(B2:B6,0,SEQUENCE(1,COUNTA(B8:Z8),0)))

お二人共、時間を割いて回答いただき誠にありがとうございます。

（ユーリ） 2023/02/12(日) 01:53:35

コメント返信：

[ 一覧(最新更新順) ]

[[20230211135016]] 『sumif関数を横方向にもspillしたい』（ユーリ） ページの最後に飛ぶ

[[20230211135016]]　『sumif関数を横方向にもspillしたい』（ユーリ）　ページの最後に飛ぶ