[[20230606103346]]　『A列だけにある数字と B列だけにある数字を知りたａx（see）　ページの最後に飛ぶ

『A列だけにある数字と B列だけにある数字を知りたい』（see）

 A列だけにある数字と
 B列だけにある数字を知りたい

 A列･B列は、昇順

 ●試したこと

 C2 に =EXACT(A2,B2)
 ↓
 最終行までコピー
 ↓
 FALSEになる行を、挿入-下方向にシフトで空白行を入れていく
 A	B　　　　C	
 1	1	TRUE
 2		FALSE
 3	3	TRUE
 	4	FALSE
 5	5	TRUE
 5		FALSE
 	6	FALSE
 9	9	TRUE
 10		FALSE
 11	11	TRUE
 	12	FALSE
 	12	FALSE
 13	13	TRUE
 ↓
 オートフィルタで FALSEのみ表示させる

 ただ行数が増えた場合、空白行を入れていく作業がなかなか手間なので…

 ちょっとした検証で使いたいと思っておりますので、
 マクロを使うまでは考えていません

 良い方法があれば教えて下さい

＜使用 Excel：Excel2010、使用 OS：Windows10 ＞

 例えば
 D1セル:=IFERROR(AGGREGATE(15,6,A$1:A$20/((COUNTIF(B:B,A$1:A$20)=0)*(A$1:A$20<>"")),ROW(A1)),"")
 E1セル:=IFERROR(AGGREGATE(15,6,B$1:B$20/((COUNTIF(A:A,B$1:B$20)=0)*(B$1:B$20<>"")),ROW(A1)),"")
 と入力して下へフィルコピーとしてはどうだろうか？

 なお上記式ではデータが最大20行目まであるものとしている。
（ねむねむ） 2023/06/06(火) 10:52:51

 空白行を入れていく作業はないので、単純に
 D1 =IFERROR(IF(VLOOKUP(A1,B:B,1,0)<>"",""),"ユニーク")
 E1 =IFERROR(IF(VLOOKUP(B1,A:A,1,0)<>"",""),"ユニーク")
 と入力して下へフィルコピーとか

（QW） 2023/06/06(火) 11:27:12

 ねむねむさん　QWさん　教えてくださりありがとうございます

 私の質問の仕方が悪くて申し訳ないです

 質問で例にあげさせてもらっていた
 C列をFALSEで絞り込むと下記のようになり、
 「5」を見てもらうと
 B列にも5はあるけれど、2つはないので表示されるようにしたいです

 A	B　　　　C	
 2		FALSE
  	4	FALSE
 5		FALSE
  	6	FALSE
 10		FALSE
  	12	FALSE
  	12	FALSE

 ×A列だけにある数字とB列だけにある数字を知りたい
 　↓
 ○A列とB列でペアになっていない数字を知りたい

（see） 2023/06/06(火) 16:48:15

 D列、E列を作業列として使い、G列、H列に結果を求める。

 D1セル：=IF(A1="","",A1+(COUNTIF(A$1:A1,A1)-1)/100)
 E1セル：=IF(B1="","",B1+(COUNTIF(B$1:B1,B1)-1)/100)
 G1セル：=IFERROR(INT(AGGREGATE(15,6,D$1:D$20/((COUNTIF(E:E,D$1:D$20)=0)*(D$1:D$20<>"")),ROW(A1))),"")
 H1セル：=IFERROR(INT(AGGREGATE(15,6,E$1:E$20/((COUNTIF(D:D,E$1:E$20)=0)*(E$1:E$20<>"")),ROW(A1))),"")

 と入力して下へフィルコピー。
（ねむねむ） 2023/06/07(水) 09:10:54

 AGGREGATE関数はつかったことがなかったのと、
 関数の組み合わせと 考え方、勉強になりました

 ねむねむさん　QWさん　ありがとうございました
（see） 2023/06/08(木) 10:59:48

コメント返信：

[ 一覧(最新更新順) ]

[[20230606103346]] 『A列だけにある数字と B列だけにある数字を知りたａx（see） ページの最後に飛ぶ

[[20230606103346]]　『A列だけにある数字と B列だけにある数字を知りたａx（see）　ページの最後に飛ぶ