[[20110721221828]]　『VLOOKUPでは無理?』（GHQ）　ページの最後に飛ぶ

『VLOOKUPでは無理?』（GHQ）

  A列に表すabcの値、B列C列を、DからJに返したいのですが
 VLOOKUPでは一つの値しか返せません。EJにどんな数式を入れたらいいのでしょうか
 教えていただけないでしょうか。

      A      B      C              D     E   F    G   H    I  J 
 1    a     aa      3              a     aa  3    bb  1    cc 1            
 2    b     dd      2              b     dd  2    ee  2                    
 3    c     ff      4              c     ff  4    gg  3   
 4    a     bb      1                    
 5    a     cc      1                    
 6    b     ee      2                  
 7    c     gg      3

 回答が付かないようですので

 D列も数式で求めるのですか?

 作業用列の使用は可能ですか?
 作業用列が使用可能(A列)であれば　VLOOKUP　関数でもできると思います

 とりあえず、レイアウトが例題のとおりであれば、

 E1=IF(COUNTIF($A$1:$A$10,$D1)<INT(COLUMN(B1)/2),""
,INDEX(OFFSET($B$1,0,MOD(COLUMN(B1),2),10,1),SMALL(IF($A$1:$A$10=$D1,ROW($A$1:$A$10)),INT(COLUMN(B1)/2))))

 と入力し、CtrlとShiftキーを押しながらEnterで確定、配列数式にします。
 それをドラッグしてJ3までコピーすれば質問のようになります。
 (sato)

 (sato)様、回答有難うごうざいました。関数を自由自在に扱えて凄いと思います。
 作業列を使用しVLOOLUPでも出来るとありますが、ご指導おねがいします。』
（GHQ）

 ↓は締めて、こちらで回答を待つのですか？
[[20110721221828]] 『VLOOKUPでは無理?』（GHQ）

 でしたら、その様に書いておかないと　両方に回答がつく可能性がありますよ。
 どちらか一つにまとめましょう。

 (HANA)

      A     B      C     　D     E      F  G   　H    I  　J  K
 1    a1　　a     aa      3      a     aa  3    bb  　1    cc 1            
 2    b1　　b     dd      2      b     dd  2    ee 　 2                    
 3    c1　　c     ff      4      c     ff  4    gg  　3   
 4    a2　　a     bb      1                    
 5    a3　　a     cc      1                    
 6    b2　　b     ee      2                  
 7    c2　　c     gg      3

 A1=B1&COUNTIF($B$1:B1,B1)
 F1=IF(COUNTIF($A:$A,$E1&INT(COLUMN(B1)/2)),VLOOKUP($E1&INT(COLUMN(B1)/2),$A$1:$D$7,MOD(COLUMN(B1),2)+3,0),"")

 または
 F1=IF(COUNTIF($A:$A,$E1&COLUMN(B1)/2),VLOOKUP($E1&COLUMN(B1)/2,$A$1:$D$7,3,0),"")
 G1=IF(COUNTIF($A:$A,$E1&COLUMN(B1)/2),VLOOKUP($E1&COLUMN(B1)/2,$A$1:$D$7,4,0),"")
 F1:G1を選択して必要範囲にコピー

 表を少し変えて
	A	B	C	D	E	F	G	H	I	J
 1	a1	a	aa	3	a		b		c	
 2	b1	b	dd	2	aa	3	dd	2	ff	4
 3	c1	c	ff	4	bb	1	ee	2	gg	3
 4	a2	a	bb	1	cc	1				
 5	a3	a	cc	1						
 6	b2	b	ee	2						
 7	c2	c	gg	3

 A1=B1&COUNTIF($B$1:B1,B1)
 E2=IF(COUNTIF($A:$A,E$1&ROW(A1)),VLOOKUP(E$1&ROW(A1),$A$1:$D$7,3,0),"")
 F2=IF(COUNTIF($A:$A,E$1&ROW(B1)),VLOOKUP(E$1&ROW(B1),$A$1:$D$7,4,0),"")

 E2:F2を選択して必要範囲にコピー

コメント返信：

[ 一覧(最新更新順) ]

[[20110721221828]] 『VLOOKUPでは無理?』（GHQ） ページの最後に飛ぶ

[[20110721221828]]　『VLOOKUPでは無理?』（GHQ）　ページの最後に飛ぶ