『エクセル2007 のチェックボックスのリンク」設定について』（おすぎさん）

エクセル2007 のチェックボックスのリンク」設定についての質問です。

作成したチェックボックスの下のセルにリンクを設定をしたいのですが、
チェックボックスの数が数個くらいなら１個ずつリンク設定で余り時間も要せずに
できますが、数十個のチェックボックスのリンク設定をする必要がある場合、
一度に、全チェックボックスのリンク設定する方法があれば、教えてください。
使用OS はVISTA 、使用エクセルは2007 です。』
（おすぎさん）

 −−−−−−−−−−−−−−−−−−−−−−−−−−−−−−−−−−−−

[[20110302225514]]質問の補足説明です。

質問の書き方が不十分でしたので補足致します。



行＼列   　　A　- - - - - - - B      - - - - - - -  N

1  

2   チェックボックス1  　チェックボックス2   - - -チェックボックスｎ

3    上記　１のリンク　　上記　2のリンク　　　　　上記　ｎのリンク

4

5　チェックボックスn+1  チェックボックスn+2 - - -チェックボックスn+n

6  上記n+１のリンク　　 上記n+2のリンク　　　　  上記n+ｎのリンク

7

上記のように
チェックボックスをn+n 個作成し、それぞれのチェックボックスの下のセルに
その結果のTrue、または、False を返すリンクを設定をしたいのです。

VBAを使用すれば、１個づつリンク設定する手間が省けて、
一発で、できるのではと言ってくれる人もありましたが、
VBAに関しましては詳しく知りませんので、どんな式を使用すればよいかについて
教えて頂けませんでしょうか。
よろしくお願い致します。

(おすぎさん)
　
----
 Sub ぴーこさん()
     Const 開始行 As Long = 2
     Const 間隔   As Long = 3
     Const 横     As Long = 14
     Const 縦     As Long = 2
    
     Dim obj As CheckBox, i As Long

     For i = 1 To 横 * 縦
         With ActiveSheet.Cells(((i - 1) \ 横) * 間隔 + 開始行, (i - 1) Mod 横 + 1)
             Set obj = ActiveSheet.CheckBoxes.Add(.Left, .Top, .Width, .Height)
             obj.Caption = "チェック " & i
             obj.LinkedCell = .Offset(1).Address
         End With
     Next i
 End Sub

 (Gray)
----
ぴーこさん　回答ありがとうございます。
ご提示のプログラムを実行すると、28個の新たなチェックボックスが
一発で作成され、驚いています。

も少し知りたいと思っています質問点は、この作成された２８個の
それぞれのチェックボックスの下のセルにチェックボックスの結果を
表示するようにリンクを張りたいのです。

ひとつずつ個別にリンク設定していけばできるのですが、何とか、28個分が一発で
できる方法はないものでしょうか。

よろしくお願いします。

----
ぴーこさん、先のコメント失礼しました。

リンクは設定されていました。
申し訳ありません。

質問の仕方が悪かったので訂正致します。

ご回答頂いたプログラムはチェックボックスを作成するセルが指定
されているようにうかがえました。

シートの任意の箇所に（いろんな場所に）複数個のチェックボックスを
まず配置しておき、そのあと、配置した全チェックボックスの下のセルに
リンク設定を一発でできるようにすることは可能なのでしょうか。
もし、できましたら、お教え願いたいと思います。

（おすぎさん）
----
 応用でChekBoxをループすれば・・・

 Sub 名前はGrayなんですが()
     Dim obj As CheckBox, i As Long

     For Each obj In ActiveSheet.CheckBoxes
        obj.LinkedCell = obj.TopLeftCell.Offset(1).Address
     Next
 End Sub

 (Gray)
----
目から鱗が取れたような思いです。

Gray さん、ほんとにありがとうございました。
（Sub の名前が「ぴーこ」さんでしたので、失礼しました。）

七十の手習いで、最近、こんなに感激したことはありませんでした。

また、わからない点が出てきましたら、ご教示よろしくお願いします。

（おすぎさん）