『製品コードを分割』（ほとほと）
　
  　   A          B        C
 　1 コード  　分類１　　型式
　 2 1234A56    1234A     56
　 3 234C567     234C     567
 　4 34B5678      34B     5678

　 A列を分解してアルファベットを境にB列とC列にわける
　 B2にLEFT関数とFIND関数、OR関数でA,B,Cでを拾いたい
   C2にMID関数とFIND関数、OR関数で後ろを拾いたい
　
　　B2　=LEFT(A2,FIND(OR("A","B","C"),A2))
    C2  =MID(A2,FIND(OR("A","B","C"),A2)+1,4))
  
   OR関数が働かないでエラー
　　考え方はあまり間違っていないとおもいますが
　　例のように分割する方法を教えてください
　　
　　Vista  Excel2007
----
 関数はからっきしの (ぶらっと) なので、グーグルさんの助けを借りると、
 B2:=LEFT(A2,LEN(LOOKUP(10^17,LEFT(A2,COLUMN(2:2))*1))+1)
 C2:=RIGHT(A2,LEN(A2)-LEN(B2))
 で、できるみたいだよ。

 (ぶらっと)
----
 > B2にLEFT関数とFIND関数、OR関数でA,B,Cでを拾いたい
 > B2　=LEFT(A2,FIND(OR("A","B","C"),A2))

 ↑ な感じでやりたいのなら、つまりコード番号には A、B、C のいずれかが必ず含まれるのなら
 OR関数は使いませんが

 B2 =LEFT(A2,MIN(FIND({"A","B","C"},A2&"ABC")))　← {"A","B","C"}　は (　) ではなく {  }

 C2 =SUBSTITUTE(A2,B2,"")　　←　アルファベットは各コードに1個だけという前提で     
 　　　　　　　　　　　　　　　　（34B34Bなんていうコードは想定外ということ）

 （JPN）

----
 ◆こんな方法はいかがでしょう
 C2=-LOOKUP(1,-RIGHT(A2,ROW($1:$15)))
 B2=LEFT(A2,LEN(A2)-LEN(C2))
 (Maron)
----
ぶらっとさんJPNさんMaronさん
有難うございます
なんとかできました

　　　　　　ほとほと