[[20080704141202]] 『ある条件を含む行を別シートにまとめたい』(あい) >>BOT

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『ある条件を含む行を別シートにまとめたい』(あい)

 過去ログを探して見たのですが、わからなかったので教えてください。
 1つのシートにある一覧をA列にある条件を含むものをその行ごと別のシートに
 まとめたいのです。

 A列  B列 C列 …
 0805  C  良い …
 0806  A  良い …
 0805  F  悪い …
 0807  B  わからない …
 0805  A  良い …

 この、A列の「0805」を含む行だけを別のシートに移したいです。
 0805  C  良い …
 0805  F  悪い …
 0805  A  良い …
 となるように。

 最初のシートのほうには随時下のほうに情報が追加されていくので、
 オートフィルタなどを使ってコピーして移していくのは何度も手間がかかるので、
 勝手に別のシートにも「0805」の一覧を作られるような形にしたいのです。
 マクロとかはわからないので、関数でできる方法があったら教えてください。
 よろしくお願いします。


 参考?
[[20080702152751]]『VLOOKUPかな?』(ミーコ)

 参考にして試してみたけどダメでした〜
 参考にいただいたのは、一つのセルの値をかえす方法だと思うのですが、
 その行全体(複数列)を別シートに移したいんです。
 その場合の式がわからないので、わかる方教えてください。
 よろしくお願いします。

 ホントに試したの?
 当然、応用しないと出来ませんよ?

 sheet1
      [A]  [B]   [C]       [D]
 [1]  0805  C   良い        …
 [2]  0806  A   良い        …
 [3]  0805  F   悪い        …
 [4]  0807  B   わからない  …
 [5]  0805  A   良い        …

 sheet2
      [A]  [B]   [C]       [D]
 [1]  0805  C   良い        …
 [2]        F   悪い        …
 [3]        A   良い        …

 shhet2のB1 =IF(ROW(1:1)>COUNTIF(Sheet1!$A$1:$A$7,$A$1),"",INDEX(Sheet1!B$1:B$7,SMALL(IF(Sheet1!$A$1:$A$7=$A$1,ROW(Sheet1!$A$1:$A$7),""),ROW(1:1))))
 ctrl+shift+enterで確定後、右へフィルコピー、下へフィルコピー
 sheet2のA1に「0805」と入力してみてください
 これでいいのかどうかは分かりませんが ^^;

 ありがとうございます。
 これでなんとかできそうです。

 もう一つ聞いてもいいですか?
 これを応用して、例えば、A列にあるのが「0805…」と後にも数字がある場合、
 完全一致じゃなくて、「0805」を含むもの全部を選びたい場合はどうなりますか?

そうなるとVBAになるのかな?
ですと、わかりません!!!
何方かの回答に期待してください。

 ミーコさん、ありがとうございました。
 それでもとっても勉強になりました。

 もう一つの場合のは、わかる方いらしたら宜しくお願いします。


 上で回答された方の式をお借りして、
 「0805」で始まる場合
=IF(ROW(1:1)>SUM(N(LEFT(Sheet1!$A$1:$A$7,LEN($A$1))=$A$1)),"",
INDEX(Sheet1!B$1:B$7,SMALL(IF(LEFT(Sheet1!$A$1:$A$7,LEN($A$1))=$A$1,ROW(Sheet1!$A$1:$A$7),""),ROW(1:1))))
 「0805」を含む場合
=IF(ROW(1:1)>SUM(N(ISNUMBER(FIND($A$1,Sheet1!$A$1:$A$7,1)))),"",
INDEX(Sheet1!B$1:B$7,SMALL(IF(ISNUMBER(FIND($A$1,Sheet1!$A$1:$A$7,1)),ROW(Sheet1!$A$1:$A$7),""),ROW(1:1))))
でしょうか? ※二つとも改行してます。
(sin)

 sinさん、ありがとうございます!
 できました〜♪
 きちんと「0805」を含んだ形で数もあっていたので、これでいけました。
 まだまだ勉強不足、がんばります。
 また、わからないときよろしくお願いします。

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.