[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『緯度経度からGoogleマップの検索結果のURLを返す方法』（あにい）
A1セルに「35.710140841802456, 139.810830394654」と緯度経度を入力しています。
D1セルに"リンク"
B1セルに「https://www.google.co.jp/maps/place/35%C2%B042'36.5%22N+139%C2%B048'39.0%22E/@35.710143,139.8095429,18z/data=!3m1!4b1!4m4!3m3!8m2!3d35.7101408!4d139.8108304?hl=ja」
のリンクを表示させたいと考えております。
＝HYPERLINK（"https://www.google.co.jp/maps/@"&A1,D1）
当方エクセル初心者にて、いろいろ調査しながら作成しており
お恥ずかし話ですがこちらですとうまく機能せず
解決策をご教示いただけますと幸いです
＜ 使用 Excel：Excel2016、使用 OS：Windows10 ＞
[___]|_________________A__________________ [ 1]|35.710140841802456, 139.810830394654 [ 2]| [ 3]|35°42'36.5"N+139°48'39.0"E ←この情報をパラメータとして準備しておく必要があるのでは? [ 4]|
=HYPERLINK("https://www.google.co.jp/maps/place/"&A3&"/@"&SUBSTITUTE(A1," ",""),"リンク")
↓ブラウザに表示されたURL
(前略)//www.google.co.jp/maps/place/35%C2%B042'36.5%22N+139%C2%B048'39.0%22E/@35.7101389,139.8108333,17z/data=!3m1!4b1!4m4!3m3!8m2!3d35.7101389!4d139.8108333
そこそこ惜しい結果になりました
（白茶） 2023/04/14(金) 18:53:52
あー、SUBSTITUTE 別に要らないですね。
（白茶） 2023/04/14(金) 18:57:29
（マップ） 2023/04/14(金) 20:45:27
こちらのサイト参考にさせてもらって https://www.ipentec.com/document/google-map-link
ピンは刺さらなかったけど、特定の場所は表示できました。
|[A] |[B] |[C]
[1]|35.710140841802456, 139.810830394654| |URL
[2]| |変換元URL→ |https://maps.google.co.jp/maps?ll=緯度,経度
[3]|緯度 | 35.710140841802456|https://maps.google.co.jp/maps?ll=35.710140841802456,経度
[4]|経度 | 139.810830394654|https://maps.google.co.jp/maps?ll=35.710140841802456,139.810830394654
[5]|リンク |リンク |
[6]| | |
[7]|参考サイト |https://www.ipentec.com/document/google-map-link|
A3=緯度 A4=経度 C2=https://maps.google.co.jp/maps?ll=緯度,経度 と事前に手入力しておく
数式の入力
B3=TRIM(MID(SUBSTITUTE($A$1,",",REPT(" ",100)),ROW(A1)*100-99,100))
B3セルをB4にコピー
C3=SUBSTITUTE(C2,A3,B3) C3セルをC4にコピー
B5=HYPERLINK(C4,"リンク")
でいかがでしょう？ （稲葉） 2023/04/15(土) 06:52:20
白茶さんご提案のA3セルにあたる部分の計算
ただ、ズームが反映されない・・・
|[A] |[B] |[C] |[D] |[E]
[1] |35.710140841802456, 139.810830394654| |URL | |
[2] | |変換元URL→ |https://maps.google.co.jp/maps?ll=緯度,経度 | |
[3] |緯度 | 35.710140841802456|https://maps.google.co.jp/maps?ll=35.710140841802456,経度 | |
[4] |経度 | 139.810830394654|https://maps.google.co.jp/maps?ll=35.710140841802456,139.810830394654| |
[5] |リンク |リンク | | |
[6] | | | | |
[7] |参考サイト |https://www.ipentec.com/document/google-map-link| | |
[8] | | | | |
[9] | |度 |分 |秒 |文字列
[10]|緯度文字列 | 35| 42|36.500|35°42'36.5"
[11]|経度文字列 | 139| 48|39.000|139°48'39.0"
[12]|ズーム |18z | | |
[13]|連結 |35°42'36.5"N+139°48'39.0"E | | |
B10=INT(B3) C10=INT((B3-B10)*60) D10=ROUND(((B3-B10)*60-C10)*60,1) E10=B10&"°"&C10&"'"&TEXT(D10,"0.0")&"""" 上記を11行目にコピー
B12=E10&"N+"&E11&"E"
ってやったらそれなりの数値になりました。
（稲葉） 2023/04/15(土) 08:16:56
ピンも↓で表示されました。
https://maps.google.com/maps?q=緯度,経度
（***） 2023/04/15(土) 09:00:04
情報ありがとうございます。 うーーーん私の黒目だと https://www.google.co.jp/maps/place/35°42'36.5"N+139°48'39.0"E/@35.710140841802456, 139.810830394654,18z このリンクで行くと https://www.google.co.jp/maps/place/35%C2%B042'36.5%22N+139%C2%B048'39.0%22E/@35.7101389,139.8108333,17z/data=!3m1!4b1!4m4!3m3!8m2!3d35.7101389!4d139.8108333 こっちのリンク（17z）に代わってしまうんですよね
余談 ChatGPTで緯度の10進数を60進数に変換する関数を作ってもらったら、エクセルにない関数ばっかり提案されて5回くらい繰り返してやっと作ってもらえた。（注釈として、VBA使えとも） DMSで検索すると、VBAコードが載ってたのでそっち使ったほうが早いかも。 https://learn.microsoft.com/ja-jp/office/troubleshoot/excel/convert-degrees-minutes-seconds-angles
=IF(A1>=0,INT(A1)&"° "&INT((A1-INT(A1))*60)&"' "&ROUND((((A1-INT(A1))*60)-INT((A1-INT(A1))*60))*60,2)&""" N",INT(-A1)&"° "&INT((-A1-INT(-A1))*60)&"' "&ROUND((((-A1-INT(-A1))*60)-INT((-A1-INT(-A1))*60))*60,2)&""" S")
（稲葉） 2023/04/15(土) 09:38:51
あ、そちらはうまくいくんですけど、元の質問に合わせた場合だとって意味で・・・ ピン刺したままどうやってズーム反映すればいいのかなーと思案していました。
（稲葉） 2023/04/15(土) 10:00:10
空白はトリムする。
35.710140841802456, 139.810830394654
~~~
（***） 2023/04/15(土) 10:02:51
いけました！！ 緯度経度だけの場合だと、スペースあっても大丈夫だったので失念してました。 情報ありがとうございました。 （稲葉） 2023/04/15(土) 10:08:23
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.