[[20061218153955]]　『計算結果を１２進法にしたい』（鈴）　ページの最後に飛ぶ

『計算結果を１２進法にしたい』（鈴）

現在のセルには下記計算式が入っています。
=IF(ISERROR(--LEFT($E8,COUNTIF(H$2,$F8+$G8)*LEN($E8))),"",--LEFT($E8,COUNTIF(H$2,$F8+$G8)*LEN($E8)))

例えば３月に購入したものを２ヶ月後に支払う、といった内容で、月ごとの表になっており、この場合だと５月の欄に結果が表示される、といった形になっています。

ただ、この計算式だと１１月に買った物を２ヵ月後、ということになりますと、１月には当然反映されません。（１１＋２＝１３となってしまうので）
該当する欄だけ-12するという方法もありますが、上記計算式を１２進法に変えられないかと思い質問させていただきます。
教えてください。
よろしくお願い致します。

既に作った計算式の「計算結果」が数値だったとき、その数値を引数に、MOD関数を使いましょう。

=MOD(計算結果,12)

で、「計算結果」を12で割った余りを計算します。

（まーまー）

 横槍失礼。
 まーまーさん、これですと12が出てきませんが。

 鈴さん
 E8,H2,F8,G8　これらのセルにどのような値が入っているのかが解らない限り、
 何のアドバイスも出来ないと思います。
 今いえるのは、E8セルの左から○文字が、数字だったら、それを表示。
 数字でなければ、何も表示しない。
 という数式です。
 ですので、これが何故、
 >（１１＋２＝１３となってしまうので） 
 と、なるのかは、各セルにどのような値が入っているのかを提示しないとわかりません。
 単純に行けば、マーマーさんが提示した式に、1を足せばとりあえずは、1～12で出ますが。
 　　（TORI)

 ぅ、なんか午前中に私が提案した式のようですね～＾＾；
 詰めが大甘でした。すみません。
同じ行でいいんでしょうかね…　
 LEFT($B2,COUNTIF(E$1,MOD($C2+$D2,12))*LEN($B2))　のようにするととりあえずは表示されると思うんですが、どうでしょう。
[[20061218100142]]『複数の条件にあった数字を該当する欄に入力するには』（らら）
HNは違いますけど、たぶんこれの続きではないかと…
(かなれっと)

まーまーさん、ＴＯＲＩさん、コメントありがとうございます。ＴＯＲＩさんのおっしゃるとおりですね、失礼しました。

       E         F         G    　     H  　　　　Ｉ　　  　Ｊ　  　　Ｋ
(1) 購入額　　購入月　　支払い                
(2)                     　           12月　　　　 1月　　　　2月 　　3月
(3)

(8)　50万円　　　12月　　1ヵ月後　　　　　　　　　　　○

○の欄に50万が反映するためにどうすればいいのか、ということです。
普通に1月に買って2ヵ月後に支払いということであれば3月の欄に金額が反映
してくれるのですが、１３を超える数字だとうまく表に落としこめないのです。

わかりづらいですか？

と、ここまで書いたところで、かなれっとさん、コメントありがとうございます。ららと一緒にやっております。わかってくださって嬉しい！
上の件書いてみたんで、かなれっとさんのアドバイスと共に作成したいと思います。
本当にありがとうございます。

 こんにちは～♪

 上のレスは、カン違いしていましたので
 削除しました～。。。

 ふたたび～です。
 こんな表の場合です。

	E	F	G	H	I	J	K
[1]	購入額	購入月	支払い	12	1	2	3
[2]	1000	12	1		1000		
[3]	2000	12	2			2000	
[4]	3000	1	2				3000

 ★かなれっとさんの式を少し直しました。

 H2 =LEFT($E2,(SUM($H$1,COLUMN(A1)-1)=($F2+$G2)+(($F2<12)*12))*LEN($E2))

 右と下にコピーします。

 この質問はいろいろと疑問があるんですが
 とりあえず。こんな式で、いかがでしょうか？

 。。。Ms.Rinでした～♪♪

 A1に10月　B1に4ヶ月とした場合
表示形式で　数値入力で　10月　と月がついて表示されますが１０で計算されます。
の条件で下記数数式
=MONTH(DATE("2002",A1+B1,3))　　　10月＋4ヶ月　で（翌年　）2月　
　　　　　　　　　　　　　　　　　　10月＋15ヶ月　で　（翌々年）１月
では　　（（ASAHI))

 衝突しました。↑おなじ発想です。
 Ms.Rin さんの表で、H2 =(H$1=MONTH(DATE(,$F2+$G2,1)))*$E2 として、
 表示形式を #,### とするのはどうでしょう？
（純丸）(o^-')b

 （（ASAHI))さん
 や
 （純丸）(o^-')bさん
　の式でよかったですね。

 何だか、いじくり回してしまいました～。。。

 私の式は、ボツににしてくださ～い。
 失礼しました。。。

 でした。。。Ms.Rin～♪♪

 元の式に近い感じだと、
=LEFT($E2,(MOD(H$1,12)=MOD($F2+$G2,12))*LEN($E2))
事後承諾で、Ms.Rinさんの表を使わせていただきました。
 --で数値化する場合には、同様のエラー処理が必要です。
(sin)

コメント返信：

[ 一覧(最新更新順) ]

[[20061218153955]] 『計算結果を１２進法にしたい』（鈴） ページの最後に飛ぶ

[[20061218153955]]　『計算結果を１２進法にしたい』（鈴）　ページの最後に飛ぶ