[[20060302200935]]　『VLOOKUP関数について』（みみ）　ページの最後に飛ぶ

『VLOOKUP関数について』（みみ）

 Sheet1　
   A       B    　  C       D        E   　　　・　　・　　・　　・　　・
 番号　電話番号　代表者　 住所　　家族氏名   DATA1  DATA2  DATA3
  1　　半角　 　  全角　　全角   　全角　　　全角
                                   全角　　　全角
                                   全角　　　全角
                                   全角　　　全角
  2　　半角　 　  全角　　全角   　全角　　　全角
                                   全角　　　全角
                                   全角　　　全角
  3    半角　 　  全角　　全角   　全角　　　全角
とある住所録で、Sheet2のA1に検索文字(代表者及び家族氏名)を入力しSheet2のA2-H2に表示させたいのですが、関数
A2=VLOOKUP($A$1,Sheet1!$A$2:$H$2,1,FALSE)
B2=VLOOKUP($A$1,Sheet1!$A$2:$H$2,2,FALSE)
C3=VLOOKUP($A$1,Sheet1!$A$2:$H$2,3,FALSE)
・
・
を入れてやってみたところ、半角の番号欄で検索すると表示されますが、代表者欄の全角で検索すると#N/Aが表示されます。
この関数の誤りを教えてもらえないでしょうか。

 VLOOKUPについて、エクセルのヘルプより抜粋すると。
 書　式　VLOOKUP(検索値,範囲,列番号,検索の型)
 検索値  範囲の左端の列で検索する値を指定します。
 なので、番号欄で検索すると表示され、代表者欄を検索値にすると値がないよ～とエラー値が表示されるわけです。
 この学校のライブラリに使い方がありますので参考にどうぞ～　　　(かなれっと)
http://www.excel.studio-kazu.jp/lib/e1tw/e1tw.html

 衝突しました。 
 ご提示のVLOOKUP関数の数式の使い方には誤りはないように思います。
 #N/Aエラーが出る原因としては、次のようなことが考えられます。
 Sheet2のA1に入力したデータが検索範囲の中に存在しないということです。
 例えば、文字自体はあるがその前後にスペースなどが入っているという
 ことはありませんか？
　　　　　　　　　　　　　　　　　　　　　　　　　　　(SS)
 あっ！
 かなれっとさんご指摘の通りです。そこまで検証せず、気が付きませんでした。
 範囲設定の仕方の問題のようですね。(自爆）
                                                   (SS)

 ありがとうございます。やはりB以降の検索はだめなのでしょうか。
そのため簡単な表を作成してやってみましたが、それでもだめでした。
   a   b   c   d
1
2  あ　い　う　え
として
A3=VLOOKUP($A$1,$A$2:$D$2,1,FALSE)
B3=VLOOKUP($A$1,$A$2:$D$2,2,FALSE)
にし、A1に「あ」と入力すると表示され、「い」と入力するとやはりエラーが出ます。
この関数では、A列での検索以外はだめなのでしょうか。他の方法があればお願いします。

 すみません、意味がよく分からないのですが、
 みみさんの数式では、A1に「あ」と入力すると、A3に「あ」、B3に「い」と表示されますが、
 A1に「い」と入力したときにはA3とB3にはなんと表示したいのですか？
 (sato)

 説明不足ですみませんでした。A1に「あいうえ」のいずれかの文字を入力した場合に、
検索された文字のある行をA列の20行目に全て表示させたいのです。
A1に「う」と入力した場合、
A20行目が
     a   b   c   d
20  あ　い　う　え
と表示させたいのですが、この説明でわかるでしょうか。
実は、シート１にあるデ－タ－をシート２のA1で検索したいのですが、簡単なこの表を使って同じシートでやってみましたが、
A列の検索はできますが、BCD列の文字検索ではエラーが表示されます。VLOOKUP関数ではできないのでしょうか。お願いします。

 このようなことでしょうか？

        A         B         C        D       E
 1      く				
 2      あ	い	う	え	
 3      か	き	く	け	2
 4      さ	し	す	せ	
 5				
 6      か	き	く	け

 E列を作業列として、
 E2=IF(ISERROR(MATCH($A$1,A2:D2,0)),"",ROW(A1))
 として、下にコピーしておきます。

 A6=INDEX($A$2:$D$5,LOOKUP(10^16,$E$2:$E$5),COLUMN(A1))

 としてD6までコピーするとこのようになります。
 (sato)

 できました。大変ありがとうございました。一箇所だけ説明してもらえますか。
LOOKUP(10^16,$E$2:$E$5)の部分の「10^16」について、勉強不足で意味がわかりません。
お願いします。

 こちらに解説がありますのでご参考にされると良いと思います。　(sato)
 　
[[20031003114044]]『最後の数値が出るようにしたい』
[[20031006082456]]『LOOKUPで使う10^16の意味は』

ご丁寧にありがとうございました。検索場所をシート２に変更してやってみます。

satoさんへ

 一つ問題が起きてしまいました。というのもデ－タ－が重複した場合に一つの行しか選択されません。
住所録の検索のため同姓同名がある場合もあり、これらを全て表示するようにできませんでしょうか。宜しくお願いします。

        A         B        C         D
 1      く				
 2      あ	い	う	え	
 3      か	き	く	け	2
 4      く	し	す	せ	3
 5				
 6      か	き	く	け	
 7      く	し	す	せ

 A6=IF(COUNT($E$2:$E$5)<ROW(A1),"",INDEX($A$2:$D$5,SMALL($E$2:$E$5,ROW(A1)),COLUMN(A1)))

 として、右方向と下方向にコピーです。
 (sato)

satoさんありがとうございます。完璧にできました。お世話になりました。

satoさんまだ見ておられるでしょうか。またまた不具合が生じました。
検索文字が１文字であれば検索できますが、２文字以上になれば完全に一致する文字
（佐藤○○）と氏名まで入力しないと検索してくれません。
これを佐藤のみで検索できるようにできませんでしょうか。

       A         B        C         D
 1      く				
 2    あい     うえ	おか     きく	
 3    けこ　　 しき	つし     はし	
 4    ちと　　 てた	らら     せせ	
 5				
 6
の場合、「あ」とか「ら」とか１文字で検索できませんでした。宜しくお願いします。

       A       B       C       D      E          
 1    く				
 2    あい    うえ    おか    きく    1
 3    けこ    しき    つし    はし	
 4    ちと    てき    らく    せせ    3
 5
 6    あい    うえ    おか    きく	
 7    ちと    てき    らく    せせ

 作業列の数式を変更してください。

 E2=IF(ISERROR(LOOKUP(10^16,FIND($A$1,A2:D2))),"",ROW(A1))

 で、下にコピーです。
 A6以降は前回のまま変更なし。
 (sato)

satoさん大変ご迷惑をおかけしました。実際に使用しているデ－タ－に計算式を入れ確認しました。
問題なく検索ができました。何回もお願いして申し訳ありません。今後とも宜しくお願いします。

コメント返信：

[ 一覧(最新更新順) ]

[[20060302200935]] 『VLOOKUP関数について』（みみ） ページの最後に飛ぶ

[[20060302200935]]　『VLOOKUP関数について』（みみ）　ページの最後に飛ぶ