[[20250807165209]]　『〇月の第〇週に何日あるかを求めたい』（＊＊＊＊）　ページの最後に飛ぶ

『〇月の第〇週に何日あるかを求めたい』（＊＊＊＊）

2025年１月
第１周５日
第２週７日
第３週７日
第４週７日
第５週５日
というふうに、
各月の第何週には何日あるという関数で求めることは可能でしょうか？

＜使用 Excel：Excel2021、使用 OS：Windows10 ＞

 こんなのではどうだろうか？

   A1         B1
 1 2025/1/1   1
 2
 3  1         5
 4  2         7
 5  3         7
 6  4         7
 7  5         5
 8  6         0

 A1セルに2025/1/1と数え始める日付を入力。
 B1セルに
 =WEEKNUM(A1)
 と入力してその日が年の何週目かを求める。
 A3セルからA8セルまでに1から6とその月で何週目かを入れる。
 そしてB3セルに
 =SUMPRODUCT((WEEKNUM(ROW(INDIRECT($A$1&":"&EOMONTH($A$1,0))),2)=$B$1+A3-1)*1)
 と入力してB8セルまでフィルコピーではどうだろうか？

（ねむねむ） 2025/08/07(木) 17:28:19

ねむねむさん

ありがとうございました！

成功しました！！

今後とも、よろしくお願いいたします！！！
（＊＊＊＊） 2025/08/07(木) 18:53:56

 おっと、一カ所修正で。

 B1セルの式は
 =WEEKNUM(A1,2)
 としてくれ。
（ねむねむ） 2025/08/07(木) 20:57:24

 愚直な別案を参考までに挙げておきます。

     A      B       C       D
  1  年    月  月内週    日数
  2  2025   1       1       5
  3         1       2       7
  4         1       3       7
  5         1       4       7
  6         1       5       5
  7         1       6       
  8         2       1       2
  9         2       2       7
 10         2       3       7
 11         2       4       7
 12         2       5       5
 13         2       6       
 14         3       1       2
 15         3       2       7
 16         3       3       7
 17         3       4       7
 18         3       5       7
 19         3       6       1
            (以下同様)

 D2セルに下記を入れ、D3以下にコピーして下さい。
   ( =以下を（つまり最初の半角スペースを除いて）コピーし、
     D2セルを選択して、数式バーに貼り付けて、Enterして下さい。 )

 =LET(
     年,         $A$2,
     月,         B2,
     月初日,     DATE(年,月,1),
     月日数,     DAY(EOMONTH(月初日,0)),
     seq年月日,  SEQUENCE(月日数,1,月初日),
     seq第何週,  WEEKNUM(seq年月日,2),
     指定週,     WEEKNUM(月初日,2)+C2-1,
     抽出,       FILTER(seq第何週,seq第何週=指定週,NA()),
     IFERROR(ROWS(抽出),"")
 )

 データを増やせば、いくらでも続けられます。

 #  Excel2021ではLAMBDA,BYROWなどが無いので、計算効率・メモリー効率は
 #  Excel365に比べると悪いかも知れません。
（xyz） 2025/08/08(金) 07:24:55

コメント返信：

[ 一覧(最新更新順) ]

[[20250807165209]] 『〇月の第〇週に何日あるかを求めたい』（＊＊＊＊） ページの最後に飛ぶ

[[20250807165209]]　『〇月の第〇週に何日あるかを求めたい』（＊＊＊＊）　ページの最後に飛ぶ