『ユーザーフォームから一覧表への転記（更新）』（WAGOMU）


ユーザーフォームを使用して、一覧表に追記したいと考えています。
（エクセル2003を使用しています。）

『オーダーNo.』のほかに何個かのデータは既に別シート（管理表）に入力済みです。
管理表へ『オーダーNo.』をキーに『日付』と『管理番号』を『オーダーNo.』と同じ行の指定列に追記したいです。

入力後に登録をクリックすると管理表に追記され、
連続して入力できるように、ユーザーフォームをクリアな状態に戻し
『オーダーNo.』にカーソルが戻るようにしたいです。

□ユーザーフォーム

オーダーNo.	B3-XXXX		（コンボボックス）
日付		YYYY/MM/DD	（テキストボックス）
管理番号		123-4567-8910	（テキストボックス）


□管理表

	C		D		E	・・・	N	O
4	オーダーNo.	入力済み		入力済み		日付	管理番号
5	オーダーNo.	入力済み		入力済み		日付	管理番号
6	オーダーNo.	入力済み		入力済み		日付	管理番号
7	オーダーNo.	入力済み		入力済み		日付	管理番号


こちらのファイルはセルの結合はありません。

 どなたか教えて頂けないでしょうか。
よろしくおねがいします。

----
 TextBox1 が日付用、TextBox2 が管理番号用、ComboBox1 がオーダーNo 用、CommandButton1 が　登録用。

 Private Sub UserForm_Initialize()
    Dim r As Range
    With Sheets("管理表")
        ComboBox1.MatchRequired = True
        ComboBox1.List = .Range("C4", .Range("C" & .Rows.Count).End(xlUp)).Value
    End With
        
 End Sub

 Private Sub CommandButton1_Click()
    Dim ok As Boolean
    Dim i As Long
    
    If ComboBox1.ListIndex < 0 Or TextBox1.Value = "" Or TextBox2.Value = "" Then
        MsgBox "オーダーNO、日付、管理番号をすべて入れてから実行してください"
    ElseIf Not IsDate(TextBox1.Value) Then
        MsgBox "正しい日付を入れてください"
    Else
        ok = True
    End If
    
    If Not ok Then Exit Sub
    
    With Sheets("管理表")
        i = ComboBox1.ListIndex + 4
        .Cells(i, "N").Value = TextBox1.Value
        .Cells(i, "O").Value = TextBox2.Value
        TextBox1.Value = ""
        TextBox2.Value = ""
        TextBox1.SetFocus
        ComboBox1.Value = ""
    End With
    
 End Sub

 (ぶらっと)

----

ぶらっと様

早速ご返信頂き有難うございます。

実行してみたところ下記のようなエラーが発生してしまいました。

実行時エラー'70':
書き込みできません。

どのように対応すればよろしいでしょうか。

よろしくお願いいたします。

（WAGOMU）

----
 ComboBox1 のプロパティで　RowSource を設定しているのかな。
 そこを空白にしておいて。

 (ぶらっと)
----
ぶらっと様

無事にできました！！
早急にご回答頂き有難うございました。

(WAGOMU)

----
質問ばかりですみません。

ComboBox1.でオーダーNo.を選択した際に、TextBox1に日付が入力されていた場合、
ユーザーフォーム上のTextBox1に、入力されている日付を表示することは可能でしょうか。

可能であればコードをご教示いただきたく。
よろしくお願いいたします。

(WAGOMU)
----
 >TextBox1に日付が入力されていた場合、 ユーザーフォーム上のTextBox1に、入力されている日付を表示することは可能でしょうか。

 ん？？？？　管理表シートのコンボボックスで選択したデータに日付があれば　ということかな？

 (ぶらっと)
----
ぶらっと様

そうです。
わかりにくくてすみません。

(WAGOMU)
----
 じゃぁ、以下を追加。

 Private Sub ComboBox1_Change()
    Dim i As Long
    If ComboBox1.ListIndex < 0 Then Exit Sub
    i = ComboBox1.ListIndex + 4
    TextBox1.Value = Sheets("管理表").Cells(i, "N").Value
 End Sub

 (ぶらっと)
----
ぶらっと様

何度も有難うございます。
出来ました！

WAGOMU