『関数を教えてください』（ゆうと）
Windows Vista,Excel2007
サイト内でカレンダーを作るサイトがあり以下のようでしたがＡ４サイズに
２か月のカレンダーを作りたくて、でもサイト内の関数はそのままコピーしても
２か月のカレンダーが表示されません。
関数は
Ａ１に「２０１３／１／１」
Ａ２〜Ｇ２に曜日入力
Ａ３に「=IF(OR(MOD(ROW(A1),2)=0,MONTH($A$1)<>MONTH($A$1-WEEKDAY($A$1)+COLUMN(A1)+7*(INT(ROW(A1)/2)))),"",
$A$1-WEEKDAY($A$1)+COLUMN(A1)+7*(INT(ROW(A1)/2)))」
でＡ３〜Ｇ２とＡ１４〜Ｇ１４までコピー
なのですが何が違うのでしょうか。
よろしくお願いいたします。
----
こんばんは

 検証してみました
自分の環境では問題なく出ますね
何だろう！
http://www.eurus.dti.ne.jp/yoneyama/Excel/jituyou/calendar.htm

 A1=2013/1/1
 A3=IF(OR(MOD(ROW(A1),2)=0,MONTH($A$1)<>MONTH($A$1-WEEKDAY($A$1)+COLUMN(A1)+7*(INT(ROW(A1)/2)))),"",$A$1-WEEKDAY($A$1)+COLUMN(A1)+7*(INT(ROW(A1)/2)))

	【A】	【B】	【C】	【D】	【E】	【F】	【G】
【 1】	2013/1/1						
【 2】	日	月	火	水	木	金	土
【 3】							
【 4】	1月7日	1月8日	1月9日	1月10日	1月11日	1月12日	1月13日
【 5】							
【 6】	1月14日	1月15日	1月16日	1月17日	1月18日	1月19日	1月20日
【 7】							
【 8】	1月21日	1月22日	1月23日	1月24日	1月25日	1月26日	1月27日
【 9】							
【10】	1月28日	1月29日	1月30日	1月31日			
	

 環境　XP　2003
 　　　　　　　　　　　　　　　　　　　　　　　　　　　2013/06/16 01:22 aki
----
 ご提示の式で、1月のカレンダーは表示されると思います。

 ＞２か月のカレンダー
 と言う事ですので、同時に2月のカレンダーも表示したいのだと思いますが
 何処にどの様に表示したいのでしょう？

 1/31の続きに2/1から31日まで（2月は31日まで無いですが）表示させたいのでしょうか？

 でよければ、あまり深く考えず条件を変更しただけですが
