[[20231213113857]]　『VBA 空白セル行削除』（YYY）　ページの最後に飛ぶ

『VBA 空白セル行削除』（YYY）

こんにちは。

A3のセルから下において空白セルが有った場合、行毎削除したいです。
ネットで似たようなコードがあり、試してみましたが1と2行も一緒に削除され
ます。1と2行はそのままキープしたいです。

宜しくお願い致します。

Sub A列が空白の行削除()

    Dim intRowEnd As Integer    '最終行番号を格納
    Dim i         As Integer    '行カウンタ

    '最終行番号の取得
    intRowEnd = Cells(Rows.Count, 1).End(xlUp).Row

    i = intRowEnd   '最終行番号を行カウンタにセット

    Do While i >= 1
        'A列が空白の場合、行削除
        If Cells(i, 1).Value = "" Then
            Rows(i).Delete
        End If
        i = i - 1
    Loop

End Sub

＜使用 Excel：unknown、使用 OS：Windows11 ＞

 いろいろやり方はあると思いますが一例です。
 Sub Sample()
    Dim Rng         As Range
    Dim intRowEnd   As Long
    Dim i           As Long

    '最終行番号の取得
    intRowEnd = Cells(Rows.Count, 1).End(xlUp).Row

    'A列が空白の場合、行削除
    For i = intRowEnd To 3 Step -1
        Set Rng = Cells(i, 1)
        If Len(Rng.Value) = 0 Then Rng.EntireRow.Delete
    Next i
 End Sub
（通りすがり助六） 2023/12/13(水) 11:53:16

 一例です。

 Sub CommandButton1_Click()
    Dim r As Range
    Set r = Cells(1).CurrentRegion.Columns(1)
    Set r = Intersect(r, r.Offset(2))
    r.SpecialCells(xlCellTypeBlanks).EntireRow.Delete
 End Sub

（hatena） 2023/12/13(水) 12:25:35

通りすがり助六様、hatena様

ご確認頂きありがとうございます！
どちらも思い通りの動きとりました！！

ありがとうございます！
（YYY） 2023/12/13(水) 12:53:06

コメント返信：

[ 一覧(最新更新順) ]

[[20231213113857]] 『VBA 空白セル 行削除』（YYY） ページの最後に飛ぶ

[[20231213113857]]　『VBA 空白セル行削除』（YYY）　ページの最後に飛ぶ