[[20211129174419]] 『複雑な条件での日付の算出』(かせ) >>BOT

[ 初めての方へ | 一覧(最新更新順) |

| 全文検索 | 過去ログ ]

 

『複雑な条件での日付の算出』(かせ)

顧客マスターからVlookupでデータを引っ張ってきた売り上げフォームがあます。顧客マスターの内容は変えられません。

A1:締日を引っ張ってきてあります。データは、10、20、末のどれかです。

A2:売上日があります。

A3:A1とA2のデータを使って、締日を算出したいです。

A1が末だったら、という文字を論理式にいれて、末日を計算させる方法が分かりません。また、この場合、締日が10日で、売り上げの日が10日より前だったら、という条件をつけないといけないと思うのですが、複数の条件を一つのセルに入れようとしても上手くいきません。宜しくお願いします。

< 使用 Excel:Excel2016、使用 OS:Windows10 >


 =IF(OR(A1="",A2=""),"",EOMONTH(A2,IF(DAY(A2)>N(A1),0,-1))+N(A1))
 表示形式「日付」

 こういうこと?
(笑) 2021/11/29(月) 18:28

 ↓ でもできますね

 =IF(OR(A1="",A2=""),"",EOMONTH(A2-N(A1),0))+N(A1)

 ついでに言っておくと N というのは関数です。

 以上
(笑) 2021/11/29(月) 22:00

すみません。だめでした。
(かせ) 2021/11/30(火) 01:39

よくわかりませんので、てきとうです。

 =IF(A1="末",EOMONTH(A2,0),IF(DAY(A2)<=A1,DATE(YEAR(A2),MONTH(A2),A1),DATE(YEAR(A2),MONTH(A2)+1,A1)))

(ひまつぶし) 2021/11/30(火) 08:23


 もしかして ↓ 同じ人?
[[20211130014050]]『二択の条件を二つ入れる関数』(モアナ)

 違うんだったら
>=IF(OR(A1="",A2=""),"",EOMONTH(A2-N(A1),0))+N(A1)
 ↑ の式で、どのような場合に、どうなるべきところがどうなってしまったのか
 具体的に説明してください。

 以上
(笑) 2021/11/30(火) 11:34

 下記でどうかな?

 =IF(OR(A1="",A2=""),"",DATE(YEAR(A2),MONTH(A2)+N(DAY(A2)>N(A1)),N(A1)))

(hatena) 2021/11/30(火) 11:47


笑さんの式でも同じ結果になりますね。笑さんの方がシンプルなのでそちらを使ってください。
(hatena) 2021/11/30(火) 11:57

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.