『納入日をカレンダーのような一覧表にする方法』（ういろ）

過去ログを探したのですが見つけられなかったので質問させて頂きます。

下記のような「元データ」から矢印下のような形に変換するような方法はあるのでしょうか？

エクセルのバージョンは2003です。

「元データ]
     A     B     C     
  1 品番　納期　台数
  2  A　 11/4    50   
  3  A   11/9   100   
  4  A   11/10  250   
  5  A   11/16   50   
  6  B   11/4　 150   
  7  B　 11/5   150   
  8  B   11/24  450   
  9  C   11/16  100   
  10 C   11/17   20   
  11 D   11/16　 30
  12 E   11/4   120   
  13 E   11/16  180   
  14 E   11/17  120   
  15 E   11/24　300
  〜 ‥   ‥　　‥
  99 AA  11/4　100

        ↓

 品番　　月合計　　11/1　2　3　4・・・・・16　17　18・・・
 　A　　　450　　　　　　　　　 50　　　　250　　　　　
　 B　　　750　　　　　　　　　150　　　　 　　　　　
　 C　　　120　　　　　　　　　　　　　   100  20　　　　　
　 D　　　 30　　　　　　　　　            30　　　　　
　 E　　　620　　　　　　　　　120　　　　180 120　　　　　
　 〜　　　　　　　　　　　　　　　 　　　　　　
　 AA　　 100　　　　　　　　　100　　　　　　　　　　
----
 ＞矢印下のような形
 で、品番の部分（A,B,C,・・・・）とカレンダーの部分（11/1,2,3,・・・）は
 事前に出来ていると考えれば良いのでしょうか？

 それとも、何もない状態から
 集計をするのでしょうか？

 (HANA)
----
説明不足で申し訳ありません。

品番、カレンダーの枠がある所への集計で考えています。

さらに可能ならば月によっては受注の無い品物もあるので数字が入らなかった行を非表示に出来ると最高なのですが・・

（ういろ）
----
 元データがSheet1のA1セルから
 集計後の表がSheet2のA1セルから配置されており
 日付部分はどちらもシリアル値で入力されている場合

 Sheet2のC2セルに
=SUMPRODUCT((Sheet1!$A$1:$A$100=$A2)*(Sheet1!$B$1:$B$100=C$1),Sheet1!$C$1:$C$100)
 の式をいれ、セルの書式設定で　表示形式を　#,##0;-#,##0;;@　に変更後
 必要範囲にフィルドラッグ（C2セルをコピペ）して下さい。

 ＞数字が入らなかった行を非表示に
 これは数式では出来ませんので
 B列にオートフィルタ等を設定して絞り込んでください。

 (HANA)
----
HANA様

的確な回答ありがとうございました。


（ういろ）

----
すみません、追加での質問なのですが

=SUMPRODUCT((Sheet1!$A$1:$A$100=$A2)*(Sheet1!$B$1:$B$100=C$1),Sheet1!$C$1:$C$100)

 上記式の $A2 の部分を複数条件にすること
 例えば"りんご" "バナナ" "いちご" 等のフルーツの合計を
  求めるようにする事は可能でしょうか？
 

 うまく言葉では伝えられないので目的は下記のようにしたいのですが・・

    A         B       C     
  1 品番　   納期　 個数
  2 りんご　 11/4    50   
  3 バナナ   11/9   100   
  4 いちご   11/10  250   
  5 いちご   11/16   50   
  6  B       11/4　 150   
  7  B　     11/5   150   
  8  B       11/24  450   
  9  C       11/16  100   
  10 C       11/17   20   
  11 D       11/16　 30
 

        ↓

 品番　　　　月合計　　11/1　2　3　4・・・・・16　17　18・・・
 フルーツ　 　450　　　　　　　　　 50　　　　250　　　　　
 根野菜　　　 750　　　　　　　　　150　　　　 　　　　　
 葉野菜　　　 120　　　　　　　　　　　　　   100  20　　　　　
　D　 　　　　 30　　　　　　　　　            30　　　　　　　　　　

(ういろ）
----
 もう一つ列を作って（D列にでも）
 集計するグループを書くようにした方が
 良いと思いますよ。

 グループは、一覧表を作って
 VLOOKUP関数を仕込んでおく等で
 入力の簡素化ははかれると思います。

 (HANA)
----
 HANA様　

 回答ありがとうございます。
 今まで数式など殆ど使用したことがなかったので
 過去ログをみても一人では応用することが出来ず
 困っておりました。

 Sheet3に下記のような一覧表を作って
   A         　B          
  1 りんご　　フルーツ
  2 バナナ　　フルーツ
  3 いちご  　フルーツ
  4 大根   　 根野菜
  5 人参   　 根野菜


 Sheet1のD列に下記式を入れて
  =VLOOKUP($A$1:$A$100,Sheet3!$A$1:$B$100,2,FALSE)
 
 前回ご教示して頂いた式を下記のように変更したところ
 =SUMPRODUCT((Sheet1!$D$1:$D$100=$A2)*(Sheet1!$B$1:$B$100=C$1),Sheet1!$C$1:$C$100)

 考えていたような表を作ることが出来ました。

----
 えっと、VLOOKUP関数の式が一寸おかしい。。。かな？
 と思います。

 D1セルには
=VLOOKUP($A1,Sheet3!$A$1:$B$100,2,FALSE)
         ~~~A1セルの値を検索値
 の様にしておかれるのが良いと思います。

 また、A列が未入力セルだった場合 #N/A エラーが
 表示されると思いますので、
 少しエラー処理を入れておいても良いかもしれません。
=IF($A1="","",VLOOKUP($A1,Sheet3!$A$1:$B$100,2,FALSE))
 こんな感じで。

 (HANA)
----
 HANA様

 返信ありがとうございます。

 さっそく修正してエラー処理しました。

 （ういろ）