[[20260807162903]]　『SORTBY関数について』（匿名）　ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) |

| 全文検索 | 過去ログ ]

『SORTBY関数について』（匿名）

=EB2Data(A2,B3:F9,H2,I3:T9,V2,W3:AB9)

EB2Dataという関数は2列n行の配列を返す自作のワークシート関数です。
戻ってきた配列に対して、SORTBYを使おうと思って色々検索したのですが、
範囲の例ばかりで、配列の例を見つけることができませんでした。

=SORTBY(EB2Data(A2,B3:F9,H2,I3:T9,V2,W3:AB9), 配列の1列目の指定方法がわからない, 1, 配列の1列目の指定方法がわからない, -1)

第一引数が範囲の場合は、第二引数も範囲を指定するのはわかったのですが、
今回のように関数によって戻ってきた2次元配列を並び換える方法がわかりません。

返ってきた配列を1列目の昇順、2列目の降順と並び換えたいのですが、
どなたかご存じの方教えていただけますでしょうか。

よろしくお願いいたします。

＜使用 Excel：Microsoft365、使用 OS：Windows11 ＞

 うまくいくかはわからないが。

 =SORTBY(EB2Data(A2,B3:F9,H2,I3:T9,V2,W3:AB9), INDEX(EB2Data(A2,B3:F9,H2,I3:T9,V2,W3:AB9),0,1), 1, INDEX(EB2Data(A2,B3:F9,H2,I3:T9,V2,W3:AB9),0,2), -1)
 ではどうだろうか？

 一応
 =SORTBY({6,"a";5,"b";1,"c"},INDEX({6,"a";5,"b";1,"c"},0,1),1)
 と入力すると

 1  C
 5  B
 6  C
 という結果になった。
（ねむねむ） 2026/08/07(金) 17:06:14

 もし上がうまくいくのであればLETを使って

 =LET(HANNI,EB2Data(A2,B3:F9,H2,I3:T9,V2,W3:AB9),SORTBY(HANNI, INDEX(HANNI,0,1), 1, INDEX(HANNI,0,2), -1))
 でもいいのかな？
（ねむねむ） 2026/08/07(金) 17:11:58

ねむねむ様
ご回答ありがとうございます。
=LET(HANNI,EB2Data(A2,B3:F9,H2,I3:T9,V2,W3:AB9),SORTBY(HANNI, INDEX(HANNI,0,1), 1, INDEX(HANNI,0,2), -1))
でできました。

そうですね。INDEX関数がありました。

（匿名） 2026/08/07(金) 17:21:32

 =SORT(EB2Data(A2,B3:F9,H2,I3:T9,V2,W3:AB9),{1,2},{1,-1})

 で同じ結果が得られるケースではないかと思うのですが、どうなんでしょうか？

（半平太） 2026/08/07(金) 18:01:44

コメント返信：

[ 一覧(最新更新順) ]

[[20260807162903]] 『SORTBY関数について』（匿名） ページの最後に飛ぶ

[[20260807162903]]　『SORTBY関数について』（匿名）　ページの最後に飛ぶ