[[20230916223718]]　『条件付きセルの塗りつぶしが機能しない。』（じー）　ページの最後に飛ぶ

『条件付きセルの塗りつぶしが機能しない。』（じー）

スケジュール表を作成しています。
A列に対応項目、B列に対応者、C列に対応開始日、D列に対応日数、E列からEZ列までをカレンダーにして1日1セルとしています。
対応者は3パターンで、?@ Re: ?A貴社?B 貴社/Re:です。
対応開始日から、対応日数分だけカレンダーのセルに塗りつぶしして、見える化したいです。

また、「設定」と言うシートのB列に祝日を列挙しています。

条件付きセルの条件は以下の通りです。

=OR(WEEKDAY(E$2,1)=1,WEEKDAY(E$2,1)=7)

=COUNTIF( INDIRECT("設定!B1:B"),E$2)>0

=AND($B4="Re:",E$2>=$C4,E$2<WORKDAY($C4,$D4,INDIRECT("設定!B1:B")))

=AND($B4="貴社",E$2>=$C4,E$2<WORKDAY($C4,$D4,INDIRECT("設定!B1:B")))

=AND($B4="貴社/Re:",E$2>=$C4,E$2<WORKDAY($C4,$D4-1,INDIRECT("設定!B1:B")))

これで、1つ目の条件である土日の塗りつぶしは機能するのですが、他が全く機能しません。

＜使用 Excel：Excel2021、使用 OS：Windows11 ＞

 ＞=COUNTIF( INDIRECT("設定!B1:B"),E$2)>0
 　　　　　　　　　　　　　　　 ↑
　　　 エクセルにはこう言う省略指定法はありません(少なくとも、現在時点では）

（半平太） 2023/09/16(土) 23:29:23

＞対応開始日から、対応日数分だけ
参考です。
TRUE の部分に色がつきます。

    |[A]     |[B]    |[C]       |[D]     |[E]|[F] |[G] |[H] |[I] |[J] |[K] |[L] |[M] |[N] |[O] |[P] |[Q] |[R] |[S] |[T] |[U] |[V] |[W] |[X] 
 [1]|対応項目|対応者 |対応開始日|対応日数|8/1|8/2 |8/3 |8/4 |8/5 |8/6 |8/7 |8/8 |8/9 |8/10|8/11|8/12|8/13|8/14|8/15|8/16|8/17|8/18|8/19|8/20
 [2]|        |Re     |8月2日    |       5|   |TRUE|TRUE|TRUE|TRUE|TRUE|    |    |    |    |    |    |    |    |    |    |    |    |    |    
 [3]|        |貴社   |8月4日    |      10|   |    |    |TRUE|TRUE|TRUE|TRUE|TRUE|TRUE|TRUE|TRUE|TRUE|TRUE|    |    |    |    |    |    |    
 [4]|        |貴社/Re|8月10日   |       7|   |    |    |    |    |    |    |    |    |TRUE|TRUE|TRUE|TRUE|TRUE|TRUE|TRUE|    |    |    |

条件付き書式 =AND(E$1>=$C2,E$1<=$C2+$D2-1)
適用先 =$E$2:$X$4
（IT） 2023/09/17(日) 09:28:31

 何のために INDIRECT 関数を使ってるんですかね？

 土日
 =WEEKDAY(E$2,2)>5

 祝日
 =COUNTIF(設定!$B$1:$B$100,E$2)

 ※土日祝が「貴社」などより上になるよう設定する 
　「条件を満たす場合は停止」にチェック
 ※土日と祝日は同じ色でいいのなら、1つの式にまとめることができる
 ※土日と祝日が別の色で、土日が祝日の場合は祝日の色にしたいのなら
 　祝日が一番上に来るようにする

 貴社
 =AND($B4="貴社",E$2>=$C4,E$2<WORKDAY($C4,$D4,設定!$B$1:$B$100))

 ※WORKDAY は「設定!$B:$B」のように列全体にしない方がいい（重くなるので）
 ※「貴社」と「Re:」は同じ色でいいのなら、1つの式にまとめることができる

 参考まで
（笑） 2023/09/18(月) 22:47:08

コメント返信：

[ 一覧(最新更新順) ]

[[20230916223718]] 『条件付きセルの塗りつぶしが機能しない。』（じー） ページの最後に飛ぶ

[[20230916223718]]　『条件付きセルの塗りつぶしが機能しない。』（じー）　ページの最後に飛ぶ