[[20181127101911]]　『１００００時間を超える足し算』（うみんちゅ）　ページの最後に飛ぶ

『１００００時間を超える足し算』（うみんちゅ）

累積時間の計算で15478：50に225：15を足すと15704：05と出るようにしたいのですがどうすれば良いでしょうか？

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 15478:50は式で求められているのだろうか？
 それとも手入力なのだろうか？
（ねむねむ） 2018/11/27(火) 10:29

[[20061023021129]]『セルに10000時間以上の時間を入力したい』（jisea）

 の#REF!MANさんの式を使って表示形式を[h]:mmにすれば15704:05と表示されます。
（bi） 2018/11/27(火) 10:34

コメントありがとうございます。
手入力で毎月入力しております。毎月運転時間が数百時間累積されていくため１００００時間を超えた
足し算ができずに作業が止まっております。
15478：50+225：15＝15704：05にならずエラーが出てしまいます
（うみんちゅ） 2018/11/27(火) 10:41

Excelが扱える時間データには制限があります。以下が判りやすいでしょう。
https://support.office.com/ja-jp/article/Excel-%E3%81%AE%E4%BB%95%E6%A7%98%E3%81%8A%E3%82%88%E3%81%B3%E5%88%B6%E9%99%90-1672b34d-7043-467e-8e27-269d656771c3

そして、時間については「9999:59:59」までとなっているので、「15478:50」の段階で既にそれは時間として認識されず、文字列になっています。（文字列だから、普通に足し算とかできない）時間と分を別のセルに分けるとか、日付も使うとかに変えられませんか？

または、現状のままどうしても足し算したいなら、文字列を「:」で区切ってから時間と分を別々に足して、繰り上がりも考慮して、できた2つの数字を再び「:」で連結する（値が0の場合も考慮する）、という面倒な式またはマクロを考えないといけないでしょう。 biさんがリンクしてくれている過去ログなんかは、その辺りを頑張ったものですね。（計算はできないけど、表示だけはできるのを利用している訳ですか）
（???） 2018/11/27(火) 10:44

 うみんちゅさんが使ってる表のレイアウトがどんなものかわかりませんが例として

 	A	B	C
 1　15478:50　225:15

 C1セル =SUMPRODUCT(--SUBSTITUTE(TEXT(A1:B1,"[h]:mm!/!6!0;0;0;@!/!6!0"),":"," "))/24
 表示形式 [h]:mm

 これでC1セルには15704:05と表示されます。
（bi） 2018/11/27(火) 10:55

皆さんありがとうございます、感謝しかございません。
早速やってみます！
なによりもこのサイトが早く解決してもらえて助かります
（うみんちゅ） 2018/11/27(火) 10:57

 ＞毎月運転時間が数百時間累積されていくため

 この計算をSUMとか数式を使ってできないんですか？
 数式を使えば「71003183:59:59」まで計算が可能です。

 以上
（笑） 2018/11/27(火) 11:00

(笑)さんありがとうございます。
私の知識ではできないんですよね。。。
（うみんちゅ） 2018/11/27(火) 11:13

 手入力ができないだけ。計算は、10000時間以上でもできますよ。

 15478.50が手入力できなくて困っているなら、
 以下、それも計算式でやる案

 A1セル　=15478/24+50/1440　（表示形式　[h]:mm）
 C1セル　=A1+B1

 <結果図>
  行  _____A_____  ____B____  _____C_____  ____D____
   1  　15478:50  　225:15  　　15704:05   時間表示 
   2        1          1            1      型(数値) 
   3   644.951389   9.385417   654.336806  実体値

 ※そういうデータが沢山あるなら、別途工夫する。

（半平太） 2018/11/27(火) 11:39

 知識の問題なら

 A列に毎月の運転時間を入力
 B列に累計

	A	B
1		
2	225:15	225:15
3	333:30	558:45
4	123:45	682:30
5

 これまでの履歴が残っていないのなら

	A	B
1		
2	9999:50	9999:50
3	5479:00	15478:50
4	225:15	15704:05
5

 A4以降に毎月の運転時間を入力

 B2 =IF(A2="","",SUM($A$2:A2))　　下にコピー

 または

 B2 =A2
 B3 =IF(A3="","",A3+B2)　　B3を下にコピー

 こういう感じにできませんか？　ということです。

 以上
（笑） 2018/11/27(火) 11:43

 ＞B2 =A2
 ＞B3 =IF(A3="","",A3+B2)　　B3を下にコピー

 B2 =IF(A2="","",A2+N(B1))

 下コピーでもいいです。

 参考まで
（笑） 2018/11/27(火) 11:48

(笑）さんご丁寧にありがとうございます。無事解決することができました。
他の皆様も親切にありがとうございました。
（うみんちゅ） 2018/11/28(水) 10:03

コメント返信：

[ 一覧(最新更新順) ]

[[20181127101911]] 『１００００時間を超える足し算』（うみんちゅ） ページの最後に飛ぶ

[[20181127101911]]　『１００００時間を超える足し算』（うみんちゅ）　ページの最後に飛ぶ