[[20230301222640]]　『年月の件数』（k.k）　ページの最後に飛ぶ

『年月の件数』（k.k）

　なかなか上手くいきませんので、お力をお願いします。

　Ａ列　　　　Ｂ列　　　　Ｃ列　　　Ｄ列

　　　　　　　2022年　　　3月　　　1件

　こんな感じでＡ列のセルに年月日を入れているとします。
　空白のセル、上のＤ列のあたりに2022年の３月は
　何件かを調べたいです。

　今まで、2022年だけだったので、右横あたりmonth関数を
　使って月を取り出し、下の方に数えたい月を入れて
　件数を数えてましたが、年がかわってしまい、カウントイフや
　いろいろがんばっても関数で上手くいきません。

　やっぱりＡ列の日付を年と月と日にちでバラさないと厳しいの
　でしょうか？

　よろしくお願いします

＜使用 Excel：Excel2010、使用 OS：unknown ＞

    |[A]     |[B] |[C]|[D] 
 [1]|日付    |年  |月 |件数
 [2]|2022/3/1|2022|  3|   1
 [3]|2023/3/3|    |   |    
 [4]|2022/6/5|    |   |

 D2 =COUNTIFS(A:A,">="&DATE(B2,C2,1),A:A,"<="&DATE(B2,C2+1,1)-1)
（フォーキー） 2023/03/01(水) 23:15:15

　ありがとうございます。会社に行ってみて、やってみます。

　関数詳しくなくて、今は出社前でパソコンさわれないのですが、
　初めのDATEの最後にある1と最後の－１のあたりはどういう意味でしょうか？

　教えてもらえると助かります。

（k.k） 2023/03/02(木) 07:49:04

＞教えてもらえると助かります。
DATEを検索して調べたらどうですか。

（きなし） 2023/03/02(木) 08:03:52

指定した年月の1日から最終日の範囲をカウントしているだけです。
上記だと3月1日から3月31日
月ごと日数は違うので、3月にプラス1して4月1日にすると、4月1日の前日は3月31日と、最終日が求められます。
（フォーキー） 2023/03/02(木) 08:25:06

 =SUMPRODUCT((TEXT(A1:A10,"yyyym")=B1&C1)*1)
 でも。
（ねむねむ） 2023/03/02(木) 08:46:33

 フォーキーさんの
 >DATE(B2,C2+1,1)-1
 の部分は
 DATE(B2,C2+1,0)
 でも。
（ねむねむ） 2023/03/02(木) 09:11:09

＞いろいろがんばっても関数で上手くいきません。
ピボットテーブルで「月」単位にグループ化して集計すればいいだけでは？
「年」はいらなければ外せばいいし。
（d-q-t-p） 2023/03/02(木) 09:16:01

 >DATE(B2,C2+1,0)
０でもいけるんですね。
勉強になります。
（フォーキー） 2023/03/02(木) 10:02:31

 DATE関数では月と日には0だけでなく-も指定でき、例えば月に-1を指定すると前年の11月(0だと12月)になったりする。
（ねむねむ） 2023/03/02(木) 10:15:10

 ＞=COUNTIFS(A:A,">="&DATE(B2,C2,1),A:A,"<="&DATE(B2,C2+1,1)-1)

 　=COUNTIFS(A:A,">="&DATE(B2,C2,1),A:A,"<"&DATE(B2,C2+1,1))　でも
                                        ~~~~~~~~~~~~~~~~~~~
 参考まで
（笑） 2023/03/02(木) 11:00:03

確かに未満にすれば-1要らないですね。
ありがとうございます。
（フォーキー） 2023/03/02(木) 11:56:00

　フォーキーさん、ねむねむさん、（笑）さん、
　丁寧に教えてくれてありがとうございます。
　うまくいきました！
　

　countifsにDATEの組合わせかたと
　サムプロダクトとTEXT関数の組み合わせ方
　とても勉強なりました。

　
（k.k） 2023/03/02(木) 16:33:00

コメント返信：

[ 一覧(最新更新順) ]

[[20230301222640]] 『年月の件数』（k.k） ページの最後に飛ぶ

[[20230301222640]]　『年月の件数』（k.k）　ページの最後に飛ぶ