[[20160811104100]]　『Ａ４に年月を入力すると工期が出る』（工期）　ページの最後に飛ぶ

『Ａ４に年月を入力すると工期が出る』（工期）

初めまして。

 下のようにA4に年月日の請求月を入力すると
 B5に平成28年 8月21日 ～ 平成28年 9月20日と出るように
 したいのですが。
　
	　　　A	                         B
　4	平成28年 8月分	
  5	工期	         平成28年 8月21日 ～ 平成28年 9月20日

　平成28年 8月分の８の前には半角スペースが入ります。
　平成28年 8月21日～平成28年 9月20日も８の前に半角スペース

 工期の参考ですが

　平成28年 9月分の工期は平成28年 9月21日～平成28年 10月20日
　平成28年 10月分の工期は平成28年 10月21日～平成28年 11月20日
　平成28年 11月分の工期は平成28年 11月21日～平成28年 12月20日
　平成28年 12月分の工期は平成28年 11月21日～平成29年 1月20日

 よろしくお願い致します。

＜使用 Excel：unknown、使用 OS：unknown ＞

A4は、日付データとし、表示形式で「平成28年 8月分」にするようにすれば

B5:=TEXT(A4,"gggge年 m月")&"21日～"&TEXT(EDATE(A4,1),"gggge年 m月")&"20日"

（マナ） 2016/08/11(木) 11:39

 ありがとうございます。
 しかし #VALUE!のエラーが出てしまいます。
 後、A4が空白になった場合は
 明治33年1月21日～明治33年1月20日となります。
（工期）

空白の場合の件は
=if(A4="","",…)
で、よいと思いますが、
エラーのほうは、わかりません。

A4は、日付でないとだめです。
そこは問題無いですか。

＞A4は、日付データとし、表示形式で「平成28年 8月分」にするようにすれば

（マナ） 2016/08/11(木) 13:58

 何度も申し訳ございません。

 セルを右クリック
 ↓
 セルの書式設定
 ↓
 分類を日付
 ↓
 種類を2001/3/14
 にして　平成28年 8月分と入力しているのですがエラーになってしまいます。
（工期） 2016/08/11(木) 14:27

 ユーザー定義にして

 ggge"年" m"月""分" を入力して
 A4に８/1と入力すると平成28年 8月分になり出来ました。

（工期） 2016/08/11(木) 15:03

もう一つよろしいでしょうか。

	　　　A	                         B
　4	平成28年 8月分	
  5	工期	         平成28年 8月21日 ～ 平成28年 9月20日

 は先程と同じで工期の平成28年 8月21日 ～ 平成28年 9月20日
 で締め後方の平成28年 9月20日は9月期なので9月の最後の日にちを
 A20に平成28年9月30日と表示させたいのですが。
 よろしくお願い致します。
（工期） 2016/08/11(木) 15:39

A20にA4の翌月末を表示ということでしょうか？
ならば、EOMONTH関数を使ってみてください。

（マナ） 2016/08/11(木) 15:47

EOMONTH関数
http://www.excel.studio-kazu.jp/func/eomonth.html

（マナ） 2016/08/11(木) 15:52

 ご丁寧にありがとうございました。
 A20=EOMONTH(A4,1)で出来ました。
 今後もよろしくお願い致します。
　
（工期） 2016/08/11(木) 16:03

 申し訳ございません。
 実は先程のは２０日締めの調書を作成での事で質問しましたが
 もう１パターンがありまして以下のようにしたいのですが。
　
	　　　A	                         B
　4	平成28年 8月分	
  5	工期	         平成28年 8月 1日 ～ 平成28年 8月31日

 工期がその月の（Ａ４の月）の1日～その月の月末日です。
  平成28年 9月分の工期は平成28年 9月 1日 ～ 平成28年 9月30日 
  平成28年 10月分の工期は平成28年 10月 1日 ～ 平成28年 10月31日 
  平成28年 11月分の工期は平成28年 11月 1日 ～ 平成28年 11月30日 
  平成28年 12月分の工期は平成28年 12月 1日 ～ 平成29年 12月31日
 のようになります。
 B5に入れる式を教えて下さい。

（工期） 2016/08/11(木) 16:17

ここまでのことが理解できていれば、応用もそれほど難しくはないと思います。
↓このあたりも参考にすると、きっと役立つでしょう。

