[[20110629220208]]　『条件ごとで違う計算をさせたいのです』（初心者　ぴの）　ページの最後に飛ぶ

『条件ごとで違う計算をさせたいのです』（初心者　ぴの）
Excel2003です。このところ頭を抱えています。ぜひ教えてください。

商品ごとに価格の平均値をＣ列に入力したいのですが、こんな式はできるのでしょうか？

 例えば「婦人Ａ」の金額が４件以上入っているので婦人Ａの平均価格を出してＣに入力。
 他の商品は単独で４件未満なので残りの平均値が入っていない「服」の平均値をＣに入力。
 くつはどちらの条件にも当てはまらないので別のシートを参照して平均価格を入力

 　　　A　　　　　　　B　　　　C平均
 1　婦人Ａ（服）　　　20　　　　25
 2　婦人Ａ（服）　　　30　　　　25
 3　婦人Ａ（服）　　　20　　　　25　
 4　子どもＡ（服）　　　　　　　19
 5　子ども（服）　　　30　　　　19　
 6　婦人Ａ（服）　　　30　　　　25
 7　婦人Ｂ（服）　　　10　　　　19
 8　婦人Ｂ（服）　　　15　　　　19
 9　紳士Ａ（服）　　　20　　　　19
 10 子どもＢ（服）　　20　　　　19
 11　くつＡ（くつ）　 10　　　　別シートを参照した価格
 12　くつＡ（くつ）　 20　　　　別シートを参照した価格

 まず「服」とそうでない区別を A列から判定する手段が必要に見えます。
 ４件以上なく、「服」ではないものは必ず参照シート先にあるのでしょうか。

 いくつ条件が重なっても、基本は IF(条件,真の式,偽の式) の組み合わせですが
 4件以上ない、「服」、という部分をまとめるためには作業列が必要だと思います。
 (Mook)

 >くつはどちらの条件にも当てはまらないので

 くつAは単独で2件、だから、「単独で４件未満」という条件に当てはまっているけど　？？

 ぶらっと立ち寄り

Mookさん、ぶらっと立ち寄りさん、ありがとうございます。

説明が下手ですみません。

４件以上ない分類（くつ、バック、ぼうしなど）の平均数値は別参照シートに作成します。まだ他にも多くの商品と分類があります。個別に平均価格が出ないもの（１商品で４件未満は分類の平均価格）を入力する。分類でも４件未満のものは別参照シートより数値をひらってくるとしたいのです。

服は分類で間違いでした。すみません　　服×　→　婦人Ｂ

婦人Ａ＝４件あるので平均価格をＣに入力

子どもＡＢ、紳士Ａ、婦人Ｂは単独で４件無いが分類の服では４件あるので、６件の平均価格を入力

くつＡは単独で２件、分類の「くつ」でも４件未満なので別参照シートから数値をひらう。

としたいのです。

ＩＦ関数ですが、「４件以上ある」ｏｒ「４件未満」でさらに分類も「４件以上ｏｒ４件未満」と判定するような式はどのような式を使えば良いのでしょうか？

作業列やシートを別に使用する方法でも良いですので、アドバイスをいただけたら助かります。あまり詳しくないので関数をぜひ教えてください。

よろしくお願いします。

（初心者　ぴの）

 作業列を二列使用します。
 ＞別シートを参照した価格
 と言う事ですが、式が長く成るのでまずは
 この表が同じシートに有ると想定して作製して居ます。
 使える様であれば、この範囲を切り取って　別シートに貼り付けて貰うと
 式が勝手にそのシートを参照してくれる様に成ると思います。

 また、数式内の範囲は20行までとして有ります。
 実際はもっと範囲が広いと思いますので、適宜変更して下さい。

 まずはサンプルから。。。
	[A]	[B]	[C]	[D]	[E]	[F]	[G]	[H]	[I]
[1]	分類	商品	金額	平均	商品件数	分類件数		分類	価格
[2]	服	婦人Ａ	20	25	4			服	50
[3]	服	婦人Ａ	30	25	4			くつ	30
[4]	服	婦人Ａ	20	25	4				
[5]	服	子どもＡ	19	19	1	6			
[6]	服	子ども	30	19	1	6			
[7]	服	婦人Ａ	30	25	4				
[8]	服	婦人Ｂ	10	19	2	6			
[9]	服	婦人Ｂ	15	19	2	6			
[10]	服	紳士Ａ	20	19	1	6			
[11]	服	子どもＢ	20	19	1	6			
[12]	くつ	くつＡ	10	30	2	2			
[13]	くつ	くつＡ	20	30	2	2			
 E,F列が作業列、H,I列が「別シートの価格表」です。

 D2　　↓途中で改行して有りますが、2行で一つの式です。
=IF(E2="","",IF(F2<4,VLOOKUP(A2,$H$1:$I$20,2,FALSE),IF(E2<4,
SUMPRODUCT(($A$1:$A$20=A2)*($E$1:$E$20<4),$C$1:$C$20)/F2,SUMIF($B$1:$B$20,B2,$C$1:$C$20)/E2)))
 E2
=IF(C2="","",COUNTIF($B$1:$B$20,B2))
 F2
=IF(E2="","",IF(E2<4,SUMPRODUCT(($A$1:$A$20=A2)*($E$1:$E$20<4)),""))

 E列で、COUNTIF関数を使って　商品毎の件数を求めます。
 F列で、商品毎の件数が4件未満だった物に関して、
        SUMPRODUCT関数と使って分類毎の件数を求めます。
 COUNTIF関数と、SUMPRODUCT関数に付いてはこちらをご覧下さい。
http://www.excel.studio-kazu.jp/mag2/backnumber/mm20040824.html
 　　エクセルマイスター「countifで複数条件」

 D列で、まず 分類件数も4未満の物は VLOOKUP関数で別表から価格を参照します。
http://www.excel.studio-kazu.jp/lib/e1tw/e1tw.html
 　　ライブラリ「VLOOKUP」
http://www.excel.studio-kazu.jp/mag2/backnumber/mm20040921.html
 　　エクセルマイスター「VLOOKUP」
 平均は、合計／件数　ですが、件数はE,F列で求められているので
 合計の方を、SUMIF関数やSUMPRODUCT関数を使って求めます。
http://www.excel.studio-kazu.jp/lib/e3h/e3h.html
 　　ライブラリ「SUMIFとSUMPRODUCT」

 (HANA)

コメント返信：

[ 一覧(最新更新順) ]

[[20110629220208]] 『条件ごとで違う計算をさせたいのです』（初心者 ぴの） ページの最後に飛ぶ

[[20110629220208]]　『条件ごとで違う計算をさせたいのです』（初心者　ぴの）　ページの最後に飛ぶ