『条件付き書式のルール印刷』（ゆう）

非常に困っています。
シート上に条件付き書式が設定されています。
条件付き書式のルールを見直しをしていますが、設定されているルールが非常に多く
設定されている条件付き書式のルールを印刷して、紙上で確認したいのですが、印刷方式が分かりません。
お分かりなる方がいましたら、教えて下さい。
よろしくお願いします。




＜ 使用 Excel：Excel2010、使用 OS：Windows7 ＞
----
 参考まで。

 条件付き書式の数式を取得するExcelマクロ

http://www.relief.jp/docs/excel-vba-get-formula-conditional-formatting.html
（カリーニン） 2017/10/25(水) 11:53
----
ご回答ありがとうございます。
教えて頂きましたリンク先を参照に試してみます。
（ゆう） 2017/10/25(水) 12:10
----
何度もすいません。
先程、教えて頂いたリンク先のマクロを試してみましたが、
For Each fc In でコンパイルエラー:構文エラー となり
実行されませんでした。
見当も付かず困ってます。
アドバイスを頂ければ、幸いです。
よろしくおねがい致します。
（ゆう） 2017/10/25(水) 12:39
----
汎用的に使えそうな例なぞ。
標準モジュールに貼ってから実行すると、新シートを追加し、ここに情報を列挙します。
 Sub test()
    Dim wk As Worksheet
    Dim i As Long
    Dim j As Long
    Dim iR As Long

    Set wk = Sheets.Add
    wk.Range("A1:J1") = Array("シート名", "範囲", "文字色", "太字", "斜体", "背景色", "タイプ", "条件", "式1", "式2")

    iR = 1

    For i = 1 To Sheets.Count
        For j = 1 To Sheets(i).Cells.FormatConditions.Count
            With Sheets(i).Cells.FormatConditions.Item(j)
                iR = iR + 1
                wk.Cells(iR, "A").Value = Sheets(i).Name
                wk.Cells(iR, "B").Value = .AppliesTo.Address(0, 0)
                wk.Cells(iR, "C").Value = "'" & Right("000000" & Hex(.Font.Color), 6)
                wk.Cells(iR, "D").Value = .Font.Bold
                wk.Cells(iR, "E").Value = .Font.Italic
                wk.Cells(iR, "F").Value = "'" & Right("000000" & Hex(.Interior.Color), 6)
                wk.Cells(iR, "G").Value = .Type
                On Error Resume Next
                wk.Cells(iR, "H").Value = Array("", "xlBetween", "xlNotBetween", "xlEqual", "xlNotEqual", "xlGreater", "xlLess", "xlGreaterEqual", "xlLessEqual")(.Operator)
                wk.Cells(iR, "I").Value = "'" & .Formula1
                wk.Cells(iR, "J").Value = "'" & .Formula2
                On Error GoTo 0
            End With
        Next j
    Next i
 End Sub
（???） 2017/10/25(水) 13:02
----
 私自身VBAで条件付き書式を操作することはほとんどないので、リンク
 先のコードた試してませんでした。

 Excel2007で試したら確かにエラーになりました。
 ↓の部分がネックになっていそうですが、回避方法はわかりません。

 Dim fc As FormatCondition
（カリーニン） 2017/10/25(水) 14:15
----
カリーニンさんご紹介のリンク先にあるコードは、2010でも、条件付き書式の指定の仕方でエラーになりますね。うまくいく場合もありますが、まぁ、あまりよい例ではなかった、という事で。
（???） 2017/10/25(水) 14:35
----
ちなみに、エラー回避するならデータ型を Object に変えれば良いようです。数式の場合の条件付き書式にしか反応しないコードのようですし、他の条件付き書式を使う事まで検証しなかったのでしょうね。
（???） 2017/10/25(水) 14:47
----
カリーニンさん、？？？さん、アドバイスを頂きありがとうございました。
また、???さんに至ってはコードまで提示して頂きイメージ通りの結果になりました。
ありがとうございました。
（ゆう） 2017/10/25(水) 17:56