『V　Look UPの質問です』（なお）

売上予算シート

店番	　店名	　4月	　　5月	　　6月

500	　横浜　	　13,500	　14,000	　14,500

510	　新宿	　37,500	　39,000	　39,000

530	　池袋　	　38,500	　39,000　　38,500



シートB　

=VLOOKUP(B8,売上予算シート!A:N,IF(OR($D$2=1,$D$2=2,$D$2=3),$D$2+11,$D$2-1))

D2に月を打ち込む

B8に店番を打ち込みます


数字が出てくるのですが、違う数字を読み込んでしまいます。
IF〜がよくわからないまま見よう見まねでつくったので、間違いがわかりません・・
----
 ヘルプの抜粋です。
 //////////////////////////////////////////
 VLOOKUP(検索値,範囲,列番号,検索の型)
 ・検索の型に TRUE を指定した場合、
範囲の左端の列のデータは、昇順に並べ替えておく必要があります。
並べ替えないと、正しく計算が行われません。
 ・検索の型 に FALSE を指定した場合は、
範囲のデータを並べ替えておく必要はありません。 

 検索の型
検索値と完全に一致する値だけを検索するか、その近似値を含めて検索するかを、論理値で指定します。
''TRUE'' を指定するか''省略''すると、
検索値が見つからない場合に、検索値未満で最も大きい値が使用されます。
''FALSE'' を指定すると、
検索値と完全に一致する値だけが検索され、見つからない場合はエラー値 #N/A が返されます。

 解説 
 検索の型に TRUE を指定し、検索値が見つからない場合は、
検索値未満で最も大きい値が使用されます。 
検索値が範囲の左端の列の最小値より小さい場合、エラー値 #N/A が返されます。 
 検索の型に FALSE を指定し、検索値が見つからない場合は、
エラー値 #N/A が返されます。
 //////////////////////////////////////////
 ご提示の式は、検索の型　を省略されてますね。
(sin)
----
ありがとうございます。

TRUEをいれても、同様なのです・・

＞IF(OR($D$2=1,$D$2=2,$D$2=3),$D$2+11,$D$2-1))
 
D2に月を入れると、なぜ1〜3月の場合は11をプラスし、
4月〜は1を引くのかがよくわかりません。

実際、この関数で動いているシートを見て
そこから拝借したので、間違えてはいないと思うのですが・・

（なお）
----
 売上予算
   A      B       C        D        E      ・・・ N
1 店番 　店名 　 4月 　　 5月 　　 6月     ・・・1月 → C1:N1のユーザー定義を 0"月"として数値のみ入力します。
2 500 　 横浜　 13,500 　14,000 　14,500 　・・・
3 510 　 新宿 　37,500 　39,000 　39,000   ・・・
4 530 　 池袋　 38,500 　39,000　 38,500   ・・・

 SheetB
 D2に月 →　5　(ユーザー定義を 0"月"としておきます。）
 B8に店番を打ち込みます →　500
 C8=14,000
 ↓
 C8=VLOOKUP(B8,売上予算!A:N,IF(OR($D$2=1,$D$2=2,$D$2=3),$D$2+11,$D$2-1),FALSE)
 もしくは
 C8=VLOOKUP(B8,売上予算!A:N,MATCH($D$2,売上予算!$A$1:$N$1,0),FALSE)

 ※ユーザー定義を用いない場合は、双方とも月まで入力してください。(gon-2)
 
 【追記】
 1月の場合は 1+11=12 で 12番目の列を指定（つまり1月の列）
 4月の場合は 4-1=3 で 3番目の列を指定（つまり4月の列）
----
 ＞TRUEをいれても、同様なのです・・ 
 完全に一致する店番号を探したいときは
 TRUEを入れるのではなく、FALSEを入れてみて下さい。
 上手く行きますか？

 ＞D2に月を入れると、なぜ1〜3月の場合は11をプラスし、 4月〜は1を引くのか
 売上予算シートの、A列から数えて　4月は 三 列目に出てきますよね。
 D2に「4」と入っていたら、 三 列目を見たいので、1を引きます。
 D2に「12」と入っていたら、十一列目を見たいので、やっぱり 1を引きます。
 D2に「1」と入っていたら、十二列目を見たいので、11を足します。
 D2に「3」と入っていたら、十四列目を見たいので、やっぱり 11を足します。

 売上予算シートを見ると、A列から数えて　探す月が
 「1〜3」の場合は、11を足した列目がその月の列で
 「4〜12」の場合は、1を引いた列目がその月の列
 になっていますよね。

 なっていない場合は、IF関数の方にも問題がありそうです。

 (HANA)
----
ありがとうございます！

(gon-2)さん　(HANA)さん

的確な説明ありがとうございます。
助かりました。

数字もきれいにでてきました（なお）