[[20230913175417]]　『ある条件を起点に指定数字を取得するには』（ひろ）　ページの最後に飛ぶ

『ある条件を起点に指定数字を取得するには』（ひろ）

	A	B	C	D	E	F	G	H
1	取得月	月額	4月	5月	6月	7月	8月	9月
2	4月	300	300	300	300	300	300	300
3	6月	600			600	600	600	600

A列の取得月に入力したら
C列以降の取得月をスタートに月額を反映させる関数はどうすればよいでしょうか。

＜使用 Excel：Excel2013、使用 OS：Windows10 ＞

 例示通り、実際も4～9月なんですか？

 ・実際は 4～3月で、その並びは固定
 ・A2セルから下には「4」とか「6」とか数字だけ入力（「月」は入力しない）

 C2 =IF($B2="","",IF(MOD($A2-4,12)+1<=COLUMN(A1),$B2,""))
 右・下コピー

 実際のセル位置が例示と違っていても COLUMN(A1)の「A1」を変更しないように

 以上
（笑） 2023/09/13(水) 19:02:20

 実際は N列までの表だとして
 A2セルから下は「4月」「6月」と「月」も入力

 C2 =IF($B2="","",IF(MATCH($A2,$C$1:$N$1,0)<=COLUMN(A1),$B2,""))

 A列は数字だけ入力なら
 C2 =IF($B2="","",IF(MATCH($A2&"月",$C$1:$N$1,0)<=COLUMN(A1),$B2,""))

 右・下コピー、でも
（笑） 2023/09/13(水) 21:27:11

（ひろ） 2023/09/14(木) 09:11:06

（笑）さん
ありがとうございます。

2つ目の

 C2 =IF($B2="","",IF(MATCH($A2,$C$1:$N$1,0)<=COLUMN(A1),$B2,""))
を使わせていただきます。

COLUMN（A1）はどういう使い方なのでしょう？
この部分がよく理解出ないのです。
（ひろ） 2023/09/14(木) 09:12:55

　では "(COLUMN(C1)-2)" としたら理解できるかしらん？
（higejee） 2023/09/14(木) 10:16:52

 ＞COLUMN（A1）はどういう使い方なのでしょう？
 どこか空いた行の、どの列でもいいので =COLUMN(A1) と入力して右にコピーしてみてください。
 =COLUMN(A1)、=COLUMN(B1)、=COLUMN(C1)　…となって
 1、2、3…と連番になりますよね。
 COLUMN(A1)はA列の列番号「1」を、COLUMN(B1)はB列の列番号「2」を返すからです。

 ■質問の件
 IF(MATCH($A2,$C$1:$N$1,0)<=COLUMN(A1)　この式は
 IF(MATCH($A2,$C$1:$N$1,0)<=1　でも同じこと
                          ~~~
 ですが、これだと「1」の部分を D2の式は「2」に、E2の式は「3」というように
 1列ずつ数式を書き替える必要がありますよね。

 COLUMN 関数を使えば、1つの式をコピーするだけで済んでしまいます。
 これが COLUMN を使う理由です。

 ■ついでに･･･
 =COLUMN(A1)は、=COLUMN(A2) でも =COLUMN(A3) でも、A列のセル番地なら行番号はどれでも同じ

 =COLUMN() のようにセル番地（引数）を省略すると、その式を入力した列番号が返る。
 C列のどこかのセルに =COLUMN() と入れたら、C列の列番号「3」になり
 右にコピーすれば　3、4、5…となります。

 ネットで COLUMN 関数を調べてみてください。
 ROW 関数も知っておいた方がいいでしょう。

 以上、参考まで
（笑） 2023/09/14(木) 11:09:42

行番号はどれでも同じ?
（?） 2023/09/14(木) 11:26:50

 ＞行番号はどれでも同じ?
 ＞（?） 2023/09/14(木) 11:26:50

 何か？
（笑） 2023/09/14(木) 11:37:14

列番号ではないのですか。
（?） 2023/09/14(木) 15:17:32

 私は
 [A列のセル番地なら行番号はどれでも](結果は)同じ
 と読んだが。
（ねむねむ） 2023/09/14(木) 15:27:57

コメント返信：

[ 一覧(最新更新順) ]

[[20230913175417]] 『ある条件を起点に指定数字を取得するには』（ひろ） ページの最後に飛ぶ

[[20230913175417]]　『ある条件を起点に指定数字を取得するには』（ひろ）　ページの最後に飛ぶ