『VLOOKUPでの足し算』（じょう）


 sheet1
     A       B    C    D    E    F
 1　氏名　　4月  5月  6月  7月  8月・・・・
 2　山田　　 2　  3　  3    1    9
 3　佐藤　　 1　  5　  8    2    6
 4  川上　　 7　  2　  4    8    3

 ・
 ・
 ・

 sheet2
      A    B    C
 1　氏名　合計
 2　佐藤　 36
 3　山田　 18
     ・
     ・
     ・
     ・
 
 と出るようにしたいのですが。
 簡単に言うと

 sheet2 B2=VLOOKUP(C3,H21.1学期,2)+VLOOKUP(C3,H21.1学期,3)+VLOOKUP(C3,H21.1学期,4)+VLOOKUP(C3,H21.1学期,5)+VLOOKUP(C3,H21.1学期,6)+VLOOKUP(C3,H21.1学期,7)

 (【１学期】はsheet1の名前定義です)

 こういう事なのですが、もっと短く簡単な式にはならないでしょうか？
 よろしくお願いいたします。
----
 SUMPRODUCT関数でしょうか？？？
　
 それとも、もしかしてこういうことでしょうか？
　
 Sheet2
 B2 =SUM(OFFSET(Sheet1!$A$1,MATCH($A2,Sheet1!$A$2:$A$4,),1,,12))
 （キリキ）（〃⌒o⌒)b
----
ピボットテーブルでもできますね。

（黒バラ）
----
 （キリキ）さま

  上記式 B2 =SUM(OFFSET(Sheet1!$A$1,MATCH($A2,Sheet1!$A$2:$A$4,),1,,12))

 最後の【1】【12】の意味を教えてください。
 説明には【列】【幅】とでたのですが・・・。
 いまいちわかりません。

 ちなみにSUMPRODUCTの場合はどうなるのでしょうか？


 （黒バラ）さま

 ピボットで集計した表を加工したものなのですが
 最初に作ったピボットの【集計】を〔表示しない〕にしてしまったのですが
 どうやっても再表示できなくて・・・。


 （じょう）

                                                                   
----
 >最後の【1】【12】の意味を教えてください。
 >説明には【列】【幅】とでたのですが・・・。
　
 OFFSET関数のヘルプをご覧になっていただいたようなので、
 「列」と「幅」の事だけ確認してみましょうｂ
　
'' OFFSET(基準,行数,列数,高さ,幅)''
'' ''「列」と「幅」は、''「基準」''からどうなるかを言っています。
'' 「基準」''から、'''「列」'''（下にいくつ）移動して、'''「幅」'''（いくつの領域）分ということになります。
　
 例題の佐藤さんでは、
 SUM(B3:M3)
 をしていることと同じになります。
　
 ※ここでの「12」は、年間のことだと思い、「12」にしてあります。
 （キリキ）（〃⌒o⌒)b


----
 （キリキ）さま

 おはようございます。

 やってみましたが、これです。できました♪
 でもいまいちやっぱりわからないのですが、

 >「基準」から、「列」（下にいくつ）移動して

 この場合↑【基準】=〔氏名〕ということですよね。
 下に１つ移動して・・・という事になると思うのですが
 【基準】から、１行ずつ氏名を探していくという事ですか？

 SUMPRODUCTも考えてみたのですが、
 氏名を探し出すという事でVLOOKUPをSUMPRODUCTにくっつければよいのでしょうか？

 （じょう）



----
 >この場合↑【基準】=〔氏名〕ということですよね。
 >下に１つ移動して・・・という事になると思うのですが
 >【基準】から、１行ずつ氏名を探していくという事ですか？
 氏名から、MATCH関数で「下に何個目」かを調べているわけです。
　
 >SUMPRODUCTも考えてみたのですが、
 >氏名を探し出すという事でVLOOKUPをSUMPRODUCTにくっつければよいのでしょうか？
 SUMPRODUCT関数もでしたね＾＾
　
 SUMPRODUCT関数だったら、もっと簡単に出来そうです。
 Sheet2
 B2 =SUMPRODUCT(($A2=Sheet1!$A$2:$A$4)*(Sheet1!$B$2:$M$4))
　
 （キリキ）（〃⌒o⌒)b

----
 他の回答で解決すると思いますので、参考までに

 
 OFFSET関数(揮発性のため)が嫌いなので
 =SUM(INDEX(Sheet1!$B$2:$F$4,MATCH(A2,Sheet1!$A$2:$A$4,),))


  >B2 =SUMPRODUCT(($A2=Sheet1!$A$2:$A$4)*(Sheet1!$B$2:$M$4))
  B2 =SUMPRODUCT(($A2=Sheet1!$A$2:$A$4)*Sheet1!$B$2:$M$4)
 括弧が一つ必要ないかな


 VLOOKUP関数を使用すると
 =SUMPRODUCT(VLOOKUP(A2,Sheet1!$A$2:$F$4,{2,3,4,5,6},0))

 提示された式にあわせると
 =SUMPRODUCT(VLOOKUP(C3,H21.1学期,{2,3,4,5,6},0))

 因みに、VLOOKUP関数の「検索の型」について調べてみましょう

 By
----
 Sheet1の方で合計を計算させて、その列をSheet2から
 VLOOKUP関数で検索するのではいけないのですかね？
　
（純丸）(o^-')b

----
 みなさま、回答ありがとうございます。
 問題の表が（キリキ）さまの最初に提示いただいた式で完成していたため、
 油断しておりました。

 （キリキ）さま

 丁寧にご説明していただき、本当にありがとうございます。
 何となくわかりました♪
 でも、きっと何度も使っていかないと本当の意味での理解にはつながらなさそうなので
 色々と試してみたいと思います。



 Byさま

 こんなに利用できる式があるのですね！！びっくりです。
 早速これから全て試してみます。


 （純丸）(o^-')bさま

 全然その方法でもいいんです。
 でもあまりにも横に長い表だったので、sheet2に直接答えを出せないかな・・・と思いまして。

 やっぱりそう思っちゃいますよね。


 みなさま、本当に勉強になりました。(じょう)