『複数の条件下で抽出する方法がわかりません。』（モー）

下記の様な表があります。

　　　　A　　　B　　　C　　　D　　　　E　　　　F　　　G　　　
　1　製造品　予算　進捗率　開始日　　終了日　締日　支払日
　2　〇〇〇　1000　　100　12/1　　　12/31　1/20　　1/末
　3　△△△　1500　　 90  　12/10 　　   1/10    　　 - 　　    -
　4　□□□　2000　　 75　  12/15      　　　-  　　　     -   　　  -

〇〇〇は進捗率が100％で、終了しているので、締日と支払日が確定
△△△は終了していますが、進捗率が90％なので、締日と支払日が未確定


進捗率が100で、かつ終了日が確定しないと、締日と支払日が表示されない
（もしくは計算されない）様にしたいのですが、可能でしょうか？


ちなみに、締日のF2のところは、=EOMONTH(E2,0)
支払日のG2のところは、=EOMONTH(F2,0)+20
の関数が入っています。（20日締翌月末払い）


前の投稿質問で説明の仕方がヘタという指摘をいただいたので、私なりに気をつけて考えて書いたつもりなんですが、よろしくお願いします。








＜ 使用 Excel：Excel2016、使用 OS：Windows10 ＞
----
 あちこちミスがあるようだが。
 F2セル:=IF(C2<100,"-",EOMONTH(E2,-(DAY(E2)<20))+20)
 G2セル:=IF(C2<100,"-",EOMONTH(F2,0))
 ではどうだろうか？
（ねむねむ） 2022/02/22(火) 13:09
----
＞締日のF2のところは、=EOMONTH(E2,0)
＞支払日のG2のところは、=EOMONTH(F2,0)+20

本当ですか？

＞（20日締翌月末払い）
　1/20〆なら、2/末支払では？

よくわかりませんが、こんな感じでしょうか。
 F2 : =IF(AND(C2=100,E2<>"-"),IF(DAY(E2)<=20,EOMONTH(E2,-1)+20,EOMONTH(E2,0)+20),"-")
 G2 : =IF(F2<>"-",MONTH(EOMONTH(F2,1))&"/末","-")


（わからん） 2022/02/22(火) 13:17
----
 すまない、G2セルの式は
 =IF(C2<100,"-",EOMONTH(F2,1))
 と修正してくれ。
（ねむねむ） 2022/02/22(火) 13:21
----
 連続で申し訳ない。
 F2セルの式も
 =IF(C2<100,"-",EOMONTH(E2,-(DAY(E2)<=20))+20)
 と修正してくれ。
（ねむねむ） 2022/02/22(火) 13:23
----
出来ました！
ぬむぬむさん、わからんさん
有難うございます！
（モー） 2022/02/22(火) 13:40
----
 ＞進捗率が100で、かつ終了日が確定しない
 進捗率が100でも、E列に日付が入ってない場合があるってこと？

 C列の表示形式はパーセンテージではないとして

 F2 =IF(AND(C2=100,COUNT(E2)),EOMONTH(E2-20,0)+20,"−")
 G2 =IF(COUNT(F2),EOMONTH(F2,1),"−")
 表示形式「日付」

 以上、参考まで
（笑） 2022/02/22(火) 14:00
----
どなたの式も正常に結果を反映しました。
すごいですね。
Excelの関数算式をどうやって繋げればいいのか、どうやってもエラーが
出てしまうので、本を読んでもよく分かりません。
有難うございました。
また質問すると思いますので、よろしくお願いします。
（モー） 2022/02/22(火) 14:26