[[20260409161505]]　『とびとびセルの合計』（ヤマザキ）　ページの最後に飛ぶ

『とびとびセルの合計』（ヤマザキ）

合計値を出したいです。
セルQ1+R1の合計をA1に、S1+T1の合計をB1へ示したいのですが
Ｑ列以降は２列づつ合計し、Ａ列からＧ列までに順に合計値を入れたいです
初心者ですみませんが、おねがいします。

＜使用 Excel：Microsoft365、使用 OS：Windows11 ＞

 A1セルに
 =MAP(A1:G1,LAMBDA(x,SUM(OFFSET(Q1:R1,,(COLUMN(x)-1)*2))))
 と入力するのではどうだろうか？
（ねむねむ） 2026/04/09(木) 16:41:55

 つい以前の癖で連番をも求めるのにCOLUMN関数やROW関数を使ってしまう。

 =MAP(SEQUENCE(,7,0)*2,LAMBDA(x,SUM(OFFSET(Q1:R1,,x))))
 でも。
（ねむねむ） 2026/04/09(木) 16:48:15

 おっと
 =MAP(SEQUENCE(,7,0,2),LAMBDA(x,SUM(OFFSET(Q1:R1,,x))))
 でも。
（ねむねむ） 2026/04/09(木) 16:50:06

基本が弱くてすみません
式にある　Ｘ　の意味がわかりません
解説お願いします

（ヤマザキ） 2026/04/09(木) 17:36:45

 G1セルは SUM(AC1:AD1)の結果が入ればいいんですよね 
 =BYCOL(WRAPCOLS(Q1:AD1,2),SUM)
 ではどうでしょう
（´・ω・`） 2026/04/09(木) 17:40:11

 lambdaは関数を定義する関数なので
 sum()←このsumの部分を作れます。
 sum(第1引数,第2引数...,) は 第1引数 + 第2引数... っていう処理を呼び出す関数です。

 lambda(第1引数,[第二引数 or 計算式]...,) で 新しい関数を作れます。
 第1引数を受ける変数名は自由につけれます。(すでに使われいる名前はNGになったりならなかったり)

 LAMBDA(x,SUM(OFFSET(Q1:R1,,x)))) の場合は
 xは好きにつけた名前

 xの中身はmapで渡しているので 0 2 4 6.... っていう数値

（ちくわ） 2026/04/09(木) 18:13:19

多数のご指導ありがとう御座いました。
うまくいけそうなので、一旦終了といたします。
（ヤマザキ） 2026/04/10(金) 13:06:53

コメント返信：