http://www.eurus.dti.ne.jp/~yoneyama/Excel/waza/hiduke02.html

（マナ） 2016/08/11(木) 16:28

 ありがとうございます。
 B5 =EOMONTH(Ａ4,0)
 で月末日がでるのですがどこに入れたらよいのか分かりません。

 B5:=TEXT(A4,"gggge年 m月")&"1日～"&TEXT(EDATE(A4,1),"gggge年 m月")&"20日" 
 これですと１日～20日で後半を変えなくてはいけないのは分かるんですけど
 申し訳ないのですが教えていただけないでしょうか
（工期） 2016/08/11(木) 17:05

式の意味を理解するようにしたほうがよいです。
でないと、応用が効きませんので。
どう表示されるか確認してみてください。

=EDATE(A4,1)
=TEXT(EDATE(A4,1),"gggge年 m月d日")
=TEXT(EDATE(A4,1),"gggge年 m月")
=TEXT(EDATE(A4,1),"gggge年 m月")&"20日"

=EOMONTH(A4,0)
=TEXT(EOMONTH(A4,0),"gggge年 m月d日")

（マナ） 2016/08/11(木) 17:40

 ありがとうございました。
 出来ました。
 B5=TEXT(A4,"gggge年 m月")&"1日～"&TEXT(EOMONTH(A4,0),"gggge年 m月d日")
（工期） 2016/08/11(木) 17:56

 > B5=TEXT(A4,"gggge年 m月")&"1日～"&TEXT(EOMONTH(A4,0),"gggge年 m月d日")

 ↑「g」を4つ並べてますけど、3つでいいです。
　
　
 > 平成28年 9月分の工期は平成28年 9月 1日 ～ 平成28年 9月30日
　
「1日」の前にも半角スペースを入れるんじゃないんですか？

 A4が空白の場合を考慮しなくてよかったんですか？

 A4が必ず月初なら

 =IF(A4="","",TEXT(A4,"ggge年 m月 d日～")&TEXT(EOMONTH(A4,0),"ggge年 m月d日"))

 > 平成28年 12月分の工期は平成28年 12月 1日 ～ 平成29年 12月31日

 平成28年 12月31日ですよね？
（笑） 2016/08/11(木) 18:05

あらら、気づかないままコピペ繰り返していました。
５個でも、６個でも、エラーにはならないんですね。

（マナ） 2016/08/11(木) 18:47

 （笑）さんもありがとうございます。

 訂正→日にちの前にも半角を入れました。

 平成28年 12月分の工期は平成28年 12月31日です。

 以下の式で完了しました。

 B5=IF(A4="","",TEXT(A4,"ggge年 m月 d日～")&TEXT(EOMONTH(A4,0),"ggge年 m月 d日"))

 21日～20日の方も以下の式で入れ替えました。

 B5=IF(A4="","",TEXT(A4,"ggge年 m月")&" 21日～"&TEXT(EDATE(A4,1),"ggge年 m月")&" 20日")

 本当にありがとうございました。
（工期） 2016/08/11(木) 19:30

 また、お世話になります。
 大変な間違えをしてしまいました。
 締日を間違ってしまいました。
 正しくは以下のとおりです。
 	　　　A	                         B
　4	平成28年 8月分	
  5	工期	         平成28年 7月21日 ～ 平成28年 8月20日

 工期の参考は
 平成28年 9月分の工期は平成28年 8月21日 ～ 平成28年 9月20日 
 平成28年 10月分の工期は平成28年 9月21日 ～ 平成28年 10月20日 
 平成28年 11月分の工期は平成28年 10月21日 ～ 平成28年 11月20日 
 平成28年 12月分の工期は平成28年 11月21日 ～ 平成28年 12月20日
 平成29年 1月分の工期は平成28年 12月21日 ～ 平成29年 1月20日  
 よろしくお願い致します。
（工期） 2016/08/13(土) 14:57

横から失礼します。
今までの議論を理解しておられるのですか？
違いはどこで、不明な点は何ですか？
（γ） 2016/08/13(土) 16:14

 申し訳ございません。
 見直して出来ました。
 B5=IF(A4="","",TEXT(EDATE(A4,-1),"ggge年 m月")&" 21日～"&TEXT(EDATE(A4,0),"ggge年 m月")&" 20日")

 ありがとうございました。

 もう一つカレンダの日にちを以下のように作成したいのですが
 可能でしょうか。

 A１は、日付データとし、表示形式で「平成28年 9月分」と表示しております。

	A	B	AX	AZ	BB	BC	BE	BF	BH	BJ
