[[20241210081251]]　『複数ファイルをまとめて印刷』（社会人）　ページの最後に飛ぶ

『複数ファイルをまとめて印刷』（社会人）

質問させてください。

複数のファイルをまとめて印刷したいのですが、ネットで以下のようなマクロを見つけました。

このマクロで動くのは確認していますが、すべてのファイルを7枚ずつ印刷したいです。

どのように変えればよいか教えていただきたいです。

'
'一括印刷マクロVer0.1
'
'デフォルトで設定したプリンタを使って、印刷を行います
'作者のEXCELが2007のため、バージョンの違いにより動かない可能性があります
'ご了承ください
'
'Ver0.0 リリース
'Ver0.1 変数の間違い修正,メッセージボックスの分岐の定義を明確化

Sub 一括印刷()

  '変数定義
  Dim strFilePath As String '印刷したいEXCELがあるパスを格納
  Dim strFileName As String '印刷したいEXCELファイルがあるパスを格納
  Dim checkSheet As Worksheet 'ワークシートを選ぶ用
  Set checkSheet = Worksheets("印刷内容確認用")

  Dim cntForPath As Long 'for用
  Dim cntForPrint As Long 'for用
  Dim answerMsg As Long 'メッセージボックス用

  answerMsg = MsgBox("印刷しますか？", vbYesNo, "印刷確認")

  If answerMsg = vbYes Then

    'ファイルパス取得
    strFilePath = ThisWorkbook.Path & "\印刷フォルダ\"
    strFileName = Dir(strFilePath & "*.*")
    checkSheet.Columns("A").ClearContents '確認シートの列(A)の文字削除

    cntForPath = 1

    Do Until strFileName = "" '確認シートにパス記入
      checkSheet.Range("A" & cntForPath).Value = strFilePath & strFileName
      cntForPath = cntForPath + 1
      strFileName = Dir()
    Loop

    '印刷
    cntForPrint = 1
    For cntForPrint = 1 To checkSheet.Cells(Rows.Count, 1).End(xlUp).Row
      Workbooks.Open Filename:=checkSheet.Range("A" & cntForPrint).Value '一括印刷フォルダにあるEXCELをオープン
      ActiveWorkbook.PrintOut '開いたEXCELを印刷
      ActiveWorkbook.Close savechanges:=False '開いたEXCELを閉じる
    Next cntForPrint

  ElseIf answerMsg = vbNo Then
    MsgBox ("印刷を中止します")
  End If

End Sub

＜使用 Excel：Excel2021、使用 OS：Windows11 ＞

 PrintOutメソッドを調べて下さい。「印刷部数」を指定する引数があります。
（xyz） 2024/12/10(火) 08:23:20

出来ました！

ありがとうございます。助かりました。

ActiveWorkbook.PrintOut Copies:=7 '開いたEXCELを印刷

これで7部印刷できました。
（社会人） 2024/12/10(火) 08:32:17

コメント返信：

[ 一覧(最新更新順) ]

[[20241210081251]] 『複数ファイルをまとめて印刷』（社会人） ページの最後に飛ぶ

[[20241210081251]]　『複数ファイルをまとめて印刷』（社会人）　ページの最後に飛ぶ