『今エクセル使ってるんですけど 

=IF(I13=0,C5,
 IF(I13=5,C6,
 IF(I13=10,C7,
IF(I13=15,C8,
IF(I13=20,C9,
IF(I13=25,C10,
IF(I13=30,C11,
IF(I13=35,C12,
IF (I13=40,C13,
IF(I13=45,C14,
IF(I13=50,C15,
IF(I13=55,C16,
IF(I13=60,C17,
IF(I13=65,C18,
IF(I13=70,C19,
IF(I13=75,C20,
IF(I13=80,C21,
IF(I13=85,C22,
IF(I13=90,C23,
))))))))))))))))))) 


これを短く出来ませんか？長くて入らないそうです・・ 』（ナゾの戦士）
----
 B列は空いているのですか？
 空いているなら、0,5,10,15等を入力し
 VLOOKUP関数を使用するのはどうでしょう。
http://www.excel.studio-kazu.jp/lib/e1tw/e1tw.html

 (HANA)
----
 こんな感じでリストを作成し
 	[B]	[C]
[5]	0	あ
[6]	5	い
[7]	10	う
[8]	15	え
[9]	20	お
[10]	25	か
[11]	30	き
[12]	35	く
[13]	40	け
[14]	45	こ
[15]	50	さ
[16]	55	し
[17]	60	す
[18]	65	せ
[19]	70	そ
[20]	75	た
[21]	80	ち
[22]	85	つ
[23]	90	て
 結果を表示したいセルに
=IF(AND(I13<>"",COUNTIF($B$5:$B$23,I13)),VLOOKUP(I13,$B$5:$C$23,2,FALSE),"")

 (HANA)
----
 ◆こんな方法もありかな
 =IF(OR(I13="",MOD(I13,5),I13>90),"",INDIRECT("C"&I13/5+5))
 (Maron)
----
 設例と同じ出力でよいのなら
 負の値はないと仮定して

 =IF(AND(MOD(I13,5)=0,I13<=90),INDEX($C$5:$C$23,I13/5+1),)
 でもよいような。

 >これを短く出来ませんか？長くて入らないそうです・・ 
 Excel2007ではあっさり入りました。

 (穂高)