『[20060311]を[土曜日]と表すには。』（たき）
A1に[20060311]と入力しB1に[土曜日]と表示させる方法はあるでしょうか。
初心者的な内容をお尋ねしますが、
宜しくお願い致します。

環境
・エクセル2002
・win2000
----
 =TEXT(WEEKDAY(--TEXT(A1,"00!年00!月00!日")),"aaaa")
でどうですか？
(ROUGE)
----
コピーしてB1に貼り付けてみましたが、
表示されません。
すみません。（たき）
----
 コピーしてB1に貼り付けてみましたら、表示されました。
 A1に入力したのでしょうか？(MOCHI)
----
 ◆こんな方法も！
 =TEXT(TEXT(A1,"0000-00-00"),"aaaa")
 (Maron)

----
 衝突しました。
 以下、衝突前。

 なぜでしょう？
 ちなみに、これでもOKでした。
 B1=TEXT(--TEXT(A1,"00!年00!月00!日"),"aaaa")
(ROUGE)
----
 こんにちは
ひょっとして
A1に[20060311]と入力ってことはないですよね？
もしそうなら、ROUGE さんの式をそのままお借りして
=TEXT(WEEKDAY(--TEXT(MID(A1,2,8),"00!年00!月00!日")),"aaaa")
　　　　　　　　　　　　　　　　　　　　　　　(oni)
----
申し訳ありません。
入力したセルを間違えていました。
ROUGEさん、ROUGEさん、Maronさん、ありがとうございます。（たき）
----
横からすみません。
参考に関数の意味をきかせてください

↓この--というのはどういう意味でしょうか

 --TEXT(A1,"00!年00!月00!日")

（まりーん）
----
 過去ログですm(｡＿｡；))m 

[[20040530061813]] 『「--」と「！」の意味?』(masabou5)

 （ぼう）
----
（ぼう）さんありがとうございました。
よくわかりました

（まりーん）

----
 解決済みのようですが、
　
=TEXT(--TEXT(A1,"[<19000000]!0;[<99991232]0000!/00!/00;!0;!0"),"aaaa;;;")
　
もしくは
　
=--TEXT(A1,"[<19000000]!0;[<99991232]0000!/00!/00;!0;!0")　として
表示形式のユーザー定義で　"aaaa;;;"　。
　
シリアル値から直接曜日を求めることができるので、WEEKDAY関数は必須ではないかも
しれません。
(みやほりん)(-_∂)b
----
 必須ではないですね・・・＿/￣|○ il||li
アップした後に気づきました。
曜日＝WEEKDAY関数という短絡思考をして、修正したものをアップしようとしたら
すでにMaronさんからの回答もついていておろおろしていたところです。
(ROUGE)
----
 お聞きしたいのですが、これから入力するのであれば、
2006/03/11 と入力し、セル書式でユーザ定義　aaaa では、まずいのでしょうか？
(名前　ワスレ)
----
 ◆ワスレさん、それでよいのですが、曜日だけを表示されることってあるでしょうか！
 ◆もし、下のように日付の横に曜日を表示したい場合などは！

 　　　　　A	B
 1　　　2006/3/11	土

 B1=TEXT(A1,"aaa")
 (Maron)

----
 (Maron)様
その場合は、ユーザ定義を　yyyy/mm/ddaaaa
とかにすれば良いのではないでしょうか
(名前　ワスレ)

----
 ◆文字の場合！
 =TEXT(A1,"aaa")
 ★表示形式は、標準

 ◆シリアル値の場合！
 =A1
 ★表示形式は、　aaaa　例：土曜日、　aaa   例：土、　　(aaa)　　例：(土)

 ◆表示形式を、yyyy/mm/ddaaaa　にすると、　2006/3/11土曜日　になります！
 (Maron)
----
 ワスレさん
仰ることはごもっともですが、すでに膨大なデータがある場合、やはり変換が必要です。
再入力では時間もかかりますし、ミスも出やすくなります。
(ROUGE)
----
 ◆すでに、ご存知かもしれませんが、入力済みの、20060311　を、2006/03/11 にする方法です！
 ◆大量に変換するには、大変便利な方法ですよ！
 ■手順■
 １）メニューバーの、［データ］−［区切り位置］を選択します！
 ２）「区切り位置指定ウィザード1/3　次へ」→「2/3　次へ」→「3/3　列のデータ形式の、日付にチェックして、完了」
 ◆不要ならば、無視してください！
 (Maron)
----
 (たき)さんの、状況が解らないままに余計なことを書いてしまいました。
今一度、質問内容を見直したら、Ａ列に入力し、Ｂ列に表示でした。
(名前　ワスレ)