[[20250416160323]]　『勤務者の常勤計算』（Teddy）　ページの最後に飛ぶ

『勤務者の常勤計算』（Teddy）

いつもお世話になっております。
勤務表なのでちょっと長いのですが、よろしくお願いします。

　　Ｄ　Ｅ　Ｆ　Ｇ　Ｈ　・・・AI　AJ　AK　AL
5　　　 1 　2 　3 　 4・・・・31
6 　　木　金　土　日・・・・土　
7　あ　休　Ｈ　Ｇ　休・・・・Ｉ　　　0.5　
8　い
9　う
10　え　I6　I6　休　休・・・・I6 　　 0.8　　0.3
11　お　Ｇ　Ｈ　Ｉ　・・・・・Ｈ　　　1 　 0.8
12　か　Ｈ　Ｈ　Ｈ・・・・・・Ｇ　　　1　　0.8
・
・
17　さ　　　　　　　　　　　　　　　　1　　0.8
・
・
20　せ　　　　　　　　　　　　　　　　0.5
・
・
24　つ
25　　　7.7　7.4・・・・

D列は社員名、５行目は日にち、６行目は曜日です。
職員の勤務はG、H、I、I6、休などで表現されています。
25行目には、「”え”がI6勤務の日はAK10にある数字（0.8）の値、”お”がG、H、I勤務の日はAK11にある数字（1）の値で計算する」という内容の関数（=SUMIFS($AK$7:$AK$20,E7:E20,"?*",E7:E20,"<>休",E7:E20,"<>年",E7:E20,"<>特")を入力しています。
今回、新たに「LI6」と「LH」という勤務形態ができてしまいまして、LI6勤務とLH勤務の日はAK列の数字ではなくAL列の数字（0.3もしくは0.8）を用いて計算する式に変更したいと思っています。
ちなみに、LI6は”え”さんのみ、LHは”お”さんから”さ”さんまでです。

すみません。説明が悪く伝わりにくいかもしれませんがどうぞよろしくお願いします。

＜使用 Excel：Excel2021、使用 OS：Windows11 ＞

「内容の関数」の式でAL列を参照するように変更するだけではダメなんですか。
（?） 2025/04/16(水) 17:19:42

すみません。具体的にその変更をお示しいただきたいので、よろしくお願いします。
（Teddy） 2025/04/16(水) 18:10:49

 「LI6」または「LH」の場合、AL列の数字を合計
 =SUM(SUMIF(E7:E20,{"LI6","LH"},$AL$7:$AL$20))

 これで合っているのなら、現在の式にこの式を足すとか。
（ＴＩ） 2025/04/16(水) 18:26:48

重ね重ねすみません。
TIさんが示してくださった式を足すと、
＝SUM(SUMIF(E7:E20,{"LI6","LH"},$AL$7:$AL$20)) SUMIFS($AK$7:$AK$20,E7:E20,"?*",E7:E20,"<>休",E7:E20,"<>年",E7:E20,"<>特"）ということであっていますでしょうか？
ちなみに、Lがついた誰か一人だけがAL列の数値になり、それ以外の人は通常通りのAK列の数値で計算したいのですが・・・
（Teddy） 2025/04/16(水) 18:37:25

 それ、足していないのでは？ 
 足すというのは ＝（回答の式）+（現在の式）ということですよ。

 合計が合っているかどうかは、そちらで確認してください。
 こちらではわかりません。 
（ＴＩ） 2025/04/16(水) 19:03:43

 ＞Lがついた誰か一人だけがAL列の数値になり、それ以外の人は通常通りのAK列の数値

 　　　　　　　　　　　　　　　　　　　　　　　　　　　　すると、こうかな？
       　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　    ↓
 =LET(r,E7:E20,SUMIFS($AK$7:$AK$20,r,"?*",r,"<>休",r,"<>年",r,"<>特",r,"<>L*")+SUMIF(r,"L*",$AL$7:$AL$20))

（半平太） 2025/04/16(水) 20:34:05

半平太様
教えていただいた式でうまくいきそうです。
明日、職場で再確認してみます。

TI様
ご教授ありがとうございました。

お二方とも、もし明日うまくいきませんでしたら再びここに来たいと思っています。
ご指導、よろしくお願いします。

（Teddy） 2025/04/16(水) 21:23:43

 あ～、「現在の式」から「LI6」と「LH」を除外しないとダメでしたね。

 AK列の数字を足すのが「G」「H」「I」「I6」の4つだけなら

 =SUM(SUMIF(E7:E20,{"G","H","I","I6"},$AK$7:$AK$20))+SUM(SUMIF(E7:E20,{"LI6","LH"},$AL$7:$AL$20))

 =SUM(SUMIF(E7:E20,{"G","H","I*"},$AK$7:$AK$20))+SUMIF(E7:E20,"L*",$AL$7:$AL$20)
　
（ＴＩ） 2025/04/16(水) 23:46:09

コメント返信：

[ 一覧(最新更新順) ]

[[20250416160323]] 『勤務者の常勤計算』（Teddy） ページの最後に飛ぶ

[[20250416160323]]　『勤務者の常勤計算』（Teddy）　ページの最後に飛ぶ