=IF(OR(MOD(ROW(A1),2)=0,
TEXT($A$1-WEEKDAY($A$1)+COLUMN(A1)+7*(INT(ROW(A1)/2)),"YYYYMM")<TEXT($A$1,"YYYYMM"),
TEXT($A$1,"YYYYYMM")+1<TEXT($A$1-WEEKDAY($A$1)+COLUMN(A1)+7*(INT(ROW(A1)/2)),"YYYYMM")*1),"",
$A$1-WEEKDAY($A$1)+COLUMN(A1)+7*(INT(ROW(A1)/2)))

 で、21行目まではコピーしないといけないですが
 もともと14行目までしかコピーして無い　って事は
 次の月の日付は14行目まで分だけ表示されれば良いのでしょうか？

 でしたら、現在入れておられる式をそのまま使う事にして
 最後の方は =同じ列の一つ上の日付のセル+7　とかで表示させる事にすると
 式も簡単で済むと思います。

 当初の式で、2段目（5行目）は、確実にすべてのセルに日付が入るので
 3段目(9行目）から、A9=A7+7 で、G列までと1行おきに貼り付け。

 それとも、2か月目はまた気分を新たに
 22行目に曜日を入れて、23行目から一週目の表示を開始
 って感じになさりたいのでしょうか？

 そのあたりがあいまいに思えますので、
 補足を書いておいて貰えると良いと思います。

 (HANA)
----
HANAさんありがとうございます。
HANAさんの指摘通り新たに下方に二か月のカレンダーを作りたいのですが可能でしょうか。
説明が悪く申し訳ありませんでした、よろしくお願いいたします。
（ゆうと）
----
こんばんわ

 もしかしたらこんなイメージですか？外していたらすいません。

	【A】	【B】	【C】	【D】	【E】	【F】	【G】
【1】	2013/1/1						
【2】 	日	月	火	水	木	金	土
【3】			1月1日	1月2日	1月3日	1月4日	1月5日
【4】							
【5】	1月6日	1月7日	1月8日	1月9日	1月10日	1月11日	1月12日
【6】							
【7】	1月13日	1月14日	1月15日	1月16日	1月17日	1月18日	1月19日
【8】							
【9】	1月20日	1月21日	1月22日	1月23日	1月24日	1月25日	1月26日
【10】							
【11】	1月27日	1月28日	1月29日	1月30日	1月31日		
【12】							
【13】	日	月	火	水	木	金	土
【14】						2月1日	2月2日
【15】							
【16】	2月3日	2月4日	2月5日	2月6日	2月7日	2月8日	2月9日
【17】							
【18】	2月10日	2月11日	2月12日	2月13日	2月14日	2月15日	2月16日
【19】							
【20】	2月17日	2月18日	2月19日	2月20日	2月21日	2月22日	2月23日
【21】							
【22】	2月24日	2月25日	2月26日	2月27日	2月28日	

 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　2013/06/17 23:15 aki
----
ａｋｉさんありがとうございます。
そのとうりです、欲を言うと「２月」と表示できる場所があると良いだけです。
（ゆうと）
----
 ＞「２月」と表示できる場所があると良いだけです。
 でしたら、A3に入れた式を一旦そのまま
 次の月のカレンダーの先頭セルに貼り付けて
 数式内の $A$1 と成っている所（5箇所）を
 「2月」と表示させるセルに変更してください。

 $が付いていない A1 と成っているセルは
 そのままA1から動かさないでください。

 その後、次の月のカレンダーの範囲にコピーしてください。

 (HANA)
----
こんばんわ
 申し訳ありません。自分には、14行目以降の数式は作れませんでした。
自分の方法は、シートを3枚用意します。
1枚は、表示するシート、2枚目は月の上段、3枚目は月の下段です。
2枚目と3枚目のシートに上記の数式をいれ、1月と2月を作成し
それを、カメラ機能で1枚目の表示するシートに張り合わせました。
もし1つの式で上記表を作成するのであれば、他の有能な方のレスをお待ちください。
中途半端ですいません。皆様宜しくお願いします。本当にごめんなさい。___orz___

 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　2013/06/21 23:52 aki
----
 一応、もう少し具体的に書いておきます。

 何処から始まれば良いのか分からないので
 たとえば、A17に=DATE(YEAR(A1),MONTH(A1)+1,1)の式を入れて
 表示形式で　m月　として下さい。
 18行目に 日・月・火・・と曜日を入力
 19行目から日付を出す式です。
 A19に 
=IF(OR(MOD(ROW(A1),2)=0,MONTH($A$17)<>MONTH($A$17-WEEKDAY($A$17)+COLUMN(A1)+7*(INT(ROW(A1)/2)))),"",
$A$17-WEEKDAY($A$17)+COLUMN(A1)+7*(INT(ROW(A1)/2)))
 を、G列までと30行目までフィルドラッグ。

 場所を変更したい場合は、
 A17:G30を切り取って好きな所に貼り付け
 または、A17:G30を選択して　枠を持ってドラッグ＆ドロップ
 して下さい。

 一回設定すれば終わりだと思うので
 一月目用の式と、二月目用の式が有っても　大丈夫ですよね。。。？

 (HANA)
 
----
ゆうとさん　ごめんなさい　お礼を言わせて下さい。

HANAさま
 有難う御座います。

 自分は
=IF(OR(MOD(ROW(A1),2)=0,MONTH($A$17)<>MONTH($A$17-WEEKDAY($A$17)+COLUMN(A1)+7*(INT(ROW(A1)/2)))),"",$A$17-WEEKDAY($A$17)+COLUMN(A1)+7*(INT(ROW(A1)/2)))
にならず
=IF(OR(MOD(ROW(A17),2)=0,MONTH($A$17)<>MONTH($A$17-WEEKDAY($A$17)+COLUMN(A17)+7*(INT(ROW(A17)/2)))),"",$A$17-WEEKDAY($A$17)+COLUMN(A17)+7*(INT(ROW(A17)/2)))
になってしまい出来ませんでした。
有難う御座いました。勉強になりました。

 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　2013/06/22 1:28 aki
----
HANAさんありがとうございます！
助かりました。
お礼が遅れました申し訳ありません。
勤務が不規則のため、時間が限られていて、ありがとうございました。
（ゆうと）