1	2016/9/1									
2			平成	28	年	9	月	1	日	（木）
3			平成	28	年	9	月	2	日	（金）
4			平成	28	年	9	月	3	日	（土）
31			平成	28	年	9	月	30	日	（金）

 A１は、日付データとし、表示形式で「平成28年 9月分」と表示しております。

	A	B	AX	AZ	BB	BC	BE	BF	BH	BJ
1	2016/9/1									
2			平成	28	年	8	月	21	日	（日）
3			平成	28	年	8	月	22	日	（月）
4			平成	28	年	8	月	23	日	（火）
32			平成	28	年	9	月	20	日	（火）

 上のパターンは1日～月末締め用のカレンダーです。
 下のパターンはＡ1の前月の21日～A1月の20日締め用のカレンダーです。

 A1に入力するとAX　AZ　BB　BC　BE　BF　BH　BJ全てに上記のように
 年月日と曜日が出るような感じです。
 よろしくお願い致します。

（工期） 2016/08/13(土) 17:30

 > 見直して出来ました。
 > （前略）･･･ &TEXT(EDATE(A4,0),"ggge年 m月")&" 20日")
 　　　　　　　　　　~~~~~~~~~~~
                　　　　↑ ここ
 EDATE関数は不要です。

 =IF(A4="","",TEXT(EDATE(A4,-1),"ggge年 m月")&" 21日～"&TEXT(A4,"ggge年 m月")&" 20日")

 新しい質問の方ですけど、表示形式でいいんですかね？
 いいとして、

 > AX　AZ　BB　BC　BE　BF　BH　BJ

 ↑ の列番号、合ってます？　なんか飛び飛びになってますけど･･･。

 よくわからないので、例として「C列～J列」ってことで説明します。

 A1が必ず月初の日付だとして

 ■月初～月末

 C2（元号）=IF($A$1="","",IF(MONTH($A$1+ROW(A1)-1)=MONTH($A$1),$A$1+ROW(A1)-1,""))

 表示形式～ユーザー定義　ggg

 ROW(A1) は、A1セルの基準日とは何の関係もありません。変更しないように。

 D2（年）=IF($C2="","",$C2)

 F2（月）、H2（日）、J2（曜日）は、すべてD2と同じ

 =IF($C2="","",$C2)

 D2（年）の表示形式～ユーザー定義　e
 F2（月）　　　　〃　　　　　　　　m
 H2（日）　　　　〃　　　　　　　　d
 J2（曜日）　　　〃　　　　　　　　(aaa)

 E2 =IF($C2="","","年")
 G2 =IF($C2="","","月")
 I2 =IF($C2="","","日")

 C2:J2 を32行目までフィルコピー

 ■21日～翌20日

 これもA1が必ず月初の日付だとして。

 C2 =IF(A1="","",EDATE(A1+20,-1))
 C3 =IF(C2="","",IF(DAY(C2+1)=21,"",C2+1))

 C2とC3の表示形式～ユーザー定義　ggg

 C3をC32までフィルコピー

 D列以降は、月初～月末のパターンと同じです。

 参考まで。
（笑） 2016/08/13(土) 19:12

 （笑）さん　ご親切、ご丁寧にありがとうございました。
 完璧に出来ました。
 また、何か分からない事がありましたらよろしくお願い致します。
（工期） 2016/08/13(土) 22:20

 改めてありがとうございました。
 一つ謝らなければならない事があります。
 一回ごとの質問でニックネームを入れ替えるのかと思い
 ニックネームを変更してしまいました。
 言い訳がましいですが大変申し訳ございませんでした。
 今後ともよろしくお願い致します。

 追伸：今後は（日にち）で参加させて下さい。
　　　 申し訳ございませんでした。

（日にち） 2016/08/28(日) 10:10

コメント返信：

[ 一覧(最新更新順) ]

[[20160811104100]] 『Ａ４に年月を入力すると工期が出る』（工期） ページの最後に飛ぶ

[[20160811104100]]　『Ａ４に年月を入力すると工期が出る』（工期）　ページの最後に飛ぶ