[[20240319170822]]　『シート名をキーにして別シートのデータをカウント』（ゆきんこ）　ページの最後に飛ぶ

『シート名をキーにして別シートのデータをカウントする方法』（ゆきんこ）

先ほどシート名を読み込む関数を教えて頂き応用で出来るかと思ったのですが上手くできず大変お手数ですが教えてくださいm(__)m

上司に対するアンケートの集計を行います。実際はもっと数が多く複雑なのですがシンプルにしたもので説明させて頂きます。

・上司分3枚のシートがありシート名は山田・鈴木・佐藤となっています。
このシート内にアンケート結果として〇・△・×を集計したものを表示させたいです。

例えば山田であれば山田のシートに〇：2　△：2　×：5と表示。
表示場所は山田シート内のA1でもB1でもどこでもOKです。

・アンケート結果シートにはそれぞれの部下が判定した結果が以下のようにバラバラに入って来ます。B列・C列・D列はそれぞれ別の質問です。

　　　　A列　　B列　C列　　D列
1行目　山田　　〇　　〇　　×
2行目　山田　　×　　△　　×
3行名　山田　　△　　×　　×
4行目　鈴木　　△　　×　　〇
5行目　佐藤　　×　　〇　　△
6行目　佐藤　　〇　　△　　△
7行目　鈴木　　△　　×　　〇
8行名　佐藤　　×　　〇　　〇
9行目　鈴木　　△　　×　　×

COUNTIFとTEXTAFTERを組み合わせれば良いのかと思うのですがまったく出来ず(:_;)

分かる方がいらっしゃいましたら教えてくださいm(__)m

＜使用 Excel：Microsoft365、使用 OS：Windows10 ＞

 A列を並び替える

 Sheet（アンケート結果シート）

     |[A] |[B]|[C]|[D]|[E]   |[F] |[G] |[H]
 [1] |鈴木|△ |✕ |◯ |      |    |    |   
 [2] |鈴木|△ |✕ |◯ |      |    |    |   
 [3] |鈴木|△ |✕ |✕ |      |    |    |   
 [4] |山田|◯ |◯ |✕ |      |    |    |   
 [5] |山田|✕ |△ |✕ |      |    |    |   
 [6] |山田|△ |✕ |✕ |      |    |    |   
 [7] |佐藤|✕ |◯ |△ |      |    |    |   
 [8] |佐藤|◯ |△ |△ |      |    |    |   
 [9] |佐藤|✕ |◯ |◯ |      |    |    |   
 [10]|    |   |   |   |      |    |    |   
 [11]|    |   |   |   |      |    |    |   
 [12]|    |   |   |   |集計表|    |    |   
 [13]|    |   |   |   |      |◯  |△  |✕  
 [14]|    |   |   |   |鈴木  |◯:2|△:3|✕:4
 [15]|    |   |   |   |山田  |◯:2|△:2|✕:5
 [16]|    |   |   |   |佐藤  |◯:4|△:3|✕:2

 F14=Sheet2!F$13&":"&COUNTIF(Sheet2!$B$1:$D$3,Sheet2!F$13) → コピー
 F15=Sheet2!F$13&":"&COUNTIF(Sheet2!$B$4:$D$6,Sheet2!F$13) → コピー
 F16=Sheet2!F$13&":"&COUNTIF(Sheet2!$B$7:$D$9,Sheet2!F$13) → コピー

 名前ごとに集計の値をコピー値貼り付けてもいいし
 名前ごとに数式をコピーしてもいい。

 ※A列の並びと集計表の並びが同じであることを確認すること

 一例です。
（IT） 2024/03/19(火) 22:18:18

[[20240319125749]]
と関係するんですか。
（IT） 2024/03/19(火) 22:22:16

  A1セル =TEXTAFTER(CELL("filename",A1),"]")
  B1セル ={"〇","△","×"}
  B2セル =LET(r,アンケート結果!$A$1:$D$9,SUM((DROP(r,,1)=B1)*(TAKE(r,,1)=$A$1)))
  右にコピー(D2セルまで）

 　<山田 シート　結果例>
 行 __A__ _B_ _C_ _D_ 
  1 山田  〇  △  ×  
  2        2   2   5

 　<鈴木 シート　結果例>
  行 __A__ _B_ _C_ _D_
   1 鈴木  〇  △  × 
   2        2   3   4

  <佐藤シート　結果例>
 行  __A__  _B_  _C_  _D_
  1  佐藤   〇   △   × 
  2         4    3    2

（半平太） 2024/03/19(火) 22:38:50

IT sama,
ありがとうございます。確かにA列を並び替えればVlookで集計できますね！
集計結果が揃ったら試してみます！

半平太 sama、
ありがとうございます。はい、[[20240319125749]]の続きでのご相談でございました。ご提案頂いた方法をさっそく試してみたいと思います！

みなさま、いつも私の気づかない方法を提案してくださり本当にありがとうございますm(__)m
（ゆきんこ） 2024/03/20(水) 22:01:53

IT sama,
半平太 sama,

[[20240319125749]]について、コメント頂いたのはIT samaでございました汗
コメント欄を正しく読めておりませんでした、大変失礼致しました！！！

（ゆきんこ） 2024/03/20(水) 22:11:16

みなさま、教えて頂いた方法で完璧に集計することができました！！m(__)m
本当に心から尊敬でございます。本当にありがとうございました！！
（ゆきんこ） 2024/03/21(木) 15:30:57

コメント返信：

[ 一覧(最新更新順) ]

[[20240319170822]] 『シート名をキーにして別シートのデータをカウント』（ゆきんこ） ページの最後に飛ぶ

[[20240319170822]]　『シート名をキーにして別シートのデータをカウント』（ゆきんこ）　ページの最後に飛ぶ