[[20230914132351]]　『タイム測定の順位を、１位から順に表示させたい』（てん）　ページの最後に飛ぶ

『タイム測定の順位を、１位から順に表示させたい』（てん）

選手を走力順に表示させたいです。
５０音順名前(別のタブからとばすための関数を入れてます)、タイム、その順位(ランク関数)は表示している状態です。

そのデータをおいたまま、隣のセルに、順位順に並び替えて表示させたいです。
(同タイムの人も上手く表示したいです。)

助けてください…！

＜使用 Excel：Excel2019、使用 OS：Windows10 ＞

行列が分かるようにサンプルデータを示されたらどうですか。

（IT） 2023/09/14(木) 14:30:01

 こんな事かな？

 D2セル =IF($C2="","",INDEX(A:A,MOD(AGGREGATE(15,6,($C$2:$C$10*1000+ROW(C$2:C$10))/(C$2:C$10<>""),ROW(A1)),1000)))
 右へ、下へコピー

 <結果図>
 行  __A__  ___B___  __C__  __D__  ___E___  __F__
  1  選手   タイム   順位   選手   タイム   順位 
  2  あ       0:03     2     か     0:01      1
  3  い       0:07     6     あ     0:03      2
  4  う       0:03     2     う     0:03      2
  5  え       0:06     5     お     0:04      4
  6  お       0:04     4     え     0:06      5
  7  か       0:01     1     い     0:07      6

（半平太） 2023/09/14(木) 16:21:00

半平太さん！ありがとうございます！
ただ、途中タイムが空欄の人がいて、上手く表示されません…
どうしたらいいですか？
（てん） 2023/09/14(木) 17:00:57

 ＞ただ、途中タイムが空欄の人がいて、上手く表示されません…

 では、この提案に従って、どんな状態のものをどう並べ替えたいのか具体的に示してください。
 　　　　↓
 ＞行列が分かるようにサンプルデータを示されたらどうですか。

（半平太） 2023/09/14(木) 17:24:12

結果図>

 行  __A__  ___B___  __C__  __D__  ___E___  __F__
  1  選手   タイム   順位   選手   タイム   順位 
  2  あ       0:03     2     か     0:01      1
  3  い              #N/A   #N/A    #N/A    #N/A  
  4  う       0:03     2     う     0:03      2
  5  え       0:06     5     お     0:04      4
  6  お       0:04     4     え     0:06      5
  7  か       0:01     1     い     0:07      6

こんなふうになります。
（てん） 2023/09/14(木) 17:39:01

 ご希望の出来上がり図が知りたいのですけども・・

（半平太） 2023/09/14(木) 19:15:26

行 __A__ ___B___ __C__ __D__ ___E___ __F__

  1  選手   タイム   順位   選手   タイム   順位 
  2  あ       0:03     2     か     0:01      1
  3  い             　　　　　 あ　　　0:03    　2
  4  う       0:03     2     う     0:03      2
  5  え       0:06     5     お     0:04      4
  6  お       0:04     4     え     0:06      5
  7  か       0:01     1     い

失礼しました。
このように表示したいです。
（てん） 2023/09/14(木) 20:02:53

 C2セル =IF(B2="","",RANK(B2,B$2:B$100,1))
 D2セル =IF(A2="","",INDEX(A:A,MOD(SMALL(INDEX((0&$C$2:$C$100)*1000+ROW($C$2:$C$100)+($C$2:$C$100="")*1000000,0),ROW(A1)),1000)))
 E2セル =IF(A2="","",IFERROR((VLOOKUP($D2,$A:$B,2,FALSE)&"")*1,""))
 F2セル =IF(A2="","",IFERROR(VLOOKUP($D2,$A:$C,3,FALSE),""))

 下にコピー

（半平太） 2023/09/14(木) 22:40:29

すごい！いけました！
ありがとうございました！！！
（てん） 2023/09/15(金) 07:53:24

コメント返信：

[ 一覧(最新更新順) ]

[[20230914132351]] 『タイム測定の順位を、１位から順に表示させたい』（てん） ページの最後に飛ぶ

[[20230914132351]]　『タイム測定の順位を、１位から順に表示させたい』（てん）　ページの最後に飛ぶ