[[20250222152732]]　『2列おきの合計値をだしたい』（ななきち）　ページの最後に飛ぶ

『2列おきの合計値をだしたい』（ななきち）

=SUMPRODUCT((MOD(COLUMN(X9:CO9),2)=0)*X9:CO9)

と、入力しているのですが#VALUE!とエラーします。
理由が、分からずご教示願います

＜使用 Excel：Microsoft365、使用 OS：Windows11 ＞

 X9:CO9に文字列セルがあるかもしれません。
=SUMPRODUCT((MOD(COLUMN(X9:CO9),2)=0)*1,X9:CO9)
=SUMPRODUCT(N(ISEVEN(COLUMN(X9:CO9))),X9:CO9)
（んなっと） 2025/02/22(土) 16:12:43

 Microsoft365なら
=SUM(FILTER(X9:CO9,ISEVEN(COLUMN(X9:CO9))))
（どん） 2025/02/22(土) 16:19:09

=SUMPRODUCT((MOD(COLUMN(A1:Z1)-COLUMN(A1),2)=0)*A1:Z1)

（） 2025/02/22(土) 20:09:24

（どん）さま
ありがとうございます。
下記、式で表示させることができました

=SUM(FILTER(X9:CP9,ISEVEN(COLUMN(X9:CP9))))

上記で、項目１については２つおきの合計を出せたのですが
項目２について同じ式でやろうとしても合計が同じになってしまいまた詰まってしまいました
項目２は、Y9:CQ9 （下方向へ１６００行ほど）

本来やりたいことは、最終列の1つ手前までの合計がだしたいです。
さすがに、そんなことは関数では無理なのでしょうか？

（んなっと）さま

文字列だったかは、不明ですが範囲すべての数値にしました

（）さま
=SUMPRODUCT((MOD(COLUMN(A1:Z1)-COLUMN(A1),2)=0)*A1:Z1)
は、どうしてもできませんでした

（ななきち） 2025/02/22(土) 22:02:31

項目１
=SUM(FILTER(Z9:INDEX(Z9:CR9, 1, COUNTA(Z9:CR9) - 1), ISEVEN(COLUMN(Z9:INDEX(Z9:CR9, 1, COUNTA(Z9:CR9) - 1))) + (COLUMN(Z9:INDEX(Z9:CR9, 1, COUNTA(Z9:CR9) - 1)) = COLUMN(INDEX(Z9:CR9, 1, COUNTA(Z9:CR9) - 1)))))

項目２
=SUM(FILTER(AA9:INDEX(AA9:CS9, 1, COUNTA(AA9:CS9) - 1), ISEVEN(COLUMN(AA9:INDEX(AA9:CS9, 1, COUNTA(AA9:CS9) - 1))) + (COLUMN(AA9:INDEX(AA9:CS9, 1, COUNTA(AA9:CS9) - 1)) = COLUMN(INDEX(AA9:CS9, 1, COUNTA(AA9:CS9) - 1)))))

と、したのですが表示される値が両方とも項目１となり項目２が正しく動作しません。
ご教示お願いいたします
（ななきち） 2025/02/23(日) 09:24:29

＞項目１となり項目２が正しく動作しません。
当初の質問にはありません。
レイアウトを示されて説明されたらどうですか。

（レイアウト手抜き） 2025/02/23(日) 11:38:24

 項目２は右に１列ずれているから、

 ISEVEN　→　ISODD　じゃないですか？

（半平太） 2025/02/23(日) 12:21:14

コメント返信：

[ 一覧(最新更新順) ]

[[20250222152732]] 『2列おきの合計値をだしたい』（ななきち） ページの最後に飛ぶ

[[20250222152732]]　『2列おきの合計値をだしたい』（ななきち）　ページの最後に飛ぶ