[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『経過した年月を合計したい』(まり〜ん)
例えば4人いたとして
A2に入社日、B2に退社日を入力し、C2に経過年月を(○年ヶ月)というように表示させる。
それを4人分行を挿入して計算させた後
その合計をA1のセルに(○年ヶ月)と表示させたい。
例:
太郎さん(0年4ヶ月)
花子さん(2年6ヶ月)
智子さん(6年10ヶ月)
弘太さん(8年5ヶ月)
この合計を単純に合計をすると(16年25ヶ月)
と返ってきてしまうので
これを(18年1ヶ月)
となるように返す方法を教えてください!!
なんとか、経過年月の求め方まではわかったのですが。
合計がうまくできなくて・・・
本当にすみません。
手助けいただけましたら幸いです。
エクセルのバージョン・excel2002、OS・Windows2000
このようにされたらどうでしょう? (LOOKUP)
A B C 1 氏名 経過年月 2 太郎さん 0年4ヶ月 3 花子さん 2年6ヶ月 4 智子さん 6年10ヶ月 5 弘太さん 8年5ヶ月 6 合計 18年1ヶ月 ↑ =SUBSTITUTE(TEXT(SUMPRODUCT(--SUBSTITUTE(SUBSTITUTE( 0&C2:C5,"年"," "),"ヶ月","/12")),"0年0/12;;"),"/12","ヶ月")
ありがとうございました。
無事表示されました。
最初”ヶ月”の表示が”ヵ月”となっていて。
答えが"#VALUE!"と表示されたときは、おたおたしましたが、
置換するので関数部分とセルの表示が一致していなければエラーになりますよね。
一回SUMPRODUCT関数なんて思いもつきませんでした。
本当にありがとうございました。
又何かありましたらお力添えいただけましたら幸いです。
まり〜ん。
=SUBSTITUTE(TEXT(SUMPRODUCT(--SUBSTITUTE(SUBSTITUTE(SUBSTITUTE( 0&C2:C5,"年"," "),"ヶ月","/12"),"ヵ月","/12")),"0年0/12;;"),"/12","ヶ月") としますと、ヶ月、ヵ月に対応しますよ。 (LOOKUP)
ありがとうございました。
ちなみに・・・・
先ほどは時間がなくて、熟考する暇がなくて
関数の貼り付けで対応したのですが、
SUMPRODUCT(--・・・・・の、
”--”を何故入力しないと正しい数値が返ってこないのか
教えていただいても宜しいでしょうか????
初心者な者で、お手を煩わせてすみません。
まり〜ん。
どんぞ〜 (純丸)(o^-')b [[20040530061813]]『「--」と「!」の意味?』(masabou5)
純丸さん。REFERENCE ありがとう。
まり〜んさんに指摘されて、数式をこのようにしました。 すこし、見栄えがよくなったでしょう? (LOOKUP)
=SUBSTITUTE(TEXT(SUMPRODUCT(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE( 0&C2:C5,"年"," "),"ヶ月","/12"),"ヵ月","/12")/1),"0年0/12;;"),"/12","ヶ月")
この 0&C2:C5 の0&と、"0年0/12;;" の;;は、範囲内の空白セルを考慮したつもりです。
あ〜、もっと検索をすればよかったです。
ネットでググッタんですけど・・・・
もっと勉強しなくちゃ。
"-"の一個だけ消すと"######"って表示されるので
マイナスの意味なんだろうな、っていうところまでは
推測できたのですが。
勉強不足ですみません(^▽^;)
LOOKUPさん>
ありがとうございました。
3個目に教えていただいた数式のほうが
実際にエクセルを使う方にもわかりやすいし
教えるときも教えやすそうです。
本当にありがとうございました。
ここの掲示板でもっともっとエクセルをマスターしていきたいです。
まり〜ん。
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.