『カレンダーの作成について』（右近）

お尋ねいたします。
以下のようなカレンダーを作成中なのですが、行き詰ってしまい、質問させていただきます。

A1に西暦、C1に月を入力すると、当月のカレンダーを表示します。
A1=2017(西暦)
C1=3(月)

A3=IF(CHOOSE(WEEKDAY(DATE($A$1,$C$1,1)),"日","月","火","水","木","金","土")=$A$2,DATE($A$1,$C$1,1),"")
以下をG3までペースト。
B3=IF(A3<>"",A3+1,IF(CHOOSE(WEEKDAY(DATE($A$1,$C$1,1)),"日","月","火","水","木","金","土")=B2,DATE($A$1,$C$1,1),""))
以下をG6までペースト。
A4=G3+1
以下をG7、A8、B8までペースト。
A7=IF(ISERR(DATE(YEAR(A1),MONTH(C1),DAY(G6)+1)=TRUE),"",G6+1)

このカレンダーは今月のものですが、F7の31日で終わらせたいのですが、G7以降翌月の日付が表示されてしまいます。
これを当月のみの表示とさせるためには、、、で行き詰っております。
よきお知恵をお貸しください。
よろしくお願いします。


__A__B__C__D__E__F__G
1 2017   3
2 日 月 火 水 木 金 土
3           1  2  3  4
4  5  6  7  8  9 10 11
5 12 13 14 15 16 17 18
6 19 20 21 22 23 24 25
7 26 27 28 29 30 31  1
8  2  3



＜ 使用 Excel：Excel2013、使用 OS：Windows7 ＞
----
A3:G8セルの条件付き書式を設定し、「=MONTH(A3)<>$C$1」の場合はフォントを白にする、という方法はいかがでしょうか。
（???） 2017/03/07(火) 18:55
----
 >右近 さん

 条件付き書式を使用しない方法

 ■A1=年（例えば、2017）
 ■C3=月（例えば、3）
 ■A2=日、B2=月、C2=火、D2=水、E2=木、F2=金、G2=土  を入力
 ■「C3:G8」の表示形式を、とりあえず「yyyy/mm/dd」にする
 ■「C3:G8」のセル範囲を黄色で塗りつぶす

 ■G3に次の式を入れる（今月の第一土曜日を求める式）
=DATE($A$1,$C$1,1*7-WEEKDAY(DATE($A$1,$C$1,-5),3))

 ■F3に次の式を入れる（F3の式をA3まで左方向に、フィルコピー）
=IF(MONTH($G$3-(7-COLUMN()))<>$C$1,"",$G$3-(7-COLUMN()))
 
 ■A4に次の式を入れる（A4の式をA8まで下方向に、フィルコピー）
=IF(G3="","",G3+1)
 
 ■B4に次の式を入れる（B4の式をG8まで、右方向＆下方向にフィルコピー）
=IF(A4="","",IF(MONTH(A4+1)<>$C$1,"",A4+1))
 
 ■最後に、「C3:G8」の表示形式を「d」にして、
  「C3:G8」のセル範囲の塗りつぶし色をなしにする。
（マリオ） 2017/03/07(火) 19:53
----
 >右近 さん

 最近、私的使用のために、エクセルカレンダー（簡易版）を作成しました。
 参考になるかもしれません。
〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
http://d.kuku.lu/b2f171d6b1
*六曜祝日_Calendar_Schedule.zip
〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
 六曜データは、次のサイトのものを使用しています。
 なお、六曜ﾃﾞｰﾀが、正しいかは、チェックしてません。
http://www.genkibox.com/rokuyo/
 六曜は、2033年に、閏月が決まらない問題（旧暦2033年問題と呼ばれる）が発生するので、
 2032年までのデータを使用しています。

（マリオ） 2017/03/07(火) 20:17
----
おはようございます。
返事が遅くなってしまいました。
???さん、マリオさん、ありがとうございます。
お二人のアイデアを参考にさせていただきました。
ありがとうございました。
（右近） 2017/03/09(木) 07:19