[[20230407100557]]　『数式を教えてください』（たけたけ）　ページの最後に飛ぶ

『数式を教えてください』（たけたけ）

 いつも勉強させていただいております。すみませんが教えてください。
 以下のような表があります。

     |[A]     |[B]       |[C]
 [ 1]|地区    |年月日    |東京の2月
 [ 2]|東京    |2023/02/12|=COUNTIFS(A:A,"東京",B:B,">=" & "2023/02/01",B:B,"<=" & "2023/02/28") で 3
 [ 3]|東京    |2023/03/05|
 [ 4]|名古屋  |2023/03/08|
 [ 5]|大阪    |2023/01/10|
 [ 6]|名古屋  |2023/02/15|
 [ 7]|東京    |2023/02/07|
 [ 8]|大阪    |2023/01/20|
 [ 9]|東京    |2023/02/25|
 [10]|大阪    |2023/03/06|
 なお、年月日のデータ形式は日付型です。

 この時、「東京の2月」の個数を算出するには、 C2 の数式で 3 が求められます。
 このやり方ではなく、「2023/02」という引数を使って、データ形式はそのままで、作業列も使わず、「東京の2月」の個数を算出するには、どのような数式にすればいいでしょうか？
 特に今困っているというわけではなく、あくまでも後学のためですが。

 ご教示の程、よろしくお願いいたします。

＜使用 Excel：Microsoft365、使用 OS：Windows11 ＞

 ＞「2023/02」という引数

 これは、どこかのセルに入れるんですか？
 それとも、数式に直接書き込むんですか？

 セルの場合、それは文字なんですか？　
 それとも日付シリアル値を表示形式でそう見せているものですか？

（半平太） 2023/04/07(金) 10:20:03

 =SUM((A2:A10="東京")*(TEXT(B2:B10,"yyyy/mm")="2023/02"))
（どん） 2023/04/07(金) 10:32:23

 半平太さん
  有難うございます。
 「2023/02」という引数は、どこかのセルに入れた文字列を想定しています。

 どんさん
 有難うございます。うまく求められました。
 ちなみに COUNTIFS を使ってはできないものなのでしょうか？

（たけたけ） 2023/04/07(金) 10:44:45

 >ちなみに COUNTIFS を使ってはできないものなのでしょうか？
  =COUNTIFS(A:A,"東京",B:B,">=" & "2023/02/01",B:B,"<=" & "2023/02/28") で 3
 その式で出来たんでしょ。
 こちらでは 0 になりましたけど。
 嘘を言わないで本当のこと言ったらどうなんですか。
（ez0l） 2023/04/07(金) 10:52:31

 >こちらでは 0 になりましたけど。
B列が文字列だと無視されて0、シリアル値(数値)ならカウント出来ると思うが･･?
">=" & "2023/02/01"
&がなくても、">=2023/02/01"で可能
(">=" & セル参照の場合は必要)
 >ちなみに COUNTIFS を使ってはできないものなのでしょうか?
"2023/02"を条件にすると2023/02/01が対象になります
第１引数はセル参照のみです(配列不可)
TEXT(B2:B10,"yyyy/mm")
などは使用出来ないので、"2023/02"を条件にするには
作業列を使用しないと出来ないと思います
（どん） 2023/04/07(金) 11:16:26

 >COUNTIFS を使ってはできないものなのでしょうか？

 ●「2023/02」がが[C1]にありシリアル値の場合
  =LET(_d,EOMONTH(C1,-1)+1,COUNTIFS(A:A,"東京",B:B,">="&_d,B:B,"<="&EOMONTH(_d,0)))

 ●「2023/02」が[D1]にあり、文字列の場合
  =LET(_d,DATEVALUE(D1),COUNTIFS(A:A,"東京",B:B,">="&_d,B:B,"<="&EOMONTH(_d,0)))

（まる2021） 2023/04/07(金) 11:23:52

 C2セル =COUNTIFS(A:A,"東京",B:B,">=" &C1,B:B,"<="&EOMONTH(C1,0))

 <結果図>
 行  __A__  ____B____  ___C___ 
  1  地区   年月日     2023/02  ←文字列
  2  東京   2023/2/12        3           
  3  ：：　：：：：：　：：：：

（半平太） 2023/04/07(金) 11:26:15

ez01

＞嘘を言わないで本当のこと言ったらどうなんですか。
はぁ？　ちゃんと3になるぜ。
あまり、しゃしゃりでない方がいいんじゃないの。

（老婆心） 2023/04/07(金) 11:27:30

 まる2021さん、半平太さん
 有難うございます。
 結局は私が最初の質問文に入れた式とやっていることは同じですよね。

 どんさん
 ＞第１引数はセル参照のみです(配列不可)
 ＞TEXT(B2:B10,"yyyy/mm")
 ＞などは使用出来ないので、"2023/02"を条件にするには
 ＞作業列を使用しないと出来ないと思います
 了解しました。 有難うございます。

（たけたけ） 2023/04/07(金) 11:41:07

 ＞ 結局は私が最初の質問文に入れた式とやっていることは同じですよね。

 真意が分からないなぁ・・、 では何を求めているんですか？

 COUNTIFS関数は使うが、最初の質問文と同じじゃない数式が知りたいってことなんですか？

（半平太） 2023/04/07(金) 11:56:11

コメント返信：

[ 一覧(最新更新順) ]

[[20230407100557]] 『数式を教えてください』（たけたけ） ページの最後に飛ぶ

[[20230407100557]]　『数式を教えてください』（たけたけ）　ページの最後に飛ぶ