『最終列の表示』（くらん）

 A列　　　B列　　C列　　 D列　　　E列　　．．．Z列
 　　　　在庫	1月6日	1月1日	1月6日
 さくら	4	0	20	
 すみれ	2	45	55	45
 もも	5	0		

 D列〜日付は発注日で決まっていません。
 この時、最終列にある値をC列に表示させて 空白は0となるように。

 C列の数式を教えてください。



＜ 使用 Excel：Excel2010、使用 OS：Windows7 ＞
----
 配列で、、、
 =OFFSET(C2,,COUNTA($D$1:$S$1))
（SoulMan） 2019/02/15(金) 22:45
----
 C1 =IF(COUNT(D1:Z1),MAX(D1:Z1),"")　　表示形式「日付」
 ※1行目の日付は昇順という前提で

 C2 =SUMIF($D$1:$Z$1,$C$1,D2:Z2)
 ※C2は、1行目に同じ日付が重複することはない、という前提で

 C2を下にコピー

 こういうこと？
（笑） 2019/02/15(金) 23:32
----
 あっ、、間違った(^^;
 =INDEX(D3:G3,MATCH($C$1,$D$1:$J$1,0))
（SoulMan） 2019/02/15(金) 23:39
----
 C1 =IFERROR(LOOKUP(10^9,D1:Z1),"")　でも（表示形式「日付」）
 ※1行目の日付は昇順でなくても可

 C2 =INDEX(D2:Z2,COUNT($D$1:$Z$1))　 でも
 ※C2は、1行目の日付が飛び飛びにならず、D列から順に詰めて入力という前提で

 または
 C2 =IF(C1="","",LOOKUP(10^9,$C$1:$Z$1,C2:Z2))
 ※1行目の日付が飛び飛びでも可、 同じ日付が重複していても可

 参考まで
（笑） 2019/02/15(金) 23:49　追記2/16(土) 0:03
----
 とりとめのない感じになってしまいましたが
 1行目の日付について

 ・昇順なのか（右へ行くほど新しい日付なのか）
 ・重複しないのか（同じ日付が複数回出ることはないのか）
 ・D1から順に詰めて入力するのか（飛び飛びにはならないのか）

 上記によって数式も変わってくるということです。

 参考まで
（笑） 2019/02/16(土) 00:24
----
 ついでにもう一つだけ。

 1行目の日付を、必ずD1から順に詰めて入力していくのなら

 C1 =IF($D$1="","",INDEX(D1:Z1,COUNT($D$1:$Z$1)))

 これを下にコピーし、C1セルの表示形式だけ「日付」に

 ＞C1 =IF(COUNT(D1:Z1),MAX(D1:Z1),"")

 この式も、日付は昇順で、かつD1から順に詰めて入力していくのなら

 C1 =IF(D1="","",MAX(D1:Z1))

 参考まで
（笑） 2019/02/16(土) 01:56
----
 こんにちは　SoulManさん　笑さん

 ・昇順なのか（右へ行くほど新しい日付なのか）　→　はい、そうです。
 ・重複しないのか（同じ日付が複数回出ることはないのか）→　はい、重複しません。
 ・D1から順に詰めて入力するのか（飛び飛びにはならないのか　→　はい、詰めて入力します。

 教えていただいた数式で表示させることが出来ました。

 ありがとうございました。

（くらん） 2019/02/16(土) 12:43
----
こんばんは、追加訂正でまたよろしくお願いします。

0の時は0と入力表示させて未入力の時は「入力もれ」と表示させることが出来ますか？
空白セルは一切に無しのルールにしました。

いろんなレベルの人と同じ職場でカバーしながら働いています。
条件付き書式で空白セルだけ（今回はE2）色を付けることも考えましたが、それを入力した人が見落とすかもということで さらに数式で「入力もれ」表示が出来れば万全かなと考えています。


	在庫	1月6日	1月1日	1月6日
さくら	4	入力もれ 20	
すみれ	2	45	 55	 45
もも	5	0	 30	 0

たびたびで申し訳ありませんが、よろしくお願いします。
（くらん） 2019/02/24(日) 18:52
----
 こんばんは！

 前回は、、頓珍漢な回答してすみませんでした。m(__)m

 C1は、↓でいいでしょう？
=IF(D1="","",MAX(D1:Z1))

 C2も、もっとスマートな式があると思いますが、、
=IF(INDEX(D2:Z2,MATCH($C$1,$D$1:$Z$1,0))="","入力もれ",INDEX(D2:Z2,MATCH($C$1,$D$1:$Z$1,0)))

 で、どうでしょう？

 注意）胸のカラータイマーが点滅しだしました。。。すみません。m(__)m
（SoulMan） 2019/02/24(日) 20:53
----
 C1 =IF(D1="","",MAX(D1:Z1))　　表示形式「日付」

 C2 =IF($C$1="","",IFERROR((INDEX(D2:Z2,COUNT($D$1:$Z$1))&"")*1,"入力もれ"))

 C2を下にコピー

 こういうこと？
（笑） 2019/02/24(日) 22:19
----
SoulManさん　笑さん
こんばんは

助かりました！
しかも途中に空白のセルがあっても最終列のデータが反映されるのですね！

明日が楽しみです。
ありがとうございました。
（くらん） 2019/02/24(日) 22:50
----
 ＞しかも途中に空白のセルがあっても

 ↓ な場合があるってこと？

	A	B	C	D	E	F
1		在庫	1/14	1/1	1/6	1/14
2	さくら	100		20		30

 C2はどうなればいいんですかね？
 30？　つまりE2は入力もれのまま先に進むってことですか？

 以上、確認まで
（笑） 2019/02/24(日) 23:43
----
 こんばんは、笑さん　お世話になっております。

 30？　つまりE2は入力もれのまま先に進むってことですか？
 ＞30です。はい、先に進みます。
 
 パーフェクトに入力をお願いするのがたぶん無理な感じなので。
 毎日が試行錯誤の状態です。きっとまた質問すると思います。
 よろしくお願いします。


（くらん） 2019/02/25(月) 20